Wolfram Language & System Documentation Center

Det

Det[m]

gives the determinant of the square matrix m.

Details and Options

Det[m,Modulus->n] computes the determinant modulo n.

Examples

open all close all

Basic Examples (2)

Find the determinant of a symbolic matrix:

Wolfram Language code:

Det[(⁠|       |       |
| :---- | :---- |
| a1, 1 | a1, 2 |
| a2, 1 | a2, 2 |⁠)]

The determinant of an exact matrix:

Wolfram Language code: Det[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]

Scope (13)

Basic Uses (8)

Find the determinant of a MachinePrecision matrix:

Wolfram Language code: Det[{{1.7, 7.1, -2.7}, {2.2, 8.7, 3.2}, {3.2, -9.2, 1.2}}]

Determinant of a complex matrix:

Wolfram Language code: Det[{{1. + I, 2, 3 - 2 I}, {0, 4 π, 5I}, {3, 0, 6}}]

Determinant of an exact matrix:

Wolfram Language code: Det[{{1, 2, 4}, {5, 4, 5}, {9, 2, 7}}]

Determinant of an arbitrary-precision matrix:

Wolfram Language code: Det[RandomReal[2, {3, 3}, WorkingPrecision -> 20]]

Determinant of a symbolic matrix:

Wolfram Language code: Det[{{a, b, c}, {d, e, f}, {g, h, i}}]

The determinant of a large numerical matrix is computed efficiently:

Wolfram Language code: mat = BlockRandom[RandomReal[3, {1500, 1500}], RandomSeeding -> 1234];

Wolfram Language code: Det[mat]//Timing

Note that the result may not be a machine number:

Wolfram Language code: Divide[Abs[Last[%]], $MaxMachineNumber]

Determinant of a matrix with finite field elements:

Wolfram Language code:

ℱ = FiniteField[17, 3];
Det[{{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}}]

Determinant of a CenteredInterval matrix:

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm

Wolfram Language code: mdet = Det[m]

Find a random representative mrep of m:

Wolfram Language code:

ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"]
(mrep = Map[ranrep, m, {2}])//MatrixForm

Verify that mdet contains the determinant of mrep:

Wolfram Language code: IntervalMemberQ[mdet, Det[mrep]]

Special Matrices (5)

Determinants of sparse matrices:

Wolfram Language code: SparseArray[{{1, 3} -> 2, {2, 2} -> 3, {3, 1} -> 1, {4, 2} -> 5}, {4, 4}]

Wolfram Language code: Det[%]

Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 1}, {10, 10}]

Wolfram Language code: Det[%]

Determinants of structured matrices:

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 1}, {2, 2}, Symmetric[All]]

Wolfram Language code: Det[%]

Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, {"Meters", "Seconds"}]

Wolfram Language code: Det[%]

IdentityMatrix always has unit determinant:

Wolfram Language code: Det[IdentityMatrix[22]]

Determinant of HilbertMatrix:

Wolfram Language code: HilbertMatrix[9]//Det

Compute the determinant of a matrix of univariate polynomials of degree :

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
m = Table[rpoly[100], {10}, {10}];

Wolfram Language code: Det[m]//Short//AbsoluteTiming

Options (1)

Modulus (1)

Compute a determinant using arithmetic modulo 47:

Wolfram Language code: m = RandomInteger[46, {100, 100}];

Wolfram Language code: Det[m, Modulus -> 47]//AbsoluteTiming

This is faster than computing Mod[Det[m],47]:

Wolfram Language code: Mod[Det[m], 47]//AbsoluteTiming

Applications (19)

Area and Volumes (6)

Use Det to find area of a parallelogram spanned by and :

Wolfram Language code:

v = {1, 4};
w = {-5, 2};

Visualize the parallelogram when one vertex is at the origin:

Wolfram Language code:

p = Parallelogram[{0, 0}, {v, w}];
Graphics[p, Axes -> True]

The area is given by the absolute value of the determinant:

Wolfram Language code: Abs[Det[{v, w}]]

Compare with the result given by Area:

Wolfram Language code: Area[p]

Use Det to find the volume of a parallelepiped spanned by , and :

Wolfram Language code: {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]} = {{1, 4, 3}, {-2, -5, 2}, {-1, 2, -2}};

Visualize the parallelepiped when one vertex is at the origin:

Wolfram Language code:

p = Parallelepiped[{0, 0, 0}, {Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}];
Graphics3D[p, Axes -> True]

The volume is given by the absolute value of the determinant:

Wolfram Language code: Abs[Det[{Subscript[v, 1], Subscript[v, 2], Subscript[v, 3]}]]

Compare with a direct computation using Volume:

Wolfram Language code: Volume[p]

Use Det to find hypervolume of a hyper-parallelepiped spanned by the following vectors:

Wolfram Language code: {v1, v2, v3, v4} = {{6, -6, -1, 6}, {10, -1, 0, -7}, {3, -2, -9, -3}, {4, 5, 6, -3}}

The hypervolume is given by the absolute value of the determinant:

Wolfram Language code: Abs[Det[{v1, v2, v3, v4}]]

Compare with the result given by RegionMeasure:

Wolfram Language code: RegionMeasure[Parallelepiped[{0, 0, 0, 0}, {v1, v2, v3, v4}]]

The determinant itself is negative, so the are not right-handed:

Wolfram Language code: Det[{v1, v2, v3, v4}]

Simply reorder any two vectors, say the middle two, to produce a right-handed set:

Wolfram Language code: Det[{v1, v3, v2, v4}]

Find the area of the image of the unit disk under the linear transformation associated to the matrix :

Wolfram Language code:

m = {{7, -3}, {5, 7}, {-10, 4}};
m//MatrixForm

The area of the image is given by :

Wolfram Language code: πSqrt[Det[Transpose[m].m]]

Compare with a direct computation:

Wolfram Language code:

f𝔻 = ParametricRegion[ {m.{x, y}, {x, y}∈Disk[]}, {x, y}];
Area[f𝔻]

Visualize the image :

Wolfram Language code: Region[f𝔻, PlotTheme -> "Scientific"]

Find the volume factor in the change of variables formula between Cartesian and polar coordinates. The mapping from polar to Cartesian coordinates is given by:

Wolfram Language code: polar[r_, θ_] := {r Cos[θ], r Sin[θ]}

Compute the Jacobian of the mapping using Grad:

Wolfram Language code: jac = Grad[polar[r, θ], {r, θ}]

By the change of variables theorem, the volume is the determinant of the Jacobian:

Wolfram Language code: Simplify[Abs[Det[jac]], r > 0]

Compare with the result given by CoordinateChartData:

Wolfram Language code: CoordinateChartData["Polar", "VolumeFactor", {r, θ}]

The same procedure will work with any coordinate system, for example, spherical coordinates:

Wolfram Language code:

spherical[r_, θ_, φ_] := {r Sin[θ]Cos[φ], r Sin[θ]Sin[φ], r Cos[θ]}
Simplify[Abs[Det[Grad[spherical[r, θ, φ], {r, θ, φ}]]], r > 0 && 0 <= θ <= π]

Wolfram Language code: CoordinateChartData["Spherical", "VolumeFactor", {r, θ, φ}]

Use the change of variables theorem to compute , where is the following region:

Wolfram Language code:

𝔻 = ImplicitRegion[x > 0 && y > 0 && 1 <= x^2 - y^2 ≤ 9 && 2 <= x y <= 4, {x, y}];
RegionPlot[𝔻]

First, define hyperbolic coordinates as follows:

Wolfram Language code: hyper[x_, y_] := {x^2 - y^2, x y}

The region clearly corresponds to and . By the change of variables formula, . The gradient is given by:

Wolfram Language code: Grad[hyper[x, y], {x, y}]

The determinant of the gradient is twice the function whose integral is :

Wolfram Language code: Det[%]

Hence, is given by the trivial integral :

Wolfram Language code: Subsuperscript[∫, 2, 4]Subsuperscript[∫, 1, 9](1/2)ⅆuⅆv

Compare with a direct integration over the region:

Wolfram Language code: Subscript[∫, {x, y}∈𝔻](x^2 + y^2)

Orientation and Rotations (5)

Determine whether the following basis for $TemplateBox[{}, Reals]^3$ is right-handed:

Wolfram Language code: {b1, b2, b3} = {{1, 0, 1}, {0, 1, 1}, {1, 0, 0}};

The determinant of the matrix formed by the basis is negative, so it is not right-handed:

Wolfram Language code: Det[{b1, b2, b3}]

Determine if linear transformation corresponding to is orientation-preserving or orientation-reversing:

Wolfram Language code: m = {{-8, 10, -7, -10}, {2, 6, -7, -9}, {6, 2, 4, -10}, {-7, -4, -3, -10}};

As , the mapping is orientation-preserving:

Wolfram Language code: Det[m]

Show that the following matrix is not a rotation matrix:

Wolfram Language code:

m = {{0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {0.170187, 0.254483, 0.170187, -0.0455171, 0.170187}, {-0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {-0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

All rotation matrices have unit determinant; since , it cannot be a rotation matrix:

Wolfram Language code: Det[m]

Show that the matrix is orthogonal and determine if it is a rotation matrix or includes a reflection:

Wolfram Language code:

m = {{-0.969655, -0.170187, -0.0303448, -0.170187, -0.0303448}, {-0.170187, 0.954483, 0.170187, -0.0455171, 0.170187}, {0.0303448, -0.170187, 0.969655, -0.170187, -0.0303448}, {-0.170187, -0.0455171, 0.170187, 0.954483, 0.170187}, {0.0303448, -0.170187, -0.0303448, -0.170187, 0.969655}};

Up to the input precision, , which shows that is orthogonal:

Wolfram Language code: Chop[Transpose[m].m, 10 ^ -6]//MatrixForm

All orthogonal matrices have , but rotations have ; as , includes a reflection:

Wolfram Language code: Det[m]

The generalization of a rotation matrix to complex vector spaces is a special unitary matrix that is unitary and has unit determinant. Show that the following matrix is a special unitary matrix:

Wolfram Language code:

u = (1/Sqrt[Cosh[2 Im[α]]])(⁠|               |               |
| ------------- | ------------- |
| Cosh[Im[α]]   | I Sinh[Im[α]] |
| I Sinh[Im[α]] | Cosh[Im[α]]   |);

The matrix is unitary because :

Wolfram Language code: ConjugateTranspose[u].u//Simplify

It also has unit determinant, so it is in fact an element of the special unitary group :

Wolfram Language code: Det[u]//Simplify

Linear and Abstract Algebra (8)

Determine the values of the parameter for which the system , has a unique solution and describe that solution. First, form the coefficient matrix and constant vector :

Wolfram Language code:

a = (|    |    |
| -- | -- |
| 2s | 1  |
| 3s | 6s |);b = (⁠|   |
| - |
| 1 |
| 2 |⁠);

Wolfram Language code: b

The solutions will be unique as :

Wolfram Language code: Det[a] != 0

Solving over the reals gives three open intervals separated at and :

Wolfram Language code: Reduce[%, s, Reals]

Since the matrix is invertible for these values of , the solution is simply :

Wolfram Language code: Inverse[a].b//Simplify

Verify the solution in the original system of equations:

Wolfram Language code: Simplify[2 s x + y == 1 && 3 s x + 6 s y == 2 /. Thread[{x, y} -> %]]

Use Cramer's rule to solve the system of equations , , . First, form the coefficient matrix and constant vector :

Wolfram Language code:

a = {{6, 9, 0}, {-7, 0, 3}, {0, 5, 9}};
b = {11, -12, -9};
{a//MatrixForm, b//MatrixForm}

Form the three matrices where replaces the corresponding columns of :

Wolfram Language code:

{dx, dy, dz} = Table[ReplacePart[a, {j_, i} :> b[[j]]], {i, 3}];
{dx//MatrixForm, dy//MatrixForm, dz//MatrixForm}

The entries of the solution are given by $TemplateBox[{{d, _, j}}, Det]/TemplateBox[{a}, Det]$ :

Wolfram Language code: ({Det[dx], Det[dy], Det[dz]}/Det[a])

Verify the result:

Wolfram Language code: a.% == b

Write a function implementing Cramer's rule for solving a linear system m.x=b:

Wolfram Language code:

crule[m_, b_] := Module[{d = Det[m], a}, 
	Table[a = m;a[[All, k]] = b;Det[a] / d, {k, Length[m]}]]

Use the function to solve a system for particular values of m and b:

Wolfram Language code:

m = {{1, 2, 3}, {1, 4, 9}, {1, 8, 27}};
b = {4, 16, 46};

Wolfram Language code: x = crule[m, {4, 16, 46}]

Verify the solution:

Wolfram Language code: m.x == b

For numerical systems, LinearSolve is much faster and more accurate:

Wolfram Language code:

n = 500;
m = RandomReal[1, {n, n}];
x = ConstantArray[1, n];
b = m.x;

Wolfram Language code: AbsoluteTiming[Norm[crule[m, b] - x]]

Wolfram Language code: AbsoluteTiming[Norm[LinearSolve[m, b] - x]]

Determine if the matrix has a nontrivial kernel (null space):

Wolfram Language code: a = {{-10, -7, -7, 8, -1}, {5, 0, 2, 0, -8}, {7, -4, -2, -10, 1}, {-5, 7, 10, 0, 3}, {-8, -5, -4, 1, -2}};

Since the determinant is nonzero, the kernel is trivial:

Wolfram Language code: Det[a]

Confirm the result using NullSpace:

Wolfram Language code: NullSpace[a]

Determine if the mapping corresponding to the matrix is injective:

Wolfram Language code: a = {{3, 1, 1}, {2, -5, 3}, {1, -11, 5}};

Since , the mapping is not injective:

Wolfram Language code: Det[a]

Confirm the result using FunctionInjective:

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionInjective[f[x, y, z], {x, y, z}]

Since defines a linear function $f:TemplateBox[{}, Reals]^3->TemplateBox[{}, Reals]^3$ , the failure to be injective implies a failure to be surjective:

Wolfram Language code: FunctionSurjective[f[x, y, z], {x, y, z}]

Determine if the matrix defines an automorphism (a bijective linear map):

Wolfram Language code: a = RandomInteger[{-10, 10}, {3, 3}]

Since , the mapping is an automorphism:

Wolfram Language code: Det[a]

Confirm the result using FunctionBijective:

Wolfram Language code: f[x_, y_, z_] := a.{x, y, z}

Wolfram Language code: FunctionBijective[f[x, y, z], {x, y, z}]

Compute the cofactor obtained from removing row i and column j:

Wolfram Language code: cofactor[m_, {i_Integer, j_Integer}] := (-1) ^ (i + j)Det[Drop[m, {i}, {j}]]

Wolfram Language code: cofactor[{{1, 2, 3, 4}, {5, 6, 7, 8}, {8, 7, 6, 4}, {5, 3, 2, 1}}, {3, 2}]

Check the result:

Wolfram Language code: (-1) ^ (3 + 2)Det[{{1, 3, 4}, {5, 7, 8}, {5, 2, 1}}]

Modular computation of a determinant:

Wolfram Language code: a = {{12, 13}, {14, 15}};

Modular determinants:

Wolfram Language code: d1 = Det[a, Modulus -> 5]

Wolfram Language code: d2 = Det[a, Modulus -> 7]

Recover the result:

Wolfram Language code: ChineseRemainder[{d1, d2}, {5, 7}]

Shift the residue to be symmetric:

Wolfram Language code: Mod[33, 5 7, (-5 7 + 1) / 2]

Confirm that the non-modular determinant was recovered:

Wolfram Language code: Det[a]

Properties & Relations (15)

The determinant is the product of the eigenvalues:

Wolfram Language code: m = RandomReal[1, {100, 100}];

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Eigenvalues[m]]

Det satisfies $TemplateBox[{a}, Det]=sum_sigma^(S_n)sgn[sigma]product_i^na〚i,sigma〚i〛〛$ , where is all -permutations and is Signature:

Wolfram Language code: a = {{-4, 8, -5, 6, -3}, {10, 2, -5, -4, 8}, {8, 8, -1, 8, 0}, {-7, -6, -4, -5, 2}, {8, -7, -6, -7, 10}};

Wolfram Language code: s5 = Permutations[Range[5]];

Wolfram Language code: Det[a] == Underoverscript[∑, σ, s5]Signature[σ]Underoverscript[∏, i, 5]a[[i, σ[[i]]]]

The determinant Det[m] is the contraction of m's rows or columns into the Levi–Civita tensor:

Wolfram Language code:

m = Array[μ, {3, 3}];
Det[m] === TensorContract[m[[1]]m[[2]]m[[3]]LeviCivitaTensor[3, List], {{1, 4}, {2, 5}, {3, 6}}]

Generalize to higher dimensions, using Inactive[TensorProduct] for efficiency:

Wolfram Language code:

det[m_] := With[{n = Length[m]}, 
	Activate[TensorContract[Inactive[TensorProduct]@@Append[m, LeviCivitaTensor[n]], Table[{k, k + n}, {k, n}]]]];

Wolfram Language code:

m = Array[μ, {6, 6}];
Det[m] == det[m]//Simplify

Det can be computed recursively via cofactor expansion along any row:

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Block[{n = Length[m], i = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^i + km[[i, k]]Det[Drop[m, {i}, {k}]], {k, n}] == Det[m]]

Or any column:

Wolfram Language code:

Block[{n = Length[m], j = RandomInteger[{1, Length[m]}]}, 
	Sum[(-1)^j + km[[k, j]]Det[Drop[m, {k}, {j}]], {k, n}] == Det[m]]

The determinant is the signed volume of the parallelepiped generated by its rows:

Wolfram Language code: m = {{1, 2, 3}, {-1, 1, 0}, {3, 2, 1}};

Wolfram Language code: Det[m]

This equals the volume up to sign:

Wolfram Language code: Volume[Parallelepiped[{0, 0, 0}, m]]

A square matrix has an inverse if and only if its determinant is nonzero:

Wolfram Language code: m = {{1, 2, 1}, {1, 0, 2}, {-1, 2, -3}};

Wolfram Language code: Det[m]

Wolfram Language code: Inverse[m]

The determinant of a triangular matrix is the product of its diagonal elements:

Wolfram Language code: MatrixForm[m = SparseArray[{i_, j_} /; i ≥ j :> RandomReal[], {5, 5}]]

Wolfram Language code: Det[m]

Wolfram Language code: Apply[Times, Diagonal[m]]

The determinant of a matrix product is the product of the determinants:

Wolfram Language code: {a, b} = RandomReal[1, {2, 100, 100}];

Wolfram Language code: Det[a.b]

Wolfram Language code: Det[a]Det[b]

The determinant of the inverse is the reciprocal of the determinant:

Wolfram Language code:

m = (⁠|       |       |       |
| :---- | :---- | :---- |
| a1, 1 | a1, 2 | a1, 3 |
| a2, 1 | a2, 2 | a2, 3 |
| a3, 1 | a3, 2 | a3, 3 |⁠);

Wolfram Language code: Det[Inverse[m]]//Simplify

Wolfram Language code: 1 / Det[m]

Wolfram Language code: %% == %//Simplify

A matrix and its transpose have equal determinants:

Wolfram Language code:

m = RandomReal[1, {5, 5}];
Det[m] == Det[Transpose[m]]

The determinant of the matrix exponential is the exponential of the trace:

Wolfram Language code: m = RandomReal[1, {10, 10}, WorkingPrecision -> $MachinePrecision];

Wolfram Language code: Det[MatrixExp[m]] == Exp[Tr[m]]

CharacteristicPolynomial[m] is equal to :

Wolfram Language code: m = RandomInteger[9, {3, 3}];

Wolfram Language code: Det[m - λ IdentityMatrix[3]]

Wolfram Language code: CharacteristicPolynomial[m, λ]

Det[m] can be computed from LUDecomposition[m]:

Wolfram Language code:

m = RandomInteger[9, {5, 5}];
{l, u, p, c} = LUDecomposition[m];
Det[m] == Signature[p["PermutationList"]]Times@@Diagonal[u]

Consider two rectangular matrices and such that and are both square:

Wolfram Language code: a = RandomReal[1, {5, 3}];b = RandomReal[1, {3, 5}];

Sylvester's determinant theorem states that , where is the matching identity matrix:

Wolfram Language code: Det[IdentityMatrix[5] + a.b] == Det[IdentityMatrix[3] + b.a]

If a matrix is the TensorProduct of two vectors and , then :

Wolfram Language code: {u, v} = RandomReal[1, {2, 5}];

Wolfram Language code: Det[IdentityMatrix[5] + uv] == 1 + u.v

This can be expressed equally in terms of KroneckerProduct:

Wolfram Language code: Det[IdentityMatrix[5] + KroneckerProduct[u, v]] == 1 + u.v

This follows from Sylvester's determinant theorem for the corresponding row and column matrices:

Wolfram Language code: c = List /@ u;r = {v};

Wolfram Language code: {Det[IdentityMatrix[5] + c.r] == Det[IdentityMatrix[1] + r.c], r.c == {{u.v}}}

Neat Examples (1)

Determinants of tridiagonal matrices:

Wolfram Language code: tridiagonal[n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]

Wolfram Language code: tridiagonal[5]//MatrixForm

Wolfram Language code: Table[Det[tridiagonal[n]], {n, 2, 12}]//TableForm

A closed-form formula for these determinants is given by $(a c)^(n/2) TemplateBox[{n, {b, /, {(, {2, , {sqrt(, {a, , c}, )}}, )}}}, ChebyshevU]$ :

Wolfram Language code: % == Table[(a c) ^ (n / 2) ChebyshevU[n, b / (2 Sqrt[a c])]//Simplify, {n, 2, 12}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Det

Details and Options

Examples

Basic Examples (2)

Scope (13)

Basic Uses (8)

Special Matrices (5)

Options (1)

Modulus (1)

Applications (19)

Area and Volumes (6)

Orientation and Rotations (5)

Linear and Abstract Algebra (8)

Properties & Relations (15)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

Det

Details and Options

Examples

Basic Examples (2)

Scope (13)

Basic Uses (8)

Special Matrices (5)

Options (1)

Modulus (1)

Applications (19)

Area and Volumes (6)

Orientation and Rotations (5)

Linear and Abstract Algebra (8)

Properties & Relations (15)

Neat Examples (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX