WOLFRAM

Wolfram Language & System Documentation Center

WaitNext[{eid1,eid2,…}]

waits until the first evaluation represented by any of the eidi finishes, then returns its result, the corresponding eidi, and the list of remaining eidk.

WaitNext[{eid1,eid2,…},h]

wraps the head h around the result before returning it.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

WaitNext

WaitNext[{eid1,eid2,…}]

waits until the first evaluation represented by any of the eidi finishes, then returns its result, the corresponding eidi, and the list of remaining eidk.

WaitNext[{eid1,eid2,…},h]

wraps the head h around the result before returning it.

Details

  • The eidi are EvaluationObject expressions obtained by submitting expressions for concurrent evaluation using ParallelSubmit.
  • WaitNext[{eid1,eid2,…}] returns a list {res,eid,eids}, where res is the result of the finished evaluation, eid is its EvaluationObject, and eids is the list of remaining evaluations.
  • The last element in the list produced by WaitNext is suitable for another call to WaitNext.

Examples

open all close all

Basic Examples  (1)

Submit a number of integer factorizations:

Wolfram Language code: eids = Table[ParallelSubmit[{i}, Length[FactorInteger[2 ^ i - 1]]], {i, 181, 186}]

Wait until the fastest one is done:

Wolfram Language code: {res, id, eids} = WaitNext[eids]

Wait for the next one:

Wolfram Language code: {res, id, eids} = WaitNext[eids];res

Finally, wait for all remaining ones:

Wolfram Language code: WaitAll[eids]

Scope  (1)

Define a symbol only on the master kernel:

Wolfram Language code: Private`getID := $KernelID

Submit a number of evaluations using this symbol:

Wolfram Language code: procs = Table[ParallelSubmit[Private`getID], {4}];

Return the first result:

Wolfram Language code: {res, i, procs} = WaitNext[procs];res

Return the next result, but wrap it in Hold first:

Wolfram Language code: {res, i, procs} = WaitNext[procs, Hold];res

Applications  (1)

Test for primality, returning $Failed if it is not prime:

Wolfram Language code: test[n_] := If[PrimeQ[n! + 1], n, $Failed] DistributeDefinitions[test];

Adaptively schedule search jobs until a result has been found or the computation is aborted:

Wolfram Language code: ids = {};res = $Failed;next = 1; next = 1400;
Wolfram Language code: PrintTemporary[Dynamic[next]]; CheckAbort[While[res === $Failed, While[Length[ids] ≤ $KernelCount, AppendTo[ids, Composition[ParallelSubmit, test][next++]]]; If[Length[ids] > 0, {res, id, ids} = WaitNext[ids]]; ], Null];AbortKernels[]; res

Properties & Relations  (2)

ParallelTry is essentially implemented in terms of WaitNext:

Wolfram Language code: parallelTry[f_, args_List] := Module[{evs, ev, res = $Failed}, evs = Composition[ParallelSubmit, f] /@ args; While[res === $Failed && Length[evs] > 0, {res, ev, evs} = WaitNext[evs]]; AbortKernels[]; res ]
Wolfram Language code: parallelTry[FactorInteger, Range[10 ^ 20 + 1, 10 ^ 20 + $KernelCount]]

Scheduled evaluations no longer needed can be aborted with AbortKernels:

Wolfram Language code: evs = Composition[ParallelSubmit, FactorInteger] /@ Range[10 ^ 20 + 1, 10 ^ 20 + 4]
Wolfram Language code: {res, ev, evs} = WaitNext[evs];res
Wolfram Language code: AbortKernels[];

Possible Issues  (2)

No more than $KernelCount evaluations are initially run to find the fastest one:

Wolfram Language code: evs = ParallelSubmit[Pause[#];#]& /@ {0.8, 1.0, 1.2, 1.4, 0.1}
Wolfram Language code: {res, ev, evs} = WaitNext[evs];res
Wolfram Language code: {res, ev, evs} = WaitNext[evs];res
Wolfram Language code: WaitAll[evs]

Each evaluation should be waited for exactly once:

Wolfram Language code: evs = ParallelSubmit[{$KernelID, #}]& /@ Range[2]
Wolfram Language code: WaitNext[evs]

One of the evaluation objects has already completed:

Wolfram Language code: WaitNext[evs]
Wolfram Language code: WaitAll[evs]
Wolfram Research (2008), WaitNext, Wolfram Language function, https://reference.wolfram.com/language/ref/WaitNext.html.

Text

Wolfram Research (2008), WaitNext, Wolfram Language function, https://reference.wolfram.com/language/ref/WaitNext.html.

CMS

Wolfram Language. 2008. "WaitNext." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WaitNext.html.

APA

Wolfram Language. (2008). WaitNext. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WaitNext.html

BibTeX

@misc{reference.wolfram_2026_waitnext, author="Wolfram Research", title="{WaitNext}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/WaitNext.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_waitnext, organization={Wolfram Research}, title={WaitNext}, year={2008}, url={https://reference.wolfram.com/language/ref/WaitNext.html}, note=[Accessed: 12-June-2026]}