WOLFRAM

Wolfram Language & System Documentation Center

VideoStream[source]

creates a new VideoStream object from source.

VideoStream[id]

is an object that represents a unique video stream.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Properties  
Options  
AudioOutputDevice  
ImageSize  
Looping  
RasterSize  
SoundVolume  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

VideoStream

VideoStream[source]

creates a new VideoStream object from source.

VideoStream[id]

is an object that represents a unique video stream.

Details and Options

  • VideoStream is a handle to a Video object or a device to programmatically control playback or recording of a video.
  • The source can be any of the following:
  • videoplayback stream from a Video object
    "camera"recording stream from a camera in $ImagingDevices
    {"Screen",n}recording stream from the n^(th) connected screen
    {"Screen",n,bbox}recording stream from the region bbox of the n^(th) screen
    NotebookObject[…]recording stream from a notebook displayed on screen
    "livestream"a stream generated from an HTTP or HTTPS livestream
  • Use VideoPlay to start playing back the video stream.
  • Use VideoRecord to start recording the stream.
  • Use VideoPause and VideoStop to pause or stop the playback or the recording.
  • Use Video[vstream] to create a Video object from a recorded stream.
  • The following options can be specified:
  • AudioOutputDevice Automaticaudio output device to use for playback
    ImageSize Automaticdisplay size of the video frames
    Looping Falsewhether to loop the playback
    RasterSize Automaticdimensions of video frames
    SoundVolume Automaticsound volume
  • A property of a video stream vstream can be obtained using vstream["prop"].
  • It is possible to set values of properties with vstream["prop"]=val.
  • Global properties:
  • "Duration"overall duration
    "ID"the stream ID
    "ImageSize"the size at which to display the video
    "Location"location of the linked video file
    "Looping"whether to loop the playback
    "Position"position of the playback given as a time Quantity
    "Status"status of the stream
    "AudioTrackCount"number of audio tracks
    "VideoTrackCount"number of video tracks
    "SubtitleTrackCount"number of subtitle tracks
  • Possible settings for "Status" include "Playing", "Recording", "Paused" or "Stopped".
  • Additional properties for VideoStream[dev]:
  • "AudioInputDevice"audio input device to use for recording
    "GeneratedAssetLocation"path to the file that will store the recorded video
    "RecordedVideo"video object for the recording
    "RecordedDuration"duration of the recorded video
  • Current track properties:
  • "CurrentAudioTrack"index of the current audio track
    "CurrentAudio"snippet of the current audio
    "CurrentVideoTrack"index of the current video track
    "CurrentFrame"a frame of the current video
    "CurrentSubtitleTrack"index of the current subtitle track
    "CurrentSubtitle"snippet of the current subtitle
  • Properties for the current audio track:
  • "AudioOutputDevice"audio output device to use for playback
    "AudioChannels"number of audio channels
    "SampleRate"audio sample rate
    "SoundVolume"sound volume
    "AudioEncoding"audio codec
  • Properties for the current video track:
  • "FrameChannels"number of color channels
    "FrameRate"video frame rate
    "RasterSize"dimensions of the frame
    "VideoEncoding"video codec
  • Properties for the current subtitle track:
  • "SubtitleEncoding"subtitle codec

Examples

open all close all

Basic Examples  (1)

Create a VideoStream object linking to a local video file:

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: Dynamic[stream["CurrentFrame"]]

Play the video stream:

Wolfram Language code: VideoPlay[stream]

Pause the stream:

Wolfram Language code: VideoPause[stream]

Scope  (10)

Basic Uses  (6)

A video stream directly from a file:

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: Dynamic[stream["CurrentFrame"]]

A video stream from a Video object:

Wolfram Language code: v = Video["ExampleData/Caminandes.mp4"]
Wolfram Language code: stream = VideoStream[v]
Wolfram Language code: stream["Duration"]

A stream from a URL:

Wolfram Language code: stream = VideoStream["http://exampledata.wolfram.com/agent327.mp4"];
Wolfram Language code: stream["Position"] = 60;
Wolfram Language code: stream["CurrentFrame"]

A stream from a livestream video:

Wolfram Language code: stream = VideoStream[URL[...]]; VideoPlay[stream]
Wolfram Language code: stream["CurrentFrame"]

The duration of livestreams is Indeterminate:

Wolfram Language code: stream["Duration"]

A recording stream from a connected imaging device:

Wolfram Language code: stream = VideoStream[$DefaultImagingDevice]

Record frames from the stream:

Wolfram Language code: VideoRecord[stream] Pause[5]; VideoStop[stream];

Retrieve the recorded video:

Wolfram Language code: Video[stream]
Wolfram Language code: Information[%]

A recording stream from a screen:

Wolfram Language code: stream = VideoStream["Screen"]

Record frames from the stream:

Wolfram Language code: VideoRecord[stream] Pause[5]; VideoStop[stream];

Retrieve the recorded video:

Wolfram Language code: Video[stream]
Wolfram Language code: Information[%]

Properties  (4)

Check for available stream properties:

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]; stream["Properties"]

Get the property values of a video stream:

Wolfram Language code: AssociationMap[stream, stream["Properties"]]//Dataset

Check for available properties in a recordable stream:

Wolfram Language code: stream = VideoStream[$DefaultImagingDevice]; stream["Properties"]

Get the property values of a video stream:

Wolfram Language code: AssociationMap[stream, stream["Properties"]]//Dataset

Set the "Position" property:

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"];
Wolfram Language code: stream["Position"] = 30;

Extract the frame at the current position:

Wolfram Language code: stream["CurrentFrame"]

Modify properties while playing a stream:

Wolfram Language code: stream = VideoStream["ExampleData/Caminandes.mp4"]
Wolfram Language code: VideoPlay[stream]; Pause[5]; stream["SoundVolume"] = .1; Pause[5]; stream["SoundVolume"] = 1;

Options  (5)

AudioOutputDevice  (1)

By default, the AudioOutputDevice is inherited from the corresponding Video object:

Wolfram Language code: v = Video["ExampleData/rule30.mp4", AudioOutputDevice -> $DefaultAudioOutputDevice]; stream = VideoStream[v];
Wolfram Language code: AudioOutputDevice /. Options[v]
Wolfram Language code: stream["AudioOutputDevice"]

It is possible to set the VideoStream to a different device using the AudioOutputDevice option:

Wolfram Language code: stream = VideoStream[v, AudioOutputDevice -> $AudioOutputDevices[[2]]];
Wolfram Language code: stream["AudioOutputDevice"]

ImageSize  (1)

By default, automatic image size is used, which scales depending on image dimensions and window size:

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: str["CurrentFrame"]

Specify a different image size:

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", ImageSize -> 200]; str["CurrentFrame"]

Notice that image dimensions are not affected:

Wolfram Language code: ImageDimensions[%]

Change the "ImageSize" property:

Wolfram Language code: str["ImageSize"] = 400; str["CurrentFrame"]

Looping  (1)

By default, the video stream is not looping:

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: str["Looping"]

Create a looping stream:

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", Looping -> True]; str["Looping"]

Create a stream that loops twice:

Wolfram Language code: str = VideoStream["ExampleData/bullfinch.mkv", Looping -> 2]; str["Looping"]

RasterSize  (1)

By default, the original raster size is used:

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: Information[v]["VideoTracks"]
Wolfram Language code: str = VideoStream[v]; str["CurrentFrame"]//ImageDimensions

Specify a different raster size:

Wolfram Language code: str = VideoStream[v, RasterSize -> 320]; str["CurrentFrame"]//ImageDimensions

Specify both width and height:

Wolfram Language code: str = VideoStream[v, RasterSize -> {320, 100}]; str["CurrentFrame"]//ImageDimensions

SoundVolume  (1)

By default, the SoundVolume is inherited from the corresponding Video object:

Wolfram Language code: v = Video["ExampleData/rule30.mp4", SoundVolume -> .5]; stream = VideoStream[v];
Wolfram Language code: SoundVolume /. Options[v]
Wolfram Language code: stream["SoundVolume"]

It is possible to set the VideoStream to a different volume using the SoundVolume option:

Wolfram Language code: stream = VideoStream[v, SoundVolume -> .1];
Wolfram Language code: stream["SoundVolume"]

Applications  (3)

Build a simple video GUI:

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]
Wolfram Language code: Panel@Column[{ Dynamic[stream["CurrentFrame"]], Slider[Dynamic[QuantityMagnitude[stream["Position"], "Seconds"], (stream["Position"] = #)&], {0, QuantityMagnitude[stream["Duration"], "Seconds"]}], Button[ Dynamic[If[stream["Status"] === "Playing", "Pause", "Play"]], If[stream["Status"] === "Playing", VideoPause[stream], VideoPlay[stream]] ] }, Alignment -> Center]

Apply a neural network–based function to the current frame in real time:

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]

Highlight the results of ImageCases dynamically:

Wolfram Language code: VideoPlay[stream];HighlightImage[stream["CurrentFrame"], ImageCases[stream["CurrentFrame"], All -> "BoundingBox"]]//Dynamic
Wolfram Language code: VideoPause[]

Apply an image processing function dynamically to the current frame:

Wolfram Language code: stream = VideoStream["ExampleData/bullfinch.mkv"]

Compute the result of ImageSaliencyFilter:

Wolfram Language code: VideoPlay[stream];Dynamic@ImageSaliencyFilter[stream["CurrentFrame"]]
Wolfram Language code: VideoPause[]

Properties & Relations  (1)

Use VideoPlay to create and start playing a video stream:

Wolfram Language code: v = Import["ExampleData/Caminandes.mp4"]; stream = VideoPlay[v]
Wolfram Language code: Dynamic[Quiet@stream["CurrentFrame"] /. Except[_Image] -> None]

Use VideoPause to pause the playback:

Wolfram Language code: VideoPause[stream];

Use VideoStop to stop and reset the playback:

Wolfram Language code: VideoStop[stream];

List all video streams in the system using VideoStreams:

Wolfram Language code: VideoStreams[]

Remove the stream and associated resources using RemoveVideoStream:

Wolfram Language code: RemoveVideoStream[stream];
Wolfram Research (2020), VideoStream, Wolfram Language function, https://reference.wolfram.com/language/ref/VideoStream.html (updated 2021).

Text

Wolfram Research (2020), VideoStream, Wolfram Language function, https://reference.wolfram.com/language/ref/VideoStream.html (updated 2021).

CMS

Wolfram Language. 2020. "VideoStream." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/VideoStream.html.

APA

Wolfram Language. (2020). VideoStream. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VideoStream.html

BibTeX

@misc{reference.wolfram_2026_videostream, author="Wolfram Research", title="{VideoStream}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/VideoStream.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_videostream, organization={Wolfram Research}, title={VideoStream}, year={2021}, url={https://reference.wolfram.com/language/ref/VideoStream.html}, note=[Accessed: 13-June-2026]}