WOLFRAM

Wolfram Language & System Documentation Center

StringSplit["string"]

splits "string" into a list of substrings separated by whitespace.

StringSplit["string",patt]

splits into substrings separated by delimiters matching the string expression patt.

StringSplit["string",{p1,p2,…}]

splits at any of the pi.

StringSplit["string",pattval]

inserts val at the position of each delimiter.

StringSplit["string",{p1v1,…}]

inserts vi at the position of each delimiter pi.

StringSplit["string",patt,n]

splits into at most n substrings.

StringSplit[{s1,s2,…},p]

gives the list of results for each of the si.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Options  
IgnoreCase  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

StringSplit

StringSplit["string"]

splits "string" into a list of substrings separated by whitespace.

StringSplit["string",patt]

splits into substrings separated by delimiters matching the string expression patt.

StringSplit["string",{p1,p2,…}]

splits at any of the pi.

StringSplit["string",pattval]

inserts val at the position of each delimiter.

StringSplit["string",{p1v1,…}]

inserts vi at the position of each delimiter pi.

StringSplit["string",patt,n]

splits into at most n substrings.

StringSplit[{s1,s2,…},p]

gives the list of results for each of the si.

Details and Options

  • StringSplit[s] does not return the whitespace characters that delimit the substrings it returns.
  • Whitespace includes any number of spaces, tabs, and newlines.
  • The string expression patt can contain any of the objects specified in the notes for StringExpression.
  • StringSplit[s] is equivalent to StringSplit[s,Whitespace].
  • If s contains two adjacent delimiters, StringSplit considers there to be a zero‐length substring "" between them.
  • StringSplit[s,patt] by default gives the list of substrings of s that occur between delimiters defined by patt; it does not include the delimiters themselves.
  • StringSplit[s,patt->val] includes val at the position of each delimiter.
  • StringSplit[s,patt:>val] evaluates val only when the pattern is found.
  • StringSplit["string",{p1->v1,…,pa,…}] includes v1 at the position of delimiters matching p1, but omits delimiters matching pa.
  • By default, StringSplit[s,patt] drops zero‐length substrings associated with delimiters that appear at the beginning or end of s.
  • StringSplit[s,patt,All] returns all substrings, including zero‐length ones at the beginning or end.
  • StringSplit takes the following option:
  • IgnoreCase Falsewhether to turn off case-sensitive matching
  • Setting the option IgnoreCase->True makes StringSplit treat lowercase and uppercase letters as equivalent.
  • StringSplit["string",RegularExpression["regex"]] splits at delimiters matching the specified regular expression.
  • StringSplit[BioSequence["type","seq"],patt,…] will split the string "seq" by patt yielding a list of biomolecular sequences. In this case, degenerate letters in patt are interpreted as wildcard patterns based on the type of biomolecular sequence. Use Verbatim["patt"] to match degenerate letters literally.
  • The documentation for BioSequence lists the degenerate letters supported by each type of biomolecular sequence.

Examples

open all close all

Basic Examples  (2)

Pick out substrings delimited by whitespace:

Wolfram Language code: StringSplit["a bbb cccc aa d"]

Show the substrings with quotes:

Wolfram Language code: InputForm[%]

Split a string at every --:

Wolfram Language code: StringSplit["a--bbb---ccc--dddd", "--"]

Scope  (11)

Split at every run of spaces:

Wolfram Language code: StringSplit["the cat in the hat"]

Use string patterns:

Wolfram Language code: StringSplit["192.168.0.1", "."]
Wolfram Language code: StringSplit["123 2.3 4 6", WhitespaceCharacter..]
Wolfram Language code: StringSplit["11a22b3", _ ? LetterQ]

Regular expressions:

Wolfram Language code: StringSplit["A tree, an apple, four pears. And more: two sacks", RegularExpression["\\W+"]]

Mixed regular expressions and string patterns:

Wolfram Language code: StringSplit["primes: 2 two 3 three 5 five ...", Whitespace ~~ RegularExpression["\\d"] ~~ Whitespace]

Split into substrings separated by either delimiter:

Wolfram Language code: StringSplit["a-b:c-d:e-f-g", {":", "-"}]
Wolfram Language code: StringSplit["a-b:c-d:e-f-g", ":" | "-"]

Insert a value at the position of a delimiter:

Wolfram Language code: StringSplit["a b::c d::e f g", "::" -> "--"]

Include the delimiters in the output:

Wolfram Language code: StringSplit["a--b c--d e", x : "--" :> x]

StringSplit automatically threads over lists of strings:

Wolfram Language code: StringSplit[{"a:b:c:d", "listable:element"}, ":"]

Split a DNA sequence by a particular substring:

Wolfram Language code: StringSplit[BioSequence["DNA", "GATGGCAAGGCAG"], "GGC"]

Use a wildcard in the pattern to split the biomolecular sequence:

Wolfram Language code: StringSplit[BioSequence["DNA", "GATGGCAAGGNAG"], "GGN"]

The "N" is a degenerate letter only in biomolecular sequences:

Wolfram Language code: StringSplit["GATGGCAAGGNAG", "GGN"]

Split only on literal degenerate letters using Verbatim:

Wolfram Language code: StringSplit[BioSequence["DNA", "GATGGCAAGGNAG"], "GG" ~~ Verbatim["N"]]

Generalizations & Extensions  (1)

All substrings, including zero‐length ones at the beginning or end:

Wolfram Language code: StringSplit[":a:b:c:", ":", All]
Wolfram Language code: InputForm[%]

Options  (1)

IgnoreCase  (1)

Split a string at every "c", including uppercase letters:

Wolfram Language code: StringSplit["cat Cat hat CAT", "c", IgnoreCase -> True]

Applications  (4)

Make a nested array by applying StringSplit twice:

Wolfram Language code: StringSplit[StringSplit["11:12:13//21:22:23//31:32:33", "//"], ":"]

A base random DNA string:

Wolfram Language code: SeedRandom[1234]; dna = StringJoin[RandomChoice[{"a", "c", "g", "t"}, 500]];

Sequences with adenine symmetrically placed:

Wolfram Language code: StringSplit[dna, x : ("a" ~~ y_ ~~ _ ~~ y_ ~~ "a") :> Style[x, FontColor -> Red]] //Row

Text analysis with some right and left context:

Wolfram Language code: text = Import["ExampleData/USConstitution.txt"];

Use StringSplit to find all occurrences of the word "power":

Wolfram Language code: a = StringSplit[text, "power", 10];

Compute part of the left and right contexts in which each word occurs:

Wolfram Language code: Apply[Row[{"…", StringTake[#1, -Min[15, StringLength[#1]]], Style["power", Blue], StringTake[#2, Min[15, StringLength[#2]]], "…"}]&, Partition[a, 2, 1], {1}]//Column

List extensions of files in a directory and its subdirectories:

Wolfram Language code: SetDirectory[$InstallationDirectory];
Wolfram Language code: files = FileNames["@.*", {"*"}, Infinity];
Wolfram Language code: Union[Last[StringSplit[#, "."]] & /@ files]

Properties & Relations  (4)

Splitting at whitespace is equivalent to cases of non-whitespace sequences:

Wolfram Language code: StringSplit["a bbb cccc aa d"]
Wolfram Language code: StringCases["a bbb cccc aa d", Except[WhitespaceCharacter]..]

StringSplit with a rule is equivalent to StringReplace:

Wolfram Language code: StringJoin[StringSplit["ab::c::d::ef", "::" -> "X"]]
Wolfram Language code: StringReplace["ab::c::d::ef", "::" -> "X"]

A null delimiter splits at every character:

Wolfram Language code: StringSplit["abcdefg", ""]
Wolfram Language code: Characters["abcdefg"]

Using StringSplit on a comma-separated values string:

Wolfram Language code: StringSplit[StringSplit["123, 2.3, 45. 345, 1.4, 450", " "], ","]//ToExpression

In many cases Import and ImportString provide direct functionality:

Wolfram Language code: ImportString["123, 2.3, 45. 345, 1.4, 450", "CSV"]

Possible Issues  (1)

StringSplit by default splits only at whitespace:

Wolfram Language code: StringSplit["This is a sentence--which goes on."]

This splits into words:

Wolfram Language code: StringSplit["This is a sentence, which goes on.", Except[WordCharacter]..]

Another way to split into words:

Wolfram Language code: StringCases["This is a sentence, which goes on.", WordCharacter..]
Wolfram Research (2004), StringSplit, Wolfram Language function, https://reference.wolfram.com/language/ref/StringSplit.html (updated 2020).

Text

Wolfram Research (2004), StringSplit, Wolfram Language function, https://reference.wolfram.com/language/ref/StringSplit.html (updated 2020).

CMS

Wolfram Language. 2004. "StringSplit." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/StringSplit.html.

APA

Wolfram Language. (2004). StringSplit. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StringSplit.html

BibTeX

@misc{reference.wolfram_2026_stringsplit, author="Wolfram Research", title="{StringSplit}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/StringSplit.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_stringsplit, organization={Wolfram Research}, title={StringSplit}, year={2020}, url={https://reference.wolfram.com/language/ref/StringSplit.html}, note=[Accessed: 12-June-2026]}