WOLFRAM

Wolfram Language & System Documentation Center

StruveL[n,z]

gives the modified Struve function TemplateBox[{n, z}, StruveL].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Integral Transforms  
Function Identities and Simplifications  
Function Representations  
Generalizations & Extensions  
Applications  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

StruveL

StruveL[n,z]

gives the modified Struve function TemplateBox[{n, z}, StruveL].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{n, z}, StruveL] for integer is related to the ordinary Struve function by TemplateBox[{n, {i, , z}}, StruveL]=-ie^(-inpi/2)TemplateBox[{n, z}, StruveH].
  • StruveL[n,z] has a branch cut discontinuity in the complex plane running from to .
  • For certain special arguments, StruveL automatically evaluates to exact values.
  • StruveL can be evaluated to arbitrary numerical precision.
  • StruveL automatically threads over lists.

Examples

open all close all

Basic Examples  (5)

Evaluate numerically:

Wolfram Language code: StruveL[0, 2.5]

Plot :

Wolfram Language code: Plot[StruveL[0, x], {x, 0, 5}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[StruveL[2, z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[StruveL[0, x], {x, 0, 10}]

Asymptotic expansion at Infinity:

Wolfram Language code: Series[StruveL[0, x], {x, ∞, 3}]//Normal//Simplify

Scope  (42)

Numerical Evaluation  (6)

Evaluate numerically to high precision:

Wolfram Language code: N[StruveL[0, 4], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: StruveL[0, 4.000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: StruveL[7 / 3 + I, 4.5 - I]

Evaluate StruveL efficiently at high precision:

Wolfram Language code: StruveL[0, 1.2`500]//Timing
Wolfram Language code: StruveL[0, 1.2`10000];//Timing

StruveL threads elementwise over lists:

Wolfram Language code: StruveL[1, {0.5, 1.0, 1.5}]

Compute average-case statistical intervals using Around:

Wolfram Language code: StruveL[2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: StruveL[.2, {{1, 2}, {3, 4}}]

Or compute the matrix StruveL function using MatrixFunction:

Wolfram Language code: MatrixFunction[StruveL[.2, #]&, {{1, 2}, {3, 4}}]

Specific Values  (4)

For half-integer indices, StruveL evaluates to elementary functions:

Wolfram Language code: StruveL[1 / 2, x]

Value of TemplateBox[{{1, /, 2}, z}, StruveL] at a complex infinity is indeterminate:

Wolfram Language code: StruveL[1 / 2, ComplexInfinity]

Limiting value at infinity:

Wolfram Language code: Limit[StruveL[n, x], x -> Infinity]

Find a root of TemplateBox[{0, x}, StruveL]=1:

Wolfram Language code: f[x_] := StruveL[0, x] - 1;
Wolfram Language code: xzero = Solve[f[x] == 0 && 1.0 < x < 2.0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[x], {x, 0, 3}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Visualization  (4)

Plot the StruveL function for integer :

Wolfram Language code: Plot[{StruveL[-3, x], StruveL[-2, x], StruveL[-1, x], StruveL[0, x], StruveL[1, x], StruveL[2, x]}, {x, -4, 4}]

Plot the StruveL function for half-integer values of :

Wolfram Language code: Plot[{StruveL[-1 / 2, x], StruveL[1 / 2, x], StruveL[3 / 2, x]}, {x, 0, 3}]

Plot the real part of TemplateBox[{0, z}, StruveL]:

Wolfram Language code: ComplexContourPlot[Re[StruveL[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{0, z}, StruveL]:

Wolfram Language code: ComplexContourPlot[Im[StruveL[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the real part of TemplateBox[{{-, 3}, z}, StruveL]:

Wolfram Language code: ComplexContourPlot[Re[StruveL[-3, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{{-, 3}, z}, StruveL]:

Wolfram Language code: ComplexContourPlot[Im[StruveL[-3, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Function Properties  (9)

Function domain of StruveL for half-integer :

Wolfram Language code: {FunctionDomain[StruveL[-1 / 2, x], x], FunctionDomain[StruveL[1 / 2, x], x], FunctionDomain[StruveL[3 / 2, x], x]}

Complex domain:

Wolfram Language code: {FunctionDomain[StruveL[1 / 2, z], z, Complexes], FunctionDomain[StruveL[3 / 2, z], z, Complexes], FunctionDomain[StruveL[5 / 2, z], z, Complexes]}

Approximate function range of StruveL for half-integer values of :

Wolfram Language code: {FunctionRange[StruveL[1 / 2, x], x, y], FunctionRange[StruveL[3 / 2, x], x, y], FunctionRange[StruveL[5 / 2, x], x, y]}

Parity:

Wolfram Language code: StruveL[n, -x]//FunctionExpand

TemplateBox[{{1, /, 3}, x}, StruveL] is analytic in the interior of its real domain:

Wolfram Language code: FunctionAnalytic[{StruveL[1 / 3, x], x > 0}, x]

It is not analytic everywhere, as it has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[StruveL[1 / 3, x], x]
Wolfram Language code: FunctionDiscontinuities[StruveL[1 / 3, x], x]

TemplateBox[{{1, /, 2}, x}, StruveL] is nondecreasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{StruveL[1 / 2, x], x > 0}, x]

TemplateBox[{{1, /, 3}, x}, StruveL] is injective:

Wolfram Language code: FunctionInjective[StruveL[1 / 3, x], x]
Wolfram Language code: Plot[{StruveL[1 / 3, x], 20}, {x, 0, 7}]

TemplateBox[{{1, /, 2}, x}, StruveL] is not surjective:

Wolfram Language code: FunctionSurjective[StruveL[1 / 2, x], x]
Wolfram Language code: Plot[{StruveL[1 / 2, x], -2}, {x, -1, 5}]

TemplateBox[{{1, /, 2}, x}, StruveL] is non-negative on its real domain:

Wolfram Language code: FunctionSign[{StruveL[1 / 2, x], x > 0}, x]

TemplateBox[{{1, /, 2}, x}, StruveL] is convex on its real domain:

Wolfram Language code: FunctionConvexity[{StruveL[1 / 2, x], x > 0}, x]

Differentiation  (3)

First derivative:

Wolfram Language code: D[StruveL[n, z], z]

Higher derivatives:

Wolfram Language code: derivs = Table[D[StruveL[n, x], {x, k}], {k, 1, 3}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. n -> 1 / 2], {x, 0, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative:

Wolfram Language code: D[StruveL[n, x], {x, k}]

Integration  (4)

Indefinite integral:

Wolfram Language code: Integrate[StruveL[n, x], x]

Definite integral:

Wolfram Language code: Integrate[Exp[-x]StruveL[n, x] / x, {x, 0, Infinity}, Assumptions -> Re[n] > -1]

Definite integral of the odd integrand TemplateBox[{0, x}, StruveL] over an interval centered at the origin is 0:

Wolfram Language code: Integrate[StruveL[0, x], {x, -1, 1}]

Definite integral of the even integrand TemplateBox[{1, x}, StruveL] over an interval centered at the origin:

Wolfram Language code: Integrate[StruveL[1, x], {x, -1, 1}]

This is twice the integral over half the interval:

Wolfram Language code: 2 Integrate[StruveL[1, x], {x, 0, 1}]//Expand

Series Expansions  (4)

Taylor expansion for TemplateBox[{1, x}, StruveL]:

Wolfram Language code: Series[StruveH[1, x], {x, 0, 10}]

Plot the first three approximations for TemplateBox[{1, x}, StruveL] around :

Wolfram Language code: terms = Normal@Table[Series[StruveL[1, x], {x, 0, m}], {m, 2, 6, 2}]; Plot[{StruveL[1, x], terms}, {x, -5, 5}]

General term in the series expansion of TemplateBox[{1, x}, StruveL]:

Wolfram Language code: SeriesCoefficient[StruveL[1, x], {x, 0, n}]

Series expansion of StruveL at infinity:

Wolfram Language code: Series[StruveL[n, x], {x, Infinity, 1}]//FullSimplify

StruveL can be applied to a power series:

Wolfram Language code: Assuming[x > 0, StruveL[1 / 3, Log[1 + x] + O[x] ^ 3]]

Integral Transforms  (2)

Compute the Laplace transform using LaplaceTransform:

Wolfram Language code: LaplaceTransform[StruveL[n, t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[StruveL[n, r], r, s]

Function Identities and Simplifications  (2)

Argument simplifications:

Wolfram Language code: StruveL[n, I z]//FunctionExpand
Wolfram Language code: StruveL[n, Sqrt[z^2]]//FunctionExpand

Recurrence relation:

Wolfram Language code: StruveL[n, z] == (2 (n + 1)/z) StruveL[n + 1, z] + StruveL[n + 2, z] + (2^-1 - n z^n + 1/Sqrt[π] Gamma[(5/2) + n])//FullSimplify

Function Representations  (4)

Series representation:

Wolfram Language code: ((z/2))^(n + 1)Sum[(1/Gamma[k + (3/2)]Gamma[k + n + (3/2)])((z/2))^2k, {k, 0, Infinity}]//FullSimplify

Representation in terms of StruveH:

Wolfram Language code: StruveL[n, z] == I z^n(-I z )^-n StruveH[n, -I z]//FullSimplify

StruveL can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[StruveL[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm formatting:

Wolfram Language code: StruveL[n, x]//TraditionalForm

Generalizations & Extensions  (1)

StruveL can be applied to a power series:

Wolfram Language code: StruveL[1 / 3, Log[1 + x] + O[x] ^ 2]

Applications  (3)

Solve the inhomogeneous Bessel differential equation:

Wolfram Language code: DSolve[x^2y''[x] + x y'[x] - (x ^ 2 + 1)y[x] == (2/π)x ^ 2, y[x], x]

3D relativistic, non-Markovian transition PDF that has the Gaussian non-relativistic limit:

Wolfram Language code: p[t_, x_, y_, z_] := 𝒩 HeavisideTheta[t - Sqrt[x ^ 2 + y ^ 2 + z ^ 2]] Exp[Sqrt[t ^ 2 - x ^ 2 - y ^ 2 - z ^ 2] / (2 σ)]

Its normalization is computed after a change of variables :

Wolfram Language code: 4 π 𝒩 t^3 Integrate[Cos[ϕ]Sin[ϕ]^2Exp[(t/2σ)Cos[ϕ]], {ϕ, 0, π / 2}]//FunctionExpand//Simplify

The mean saddle order in the mean-field -trigonometric model as a function of temperature:

Wolfram Language code: Plot[(1/2)(1 - StruveL[0, 5 / t] / BesselI[0, 5 / t]), {t, 0.1, 20}]
Wolfram Research (1999), StruveL, Wolfram Language function, https://reference.wolfram.com/language/ref/StruveL.html.

Text

Wolfram Research (1999), StruveL, Wolfram Language function, https://reference.wolfram.com/language/ref/StruveL.html.

CMS

Wolfram Language. 1999. "StruveL." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/StruveL.html.

APA

Wolfram Language. (1999). StruveL. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/StruveL.html

BibTeX

@misc{reference.wolfram_2026_struvel, author="Wolfram Research", title="{StruveL}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/StruveL.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_struvel, organization={Wolfram Research}, title={StruveL}, year={1999}, url={https://reference.wolfram.com/language/ref/StruveL.html}, note=[Accessed: 13-June-2026]}