WOLFRAM

Wolfram Language & System Documentation Center

TimeSeriesModel[…]

represents the symbolic time series model obtained from TimeSeriesModelFit.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
ConfidenceLevel  
"LagMax"  
See Also
Related Guides
History
Cite this Page

TimeSeriesModel

TimeSeriesModel[…]

represents the symbolic time series model obtained from TimeSeriesModelFit.

Details and Options

  • Properties of a time series model are obtained from TimeSeriesModel[…]["property"].
  • The value of the model at time t can be obtained by giving model[t]. If t is in the range of the input data, then the data at time t is returned; otherwise, a forecasted value is given.
  • Forecast prediction limits at a time t can be obtained using model["PredictionLimits"][t].
  • Normal gives the underlying time series process for the time series model.
  • TimeSeriesModel[…][prop,ann] gives the annotation ann associated with the property prop.
  • Possible time series model properties are listed on the page for TimeSeriesModelFit.
  • TimeSeriesModel takes the following options:
  • ConfidenceLevel 95/100confidence level to use »
    "LagMax" 10maximum lag number for autocorrelation and partial correlation values and Ljug-Box test -values and plot range »

Examples

open all close all

Basic Examples  (1)

Create a TimeSeriesModel from some data:

Wolfram Language code: data = RandomFunction[ARMAProcess[{.1}, {.2}, 1], {1, 10 ^ 4}];
Wolfram Language code: mod = TimeSeriesModelFit[data]

Extract a property from the model:

Wolfram Language code: mod["AIC"]

Evaluate the time series model at time 100:

Wolfram Language code: mod[100]

Use Normal to obtain the underlying time series process:

Wolfram Language code: Normal[mod]

Obtain a list of available properties:

Wolfram Language code: mod["Properties"]

Scope  (7)

Extract a property from a TimeSeriesModel:

Wolfram Language code: mod = TimeSeriesModelFit[RandomReal[{-1, 1}, 10 ^ 4]]

The BIC value for the model:

Wolfram Language code: mod["BIC"]

Obtain a list of properties:

Wolfram Language code: mod = TimeSeriesModelFit[RandomReal[{-1, 1}, 10 ^ 4]]
Wolfram Language code: mod[{"AIC", "BIC"}]

Evaluate the time series model at a point:

Wolfram Language code: mod = TimeSeriesModelFit[RandomReal[{-1, 1}, 100]];
Wolfram Language code: mod[102]

Map over several points:

Wolfram Language code: mod /@ {1, 2, 3, 4}

Evaluate the time series model at a date:

Wolfram Language code: mod = TimeSeriesModelFit[TemporalData[RandomReal[{-1, 1}, 100], {"January 24 1982", Automatic, "Month"}]];
Wolfram Language code: mod["March 15th 1989"]

Obtain the underlying time series process:

Wolfram Language code: mod = TimeSeriesModelFit[RandomReal[{-1, 1}, 100]];
Wolfram Language code: Normal[mod]

Annotate a property:

Wolfram Language code: mod = TimeSeriesModelFit[RandomFunction[ARMAProcess[{.1}, {.2}, 1], {1, 10 ^ 4}]];
Wolfram Language code: propAnnotate[p_] := (Column[Join[{Row[{"Property: ", #1}]}, Table[Row[{i, ": ", mod[#1, i]}], {i, {"Description", "LongDescription", "Value"}}]]]&)[p]
Wolfram Language code: propAnnotate["BestFit"]

Use the original data to simulate future observations with TimeSeriesModel:

Wolfram Language code: data = TemporalData[RandomFunction[ARProcess[{.8}, 1], {100}]["Values"], {"January 24 1982", Automatic, "Month"}]

Fit a model using TimeSeriesModelFit:

Wolfram Language code: model = TimeSeriesModelFit[data]

Use the best fit process to simulate 10 future observations:

Wolfram Language code: process = model["Process"]

No information about time stamps or initial values is passed to RandomFunction:

Wolfram Language code: SeedRandom["TSM"];BlockRandom[sim1 = RandomFunction[process, {10}, 4]]

Simulate using TimeSeriesModel to use information given by the original data:

Wolfram Language code: SeedRandom["TSM"];BlockRandom[sim2 = RandomFunction[model, {10}, 4]]
Wolfram Language code: {ListLinePlot[sim1], DateListPlot[sim2]}

Options  (3)

ConfidenceLevel  (1)

Set the confidence level to use for prediction limits:

Wolfram Language code: ts = RandomFunction[ARIMAProcess[{.1}, 2, {.2}, 1], {1, 150}];
Wolfram Language code: ListLinePlot[ts]

Use a 90% confidence level:

Wolfram Language code: tsm = TimeSeriesModelFit[ts];tsm["PredictionLimits", ConfidenceLevel -> .9][155]

The confidence level can be set before fitting:

Wolfram Language code: tsm = TimeSeriesModelFit[ts, ConfidenceLevel -> .9]
Wolfram Language code: tsm["PredictionLimits"][155]

The default confidence level is 95%:

Wolfram Language code: Table[TimeSeriesModelFit[ts]["PredictionLimits"][k], {k, 1, 155}] === Table[TimeSeriesModelFit[ts]["PredictionLimits", ConfidenceLevel -> .95][k], {k, 1, 155}]

"LagMax"  (2)

Obtain values used in residual whiteness diagnostic plots:

Wolfram Language code: mod = TimeSeriesModelFit[TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {}}, False, 10.], {"ARMA", {2, 1}}];
Wolfram Language code: Row[mod[#]& /@ {"ACFPlot", "PACFPlot", "LjungBoxPlot"}]

The first 5 autocorrelation values and 95% confidence region used in the "ACFPlot":

Wolfram Language code: mod["ACFValues", "LagMax" -> 5]

The first 5 partial autocorrelation values and 95% confidence region used in the "PACFPlot":

Wolfram Language code: mod["PACFValues", "LagMax" -> 5]

The Ljung–Box -values for lags 1 to 12 and the critical value used in the plot:

Wolfram Language code: mod["LjungBoxValues", "LagMax" -> 12]

Test model residuals for autocorrelation:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-0.7935061667730144, 4.3778286773763035, 2.922958541001586, 1.9853580784609617, 1.147308854130249, 1.698080426822207, 0.008331318340714766, 0.10200160157297689, 2.2513707375476235, 0.8328655174414309, -2.378076 ... 761350230830915, 2.4578396008405163, -0.9273117800247228, 0.3871528084319487, 1.0557919551990362, 1.8934299378382737, 3.913518335425615, 1.3010389634021429}}, {{1, 10000, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {}}, False, 10.];
Wolfram Language code: tsm = TimeSeriesModelFit[ts, {"ARMA", {2, 1}}];

Plot the results of Ljung-Box test:

Wolfram Language code: tsm["LjungBoxPlot"]

Change the maximum lag in Ljung-Box test:

Wolfram Language code: tsm["LjungBoxPlot", "LagMax" -> 15]
Wolfram Research (2014), TimeSeriesModel, Wolfram Language function, https://reference.wolfram.com/language/ref/TimeSeriesModel.html.

Text

Wolfram Research (2014), TimeSeriesModel, Wolfram Language function, https://reference.wolfram.com/language/ref/TimeSeriesModel.html.

CMS

Wolfram Language. 2014. "TimeSeriesModel." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TimeSeriesModel.html.

APA

Wolfram Language. (2014). TimeSeriesModel. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TimeSeriesModel.html

BibTeX

@misc{reference.wolfram_2026_timeseriesmodel, author="Wolfram Research", title="{TimeSeriesModel}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/TimeSeriesModel.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_timeseriesmodel, organization={Wolfram Research}, title={TimeSeriesModel}, year={2014}, url={https://reference.wolfram.com/language/ref/TimeSeriesModel.html}, note=[Accessed: 15-June-2026]}