WOLFRAM

Wolfram Language & System Documentation Center

SquareFreeQ[expr]

gives True if expr is a square-free polynomial or number, and False otherwise.

SquareFreeQ[expr,vars]

gives True if expr is square free with respect to the variables vars.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
GaussianIntegers  
Modulus  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
History
Cite this Page

SquareFreeQ

SquareFreeQ[expr]

gives True if expr is a square-free polynomial or number, and False otherwise.

SquareFreeQ[expr,vars]

gives True if expr is square free with respect to the variables vars.

Details and Options

  • SquareFreeQ is typically used to test whether a number or a polynomial is square free.
  • An integer n is square free if it is divisible by no perfect square other than 1.
  • SquareFreeQ[expr] returns False unless expr is manifestly square free.
  • With the setting GaussianIntegers->True, SquareFreeQ tests whether expr is Gaussian square free.
  • For integers m and n, SquareFreeQ[m+I n] automatically works over Gaussian integers.
  • The following options can be given:
  • GaussianIntegers Automaticwhether to allow Gaussian integers
    Modulus 0modulus for polynomial coefficients

Examples

open all close all

Basic Examples  (2)

Test whether a number is square free:

Wolfram Language code: SquareFreeQ[10]

The number 4 is not square free:

Wolfram Language code: SquareFreeQ[4]

Scope  (5)

SquareFreeQ works over integers:

Wolfram Language code: SquareFreeQ[20]

Gaussian integers:

Wolfram Language code: SquareFreeQ[3 + 2I]
Wolfram Language code: SquareFreeQ[2, GaussianIntegers -> True]

Rational numbers:

Wolfram Language code: SquareFreeQ[2 / 3]

Univariate polynomials:

Wolfram Language code: SquareFreeQ[6 + 6x + x ^ 2]

Multivariate polynomials:

Wolfram Language code: SquareFreeQ[x ^ 3 - x ^ 2y]

Specify the variable in a polynomial:

Wolfram Language code: SquareFreeQ[x y ^ 2, x]
Wolfram Language code: SquareFreeQ[x y ^ 2, y]

Polynomials over a finite field:

Wolfram Language code: SquareFreeQ[x ^ 2 + 1, Modulus -> 2]

Test for large integers:

Wolfram Language code: SquareFreeQ[10 ^ 70 + 3]

Options  (2)

GaussianIntegers  (1)

Test whether 2 is square free over integers:

Wolfram Language code: SquareFreeQ[2]

Gaussian integers:

Wolfram Language code: SquareFreeQ[2, GaussianIntegers -> True]

Modulus  (1)

Test whether is square free over integers:

Wolfram Language code: SquareFreeQ[x ^ 2 - 3]

Integers modulo 3:

Wolfram Language code: SquareFreeQ[x ^ 2 - 3, Modulus -> 3]

Applications  (8)

Basic Applications  (3)

Highlight square-free numbers:

Wolfram Language code: Multicolumn[If[SquareFreeQ[#], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

Generate random square-free integers:

Wolfram Language code: randomSquareFree[m_] := Table[Times@@Union[RandomPrime[{2, 1000}, RandomInteger[{1, 5}]]], {m}];
Wolfram Language code: randomSquareFree[5]
Wolfram Language code: AllTrue[%, SquareFreeQ]

Square-free Gaussian integers:

Wolfram Language code: ArrayPlot[Table[Boole[SquareFreeQ[x + I y, GaussianIntegers -> True]], {x, 300}, {y, 300}]]

Number Theory  (5)

The central binomial coefficients Binomial[2n,n] are not square free for :

Wolfram Language code: And @@ Table[Not[SquareFreeQ[Binomial[2n, n]]], {n, 5, 2 ^ 10}]

Find the fraction of the first numbers that are square free:

Wolfram Language code: Length@Select[Range[10 ^ 5], SquareFreeQ] / 10 ^ 5//N

The result is close to :

Wolfram Language code: 1 / Zeta[2]//N

The polynomial p[x]/PolynomialGCD[p[x],p'[x]] is always square free:

Wolfram Language code: p = (x + 1) ^ 3(x + 2) ^ 2(x + 3) ^ 2;
Wolfram Language code: q = p / PolynomialGCD[p, D[p, x]]//FullSimplify
Wolfram Language code: SquareFreeQ[q]

The distribution of square-free numbers over integers:

Wolfram Language code: data = Select[Range[100], SquareFreeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Plot the distribution:

Wolfram Language code: DiscretePlot[Evaluate[CDF[𝒟, x]], {x, 1, 100}, ExtentSize -> Right]

The distribution of square-free numbers over the Gaussian integers:

Wolfram Language code: data = {Re[#], Im[#]}& /@ Select[Flatten[Table[a + b I, {a, 500}, {b, 500}]], SquareFreeQ];
Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Plot the distribution:

Wolfram Language code: DiscretePlot3D[Evaluate[CDF[𝒟, {x, y}]], {x, 1, 5}, {y, 1, 5}, ExtentSize -> Right]

Properties & Relations  (8)

A number that is divisible by a square is not square free:

Wolfram Language code: Divisible[12, 4]
Wolfram Language code: SquareFreeQ[12]

In the prime factorization of a square-free number, the exponents of primes are all 1:

Wolfram Language code: SquareFreeQ[210]
Wolfram Language code: FactorInteger[210]

PrimeNu is equal to PrimeOmega for square-free numbers:

Wolfram Language code: SquareFreeQ[14]
Wolfram Language code: PrimeNu[14] == PrimeOmega[14]

MoebiusMu is zero for non-square-free integers:

Wolfram Language code: SquareFreeQ[12]
Wolfram Language code: MoebiusMu[12]

Numbers that are prime powers and square free are prime numbers:

Wolfram Language code: PrimePowerQ[17] && SquareFreeQ[17]
Wolfram Language code: PrimeQ[17]

The discriminant of a quadratic non-square-free polynomial is 0:

Wolfram Language code: SquareFreeQ[x ^ 2 - 2x + 1, x]
Wolfram Language code: Discriminant[x ^ 2 - 2x + 1, x]

Square factors can be found using FactorSquareFreeList:

Wolfram Language code: SquareFreeQ[Expand[(x + 1) ^ 3(x + 2) ^ 2(x + 3) ^ 2]]
Wolfram Language code: FactorSquareFreeList[Expand[(x + 1) ^ 3(x + 2) ^ 2(x + 3) ^ 2]]

Simplify symbolic expressions:

Wolfram Language code: Simplify[SquareFreeQ[a ^ 2], a∈Integers]

Neat Examples  (3)

Plot the prime numbers that are the sum of three squares:

Wolfram Language code: ArrayMesh[Boole[Table[SquareFreeQ[a ^ 2 + b ^ 2 + c ^ 2], {a, 10}, {b, 10}, {c, 10}]]]

Square-free Gaussian integers:

Wolfram Language code: ArrayPlot[Table[Boole[SquareFreeQ[x + I y]], {x, 50}, {y, 50}]]

Plot the Ulam spiral of square-free numbers:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[ulam[101]MapAt[Boole[SquareFreeQ[#]]&, ulam[101], {All, All}], ColorFunction -> "Rainbow", ColorRules -> {0 -> White}]
Wolfram Research (2007), SquareFreeQ, Wolfram Language function, https://reference.wolfram.com/language/ref/SquareFreeQ.html.

Text

Wolfram Research (2007), SquareFreeQ, Wolfram Language function, https://reference.wolfram.com/language/ref/SquareFreeQ.html.

CMS

Wolfram Language. 2007. "SquareFreeQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SquareFreeQ.html.

APA

Wolfram Language. (2007). SquareFreeQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SquareFreeQ.html

BibTeX

@misc{reference.wolfram_2026_squarefreeq, author="Wolfram Research", title="{SquareFreeQ}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/SquareFreeQ.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_squarefreeq, organization={Wolfram Research}, title={SquareFreeQ}, year={2007}, url={https://reference.wolfram.com/language/ref/SquareFreeQ.html}, note=[Accessed: 13-June-2026]}