WOLFRAM

Wolfram Language & System Documentation Center

Tr[list]

finds the trace of the matrix or tensor list.

Tr[list,f]

finds a generalized trace, combining terms with f instead of Plus.

Tr[list,f,n]

goes down to level n in list.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

Tr

Tr[list]

finds the trace of the matrix or tensor list.

Tr[list,f]

finds a generalized trace, combining terms with f instead of Plus.

Tr[list,f,n]

goes down to level n in list.

Details

  • Tr[list] sums the diagonal elements list[[i,i,…]].
  • Tr works for rectangular as well as square matrices and tensors.
  • Tr can be used on SparseArray objects. »

Examples

open all close all

Basic Examples  (1)

The trace of a matrix is the sum of the diagonal elements:

Wolfram Language code: Tr[(⁠| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 | | 7 | 8 | 9 |⁠)]

Scope  (2)

Symbolic trace:

Wolfram Language code: Tr[{{a, b}, {c, d}}]

Trace of a numerical matrix:

Wolfram Language code: Tr[RandomReal[1, {100, 100}]]

Trace of a sparse matrix:

Wolfram Language code: Tr[SparseArray[{i_, j_} /; Abs[i - j] ≤ 1 -> j / i, {40, 40}]]

Generalizations & Extensions  (6)

For a vector Tr gives the sum of the elements:

Wolfram Language code: Tr[{1, 2, 3}]

For a higher‐rank tensor, Tr gives the sum of elements with equal indices:

Wolfram Language code: Tr[Array[a, {4, 3, 2}]]

Apply a function to the diagonal elements of a matrix:

Wolfram Language code: Tr[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, f]

Extract the diagonal of a matrix as a list:

Wolfram Language code: Tr[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, List]

Only consider down to level 1; this adds the rows of the matrix:

Wolfram Language code: Tr[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, Plus, 1]

Only consider down to level 2:

Wolfram Language code: Tr[Array[a, {4, 3, 2}], f, 2]

Applications  (2)

Find the determinant of a triangular matrix:

Wolfram Language code: Tr[{{1, 2, 3}, {0, 4, 5}, {0, 0, 6}}, Times]
Wolfram Language code: Det[{{1, 2, 3}, {0, 4, 5}, {0, 0, 6}}]

Define an inner product for the cone of positive definite matrices using :

Wolfram Language code: traceProduct[a_, b_] := Tr[a.b]
Wolfram Language code: a = RandomReal[1, {3, 3}]; a = a.a; b = RandomReal[1, {3, 3}];b = b.b;
Wolfram Language code: traceProduct[a, b]

Project the matrix onto the space spanned by the matrix :

Wolfram Language code: Projection[a, b, traceProduct]

Properties & Relations  (3)

The trace of a matrix is invariant under similarity transformations:

Wolfram Language code: m = RandomReal[1, {10, 10}]; Tr[m]
Wolfram Language code: a = RandomReal[1, {10, 10}]; Tr[a.m.Inverse[a]]

The invariance means that the sum of the eigenvalues must equal the trace:

Wolfram Language code: Total[Eigenvalues[m]]

The Frobenius norm is defined as :

Wolfram Language code: A = RandomReal[1, {3, 3}];
Wolfram Language code: Sqrt@Tr[A.Transpose[A]]
Wolfram Language code: Norm[A, "Frobenius"]

Tr[m,List] is equivalent to Diagonal[m] for a matrix m:

Wolfram Language code: m = (⁠| | | | | - | - | - | | 1 | 2 | 3 | | 4 | 5 | 6 |⁠);
Wolfram Language code: Tr[m, List]
Wolfram Language code: Diagonal[m]
Wolfram Research (1999), Tr, Wolfram Language function, https://reference.wolfram.com/language/ref/Tr.html (updated 2003).

Text

Wolfram Research (1999), Tr, Wolfram Language function, https://reference.wolfram.com/language/ref/Tr.html (updated 2003).

CMS

Wolfram Language. 1999. "Tr." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2003. https://reference.wolfram.com/language/ref/Tr.html.

APA

Wolfram Language. (1999). Tr. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Tr.html

BibTeX

@misc{reference.wolfram_2026_tr, author="Wolfram Research", title="{Tr}", year="2003", howpublished="\url{https://reference.wolfram.com/language/ref/Tr.html}", note=[Accessed: 15-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tr, organization={Wolfram Research}, title={Tr}, year={2003}, url={https://reference.wolfram.com/language/ref/Tr.html}, note=[Accessed: 15-June-2026]}