WOLFRAM

Wolfram Language & System Documentation Center

VerticalSlider[y]

represents a vertical slider at position y with range 0 to 1.

VerticalSlider[Dynamic[y]]

takes the position to be the dynamically updated current value of y, with the value of y being reset if the slider is moved.

VerticalSlider[y,{ymin,ymax}]

represents a vertical slider with range ymin to ymax.

VerticalSlider[y,{ymin,ymax,dy}]

represents a vertical slider that jumps in steps dy.

VerticalSlider[y,{{e1,e2,…}}]

represents a slider in which equally spaced intervals correspond to successive settings ei.

VerticalSlider[y,{{{e1,h1},{e2,h2},…}}]

uses intervals of relative heights hi for the ei.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Appearance  
AutoAction  
Background  
Show More Show More
BaselinePosition  
ContinuousAction  
Enabled  
Exclusions  
ImageMargins  
ImageSize  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

VerticalSlider

VerticalSlider[y]

represents a vertical slider at position y with range 0 to 1.

VerticalSlider[Dynamic[y]]

takes the position to be the dynamically updated current value of y, with the value of y being reset if the slider is moved.

VerticalSlider[y,{ymin,ymax}]

represents a vertical slider with range ymin to ymax.

VerticalSlider[y,{ymin,ymax,dy}]

represents a vertical slider that jumps in steps dy.

VerticalSlider[y,{{e1,e2,…}}]

represents a slider in which equally spaced intervals correspond to successive settings ei.

VerticalSlider[y,{{{e1,h1},{e2,h2},…}}]

uses intervals of relative heights hi for the ei.

Details and Options

  • VerticalSlider[…] displays in a notebook as a vertical slider that can be manipulated interactively.
  • VerticalSlider[Dynamic[y]] will reset the value of y when the slider is moved; VerticalSlider[y] will not.
  • VerticalSlider[n,{nmin,nmax,dn}] jumps to integer positions if nmin and dn are integers. »
  • VerticalSlider[y,{ymin,ymax,dy}] in general jumps to positions given by Range[ymin,ymax,dy]. »
  • VerticalSlider[y] represents a slider running from value 0 at the bottom to value 1 at the top.
  • VerticalSlider[y,{ymax,ymin}] with ymax>ymin represents a slider running from value ymin at the top to value ymax at the bottom. »
  • If the value of the slider is outside the range given, it will be displayed at one of the ends.
  • VerticalSlider[y,{0,1,dy}] displays at position y, even if this is not a multiple of dy.
  • In VerticalSlider[y,{{e1,e2,…}}], the ei can be any expressions, not just numbers.
  • The following options can be given:
  • Appearance Automaticthe overall appearance of the slider
    AutoAction Falsewhether to move the slider automatically when the mouse is over it
    BaselinePosition Automaticalignment relative to surrounding text
    BaseStyle{}base style specifications for the slider
    ContinuousAction Truewhether to update continuously when the slider is moved
    Enabled Automaticwhether the slider is enabled, or grayed out
    ImageMargins 0margins around the image of the displayed slider
    ImageSize Automaticthe overall image size of the displayed slider
  • Possible settings for Appearance include Tiny, Small, Medium, and Large, as well as typically some other settings such as "LeftArrow" and "RightArrow".
  • VerticalSlider[] is equivalent to VerticalSlider[0.5].
  • The settings for BaseStyle are appended to the default style typically given by the "VerticalSlider" style in the current stylesheet.

Examples

open all close all

Basic Examples  (2)

A vertical slider set at 0.8 in the default range 0 to 1:

Wolfram Language code: VerticalSlider[0.8]

Dynamically change the value of :

Wolfram Language code: {VerticalSlider[Dynamic[x]], Dynamic[x]}

Scope  (3)

Specify integer values only:

Wolfram Language code: {VerticalSlider[Dynamic[x], {0, 100, 1}], Dynamic[x]}

Use the range to , increasing when going from bottom to top:

Wolfram Language code: x = 0;{VerticalSlider[Dynamic[x], {-1, 2}], Dynamic[x]}

A vertical slider with range to , increasing when going from top to bottom:

Wolfram Language code: y = 0;{VerticalSlider[Dynamic[y], {2, -1}], Dynamic[y]}

Use rational steps:

Wolfram Language code: {VerticalSlider[Dynamic[x], {0, 5, 1 / 4}], Dynamic[x]}

Use increments of :

Wolfram Language code: {VerticalSlider[Dynamic[y], {0, 5π, π}], Dynamic[y]}

Options  (14)

Appearance  (3)

Different appearance sizes:

Wolfram Language code: Table[VerticalSlider[0.5, Appearance -> {Vertical, a}], {a, {Tiny, Small, Medium, Large}}]

Add a label:

Wolfram Language code: VerticalSlider[0.5, Appearance -> "Labeled"]

Different appearances for the slider thumb are available on some platforms:

Wolfram Language code: Table[VerticalSlider[Dynamic[x], Appearance -> a], {a, {"RightArrow", "LeftArrow"}}]

AutoAction  (1)

Change the value by moving the mouse over the slider area:

Wolfram Language code: Table[VerticalSlider[0.5, AutoAction -> a], {a, {True, False}}]

Background  (2)

Change the background color:

Wolfram Language code: Table[VerticalSlider[0.5, Background -> c], {c, {Pink, Green, Gray, Yellow}}]

Change the background color dynamically:

Wolfram Language code: VerticalSlider[Dynamic[x], Background -> Dynamic[Hue[x]]]

BaselinePosition  (1)

Align with surrounding text:

Wolfram Language code: Row[Table[VerticalSlider[0.5, BaselinePosition -> b], {b, {Bottom, Center, Top}}], "xxx"]

ContinuousAction  (1)

By default, variables are continuously updated:

Wolfram Language code: {VerticalSlider[Dynamic[x]], Dynamic[x]}

Setting ContinuousAction to False updates the variable only when the slider is released:

Wolfram Language code: {VerticalSlider[Dynamic[y], ContinuousAction -> False], Dynamic[y]}

Enabled  (1)

By default, VerticalSlider is enabled:

Wolfram Language code: VerticalSlider[0.5]

By setting Enabled->False, the slider is disabled but visible in its current state:

Wolfram Language code: VerticalSlider[0.3, Enabled -> False]

Exclusions  (1)

Exclude values from the range of the slider:

Wolfram Language code: {VerticalSlider[Dynamic[x], {-1, 1, 0.1}, Exclusions -> {0}], Dynamic[1 / x]}

ImageMargins  (1)

Add margins to the slider area:

Wolfram Language code: VerticalSlider[0.5, Background -> LightBlue, ImageMargins -> 10]

ImageSize  (3)

Use preset values:

Wolfram Language code: Table[VerticalSlider[Dynamic[x], ImageSize -> i], {i, {Tiny, Small, Medium, Large}}]

Use any height value and default width:

Wolfram Language code: Table[VerticalSlider[0.5, ImageSize -> {Automatic, i}], {i, {50, 150, 300}}]

A fully customized image size:

Wolfram Language code: Table[VerticalSlider[0.5, ImageSize -> i], {i, {{50, 50}, {75, 50}, {100, 200}}}]

Applications  (1)

A color selector:

Wolfram Language code: DynamicModule[{x = 0}, Row[{VerticalSlider[Dynamic[x], Appearance -> "RightArrow"], Graphics[Table[{Hue[i], Rectangle[{0, i}, {0.1, i + 0.01}]}, {i, 0, 1, 0.01}], ImageSize -> {30, 200}], VerticalSlider[Dynamic[x], Appearance -> "LeftArrow"], " ", Dynamic@Graphics[{Hue[x], Disk[]}]}]]

Properties & Relations  (1)

VerticalSlider is equivalent to Slider with a vertical appearance:

Wolfram Language code: Slider[0.8, Appearance -> "Vertical"]

Possible Issues  (1)

Appearances provided by the operating system may be different or unavailable on other platforms:

Wolfram Language code: VerticalSlider[0.5, Appearance -> "RightArrow"]

Generic appearances are available on all platforms:

Wolfram Language code: Style[VerticalSlider[0.5, Appearance -> "RightArrow"], ControlsRendering -> "Generic"]
Wolfram Research (2007), VerticalSlider, Wolfram Language function, https://reference.wolfram.com/language/ref/VerticalSlider.html.

Text

Wolfram Research (2007), VerticalSlider, Wolfram Language function, https://reference.wolfram.com/language/ref/VerticalSlider.html.

CMS

Wolfram Language. 2007. "VerticalSlider." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/VerticalSlider.html.

APA

Wolfram Language. (2007). VerticalSlider. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VerticalSlider.html

BibTeX

@misc{reference.wolfram_2026_verticalslider, author="Wolfram Research", title="{VerticalSlider}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/VerticalSlider.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_verticalslider, organization={Wolfram Research}, title={VerticalSlider}, year={2007}, url={https://reference.wolfram.com/language/ref/VerticalSlider.html}, note=[Accessed: 13-June-2026]}