WOLFRAM

Wolfram Language & System Documentation Center

WordList[]

gives a list of common words.

WordList[type]

gives a list of words of the specified type.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Language  
IncludeInflections  
Applications  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

WordList

WordList[]

gives a list of common words.

WordList[type]

gives a list of words of the specified type.

Details and Options

  • The following types are supported:
  • "CommonWords"common words (default)
    "KnownWords"known dictionary words
    poscommon words that can be a given part of speech
    {"type",pos}inflected, known, etc. words filtered by part of speech
    "Stopwords"words like "the" that are often considered insignificant
  • Core parts of speech are: "Noun", "Verb", "Adjective", "Adverb", "Preposition", "Conjunction", "Pronoun", "Determiner", and "Interjection".
  • WordList supports the following options:
  • IncludeInflections Falsewhether to include inflected forms of words
    Language $Languagewhat language to use

Examples

open all close all

Basic Examples  (1)

Get a list of common English language words:

Wolfram Language code: WordList[]

List common English language nouns:

Wolfram Language code: WordList["Noun"]

Get the list of stop words for a given language:

Wolfram Language code: WordList["Stopwords"]

Scope  (1)

In WordList[type], type may correspond to a collection of words or a part of speech:

Wolfram Language code: WordList["Verb"]//Short
Wolfram Language code: WordList["KnownWords"]//Short

Options  (2)

Language  (1)

Get a list of all available Spanish language words:

Wolfram Language code: WordList["KnownWords", Language -> "Spanish"]

Language specifications can be strings, or "Language" entities:

Wolfram Language code: WordList["KnownWords", Language -> Entity["Language", "German"]]

IncludeInflections  (1)

With IncludeInflections->True, inflected forms will be included in results:

Wolfram Language code: MemberQ[WordList[IncludeInflections -> True], "zooming"]

With IncludeInflections->False, only uninflected words will be returned:

Wolfram Language code: MemberQ[WordList[IncludeInflections -> False], "zooming"]

Applications  (2)

Generate a list of common English words:

Wolfram Language code: Length[words = WordList[]]

Find the most frequent characters at the beginning of words:

Wolfram Language code: firstchars = StringTake[words, 1]; Counts[firstchars]

Visualize the relative frequencies in a word cloud:

Wolfram Language code: WordCloud[firstchars]

Compare to the most frequent characters globally:

Wolfram Language code: allchars = LetterCounts[StringJoin[words], IgnoreCase -> True]
Wolfram Language code: WordCloud[allchars]

Generate lists of common words for a set of languages:

Wolfram Language code: languages = {"German", "English", "Italian", "Dutch", "Russian"}; words = Association[# -> WordList[Language -> #]& /@ languages];

Compute the length of each of these words:

Wolfram Language code: wordLengths = StringLength /@ words;

Compare the distribution of numbers of characters per word for each language by overlapping histograms of relative frequencies:

Wolfram Language code: Histogram[wordLengths, Automatic, "PDF", ChartLegends -> Automatic]

Combine the histograms to show total counts of lengths for all languages together:

Wolfram Language code: Histogram[wordLengths, ChartLegends -> Automatic, ChartLayout -> "Stacked"]

Possible Issues  (2)

Part-of-speech definitions may not be available for all language settings:

Wolfram Language code: WordList["Noun", Language -> "Spanish"]

Not all languages have available word lists:

Wolfram Language code: WordList["KnownWords", Language -> Entity["Language", "Warlpiri"]]
Wolfram Research (2015), WordList, Wolfram Language function, https://reference.wolfram.com/language/ref/WordList.html.

Text

Wolfram Research (2015), WordList, Wolfram Language function, https://reference.wolfram.com/language/ref/WordList.html.

CMS

Wolfram Language. 2015. "WordList." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WordList.html.

APA

Wolfram Language. (2015). WordList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WordList.html

BibTeX

@misc{reference.wolfram_2026_wordlist, author="Wolfram Research", title="{WordList}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/WordList.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_wordlist, organization={Wolfram Research}, title={WordList}, year={2015}, url={https://reference.wolfram.com/language/ref/WordList.html}, note=[Accessed: 12-June-2026]}