WOLFRAM

Wolfram Language & System Documentation Center

StruveH[n,z]

gives the Struve function TemplateBox[{n, z}, StruveH].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Integral Transforms  
Function Identities and Simplifications  
Function Representations  
Generalizations & Extensions  
Applications  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

StruveH

StruveH[n,z]

gives the Struve function TemplateBox[{n, z}, StruveH].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{n, z}, StruveH] for integer n satisfies the differential equation .
  • StruveH[n,z] has a branch cut discontinuity in the complex plane running from to .
  • For certain special arguments, StruveH automatically evaluates to exact values.
  • StruveH can be evaluated to arbitrary numerical precision.
  • StruveH automatically threads over lists.

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: StruveH[0, 5.2]

Plot :

Wolfram Language code: Plot[StruveH[0, x], {x, 0, 50}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[StruveH[2, z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[StruveH[0, x], {x, 0, 10}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[StruveH[0, x], {x, ∞, 3}]//Normal//FullSimplify

Scope  (43)

Numerical Evaluation  (6)

Evaluate numerically to high precision:

Wolfram Language code: N[StruveH[0, 4], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: StruveH[0, 4.000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: StruveH[7 / 3 + I, 4.5 - I]

Evaluate StruveH efficiently at high precision:

Wolfram Language code: StruveH[0, 1.2`500]//Timing
Wolfram Language code: StruveH[0, 1.2`10000];//Timing

StruveH threads elementwise over lists:

Wolfram Language code: StruveH[1, {0.5, 1.0, 1.5}]

Compute average-case statistical intervals using Around:

Wolfram Language code: StruveH[2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: StruveH[.2, {{1, 2}, {3, 4}}]

Or compute the matrix StruveH function using MatrixFunction:

Wolfram Language code: MatrixFunction[StruveH[.2, #]&, {{1, 2}, {3, 4}}]

Specific Values  (4)

For half-integer indices, StruveH evaluates to elementary functions:

Wolfram Language code: StruveH[1 / 2, x]

Limiting values at infinity:

Wolfram Language code: Limit[{StruveH[0, x], StruveH[1, x], StruveH[2, x]}, x -> Infinity]

Value of TemplateBox[{{1, /, 2}, z}, StruveH] at a complex infinity is indeterminate:

Wolfram Language code: StruveH[1 / 2, ComplexInfinity]

Find a zero of TemplateBox[{0, x}, StruveH]:

Wolfram Language code: xzero = Solve[StruveH[0, x] == 0 && 4.0 < x < 5.0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[StruveH[0, x], {x, 0, 10}, Epilog -> Style[Point[{xzero, StruveH[0, xzero]}], PointSize[Large], Red]]

Visualization  (5)

Plot the StruveH function for :

Wolfram Language code: Plot[{StruveH[0, x], StruveH[1, x], StruveH[2, x], StruveH[3, x], StruveH[4, x], StruveH[5, x]}, {x, -8, 8}]

Plot the StruveH function for negative integer values of :

Wolfram Language code: Plot[{StruveH[-3, x], StruveH[-2, x], StruveH[-1, x]}, {x, -10, 10}]

Plot the StruveH function for half-integer values of :

Wolfram Language code: Plot[{StruveH[-5 / 2, x], StruveH[-3 / 2, x], StruveH[-1 / 2, x], StruveH[1 / 2, x], StruveH[3 / 2, x], StruveH[5 / 2, x]}, {x, 0, 10}, IconizedObject[«PlotOptions»]]

Plot the real part of TemplateBox[{0, z}, StruveH]:

Wolfram Language code: ComplexContourPlot[Re[StruveH[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{0, z}, StruveH]:

Wolfram Language code: ComplexContourPlot[Im[StruveH[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the real part of TemplateBox[{{-, 3}, z}, StruveH]:

Wolfram Language code: ComplexContourPlot[Re[StruveH[-3, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{{-, 3}, z}, StruveH]:

Wolfram Language code: ComplexContourPlot[Im[StruveH[-3, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Function Properties  (9)

Function domain of StruveH for half-integer :

Wolfram Language code: {FunctionDomain[StruveH[1 / 2, x], x], FunctionDomain[StruveH[3 / 2, x], x], FunctionDomain[StruveH[5 / 2, x], x]}

Complex domain:

Wolfram Language code: {FunctionDomain[StruveH[1 / 2, z], z, Complexes], FunctionDomain[StruveH[3 / 2, z], z, Complexes], FunctionDomain[StruveH[5 / 2, z], z, Complexes]}

Approximate function range of TemplateBox[{{-, {1, /, 2}}, x}, StruveH]:

Wolfram Language code: FunctionRange[StruveH[-1 / 2, x], x, y]//N

Function range of TemplateBox[{{5, /, 2}, x}, StruveH]:

Wolfram Language code: FunctionRange[StruveH[5 / 2, x], x, y]

Parity:

Wolfram Language code: StruveH[n, -x]//FunctionExpand

TemplateBox[{{1, /, 3}, x}, StruveH] is analytic in the interior of its real domain:

Wolfram Language code: FunctionAnalytic[{StruveH[1 / 3, x], x > 0}, x]

It is not analytic everywhere, as it has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[StruveH[1 / 3, x], x]
Wolfram Language code: FunctionDiscontinuities[StruveH[1 / 3, x], x]

TemplateBox[{{1, /, 3}, x}, StruveH] is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[{StruveH[1 / 3, x], x >= 0}, x]

TemplateBox[{{1, /, 3}, x}, StruveH] is not injective:

Wolfram Language code: FunctionInjective[StruveH[1 / 3, x], x]
Wolfram Language code: Plot[{StruveH[1 / 3, x], .5}, {x, 0, 20}]

TemplateBox[{{1, /, 2}, x}, StruveH] is not surjective:

Wolfram Language code: FunctionSurjective[StruveH[1 / 2, x], x]
Wolfram Language code: Plot[{StruveH[1 / 2, x], -1}, {x, 0, 25}]

TemplateBox[{{1, /, 3}, x}, StruveH] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[{StruveH[1 / 3, x], x >= 0}, x]

TemplateBox[{{1, /, 3}, x}, StruveH] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[{StruveH[1 / 3, x], x >= 0}, x]

Differentiation  (3)

First derivative:

Wolfram Language code: D[StruveH[n, z], z]

Higher derivatives:

Wolfram Language code: derivs = Table[D[StruveH[n, x], {x, k}], {k, 1, 3}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. n -> 1 / 2], {x, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative:

Wolfram Language code: D[StruveH[n, x], {x, k}]

Integration  (4)

Indefinite integral:

Wolfram Language code: Integrate[StruveH[n, x], x]

Definite integral of StruveH:

Wolfram Language code: Integrate[StruveH[n, x], {x, 0, Infinity}, Assumptions -> {-2 < n < 0}]

Definite integral of the odd integrand TemplateBox[{0, x}, StruveH] over an interval centered at the origin is 0:

Wolfram Language code: Integrate[StruveH[0, x], {x, -1, 1}]

Definite integral of the even integrand TemplateBox[{1, x}, StruveH] over an interval centered at the origin:

Wolfram Language code: Integrate[StruveH[1, x], {x, -1, 1}]

This is twice the integral over half the interval:

Wolfram Language code: 2 Integrate[StruveH[1, x], {x, 0, 1}]//Expand

Series Expansions  (4)

Taylor expansion for TemplateBox[{0, x}, StruveH]:

Wolfram Language code: Series[StruveH[0, x], {x, 0, 7}]

Plot the first three approximations for TemplateBox[{0, x}, StruveH] around :

Wolfram Language code: terms = Normal@Table[Series[StruveH[0, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{StruveH[0, x], terms}, {x, -3, 3}]

General term in the series expansion of TemplateBox[{0, x}, StruveH]:

Wolfram Language code: SeriesCoefficient[StruveH[0, x], {x, 0, n}]

Series expansion of StruveH at infinity:

Wolfram Language code: Series[StruveH[n, x], {x, Infinity, 1}]//FullSimplify

StruveH can be applied to a power series:

Wolfram Language code: Assuming[x > 0, StruveH[0, Log[1 + x] + O[x] ^ 10]]

Integral Transforms  (2)

Compute the Hankel transform using HankelTransform:

Wolfram Language code: HankelTransform[StruveH[n, r], r, s]

Mellin transform for TemplateBox[{0, x}, StruveH] using MellinTransform:

Wolfram Language code: MellinTransform[StruveH[0, x], x, s]

Function Identities and Simplifications  (2)

Argument simplifications:

Wolfram Language code: StruveH[n, I z]//FunctionExpand
Wolfram Language code: StruveH[n, Sqrt[z^2]]//FunctionExpand

Recurrence relation:

Wolfram Language code: StruveH[n, z] == (2 (n + 1)/z) StruveH[n + 1, z] - StruveH[n + 2, z] + (2^-1 - n z^n + 1/Sqrt[π] Gamma[(5/2) + n])//FullSimplify

Function Representations  (4)

Series representation:

Wolfram Language code: ((z/2))^(n + 1)Sum[((-1)^k/Gamma[k + (3/2)]Gamma[k + n + (3/2)])((z/2))^2k, {k, 0, Infinity}]//FullSimplify

Representation in terms of StruveL:

Wolfram Language code: I z^n (-I z)^-n StruveL[n, -I z]//FullSimplify

StruveH can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[StruveH[n, x], x]
Wolfram Language code: Activate[%]//Simplify

TraditionalForm formatting:

Wolfram Language code: StruveH[n, x]//TraditionalForm

Generalizations & Extensions  (1)

StruveH can be applied to a power series:

Wolfram Language code: StruveH[0, Log[1 + x] + O[x] ^ 10]

Applications  (2)

Solve the inhomogeneous Bessel differential equation:

Wolfram Language code: DSolve[x^2y''[x] + x y'[x] + (x ^ 2 - 1)y[x] == (2/π)x ^ 2, y[x], x]

The diffraction pattern from an infinitely long line source by a circular aperture:

Wolfram Language code: LogPlot[3Pi / (8x ^ 2) StruveH[1, 2x], {x, -30, 30}, MaxRecursion -> 1]
Wolfram Research (1999), StruveH, Wolfram Language function, https://reference.wolfram.com/language/ref/StruveH.html.

Text

Wolfram Research (1999), StruveH, Wolfram Language function, https://reference.wolfram.com/language/ref/StruveH.html.

CMS

Wolfram Language. 1999. "StruveH." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/StruveH.html.

APA

Wolfram Language. (1999). StruveH. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StruveH.html

BibTeX

@misc{reference.wolfram_2026_struveh, author="Wolfram Research", title="{StruveH}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/StruveH.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_struveh, organization={Wolfram Research}, title={StruveH}, year={1999}, url={https://reference.wolfram.com/language/ref/StruveH.html}, note=[Accessed: 13-June-2026]}