WOLFRAM

Wolfram Language & System Documentation Center

ZetaZero[k]

represents the k^(th) zero of the Riemann zeta function on the critical line.

ZetaZero[k,t]

represents the k^(th) zero with imaginary part greater than t.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

ZetaZero

ZetaZero[k]

represents the k^(th) zero of the Riemann zeta function on the critical line.

ZetaZero[k,t]

represents the k^(th) zero with imaginary part greater than t.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For positive k, ZetaZero[k] represents the zero of on the critical line that has the k^(th) smallest positive imaginary part.
  • For negative k, ZetaZero[k] represents zeros with progressively larger negative imaginary parts.
  • N[ZetaZero[k]] gives a numerical approximation to the specified zero.
  • ZetaZero can be evaluated to arbitrary numerical precision.
  • ZetaZero automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Find numerically the position of the first zero:

Wolfram Language code: N[ZetaZero[1]]

Symbolic property:

Wolfram Language code: Zeta[ZetaZero[10]]

Display zeros of the Im[Zeta[1/2+z]] function:

Wolfram Language code: Plot[Im[Zeta[1 / 2 + I z]], {z, 0, 32}, Epilog -> {PointSize[0.03], Red, Point[Table[{Im[ZetaZero[k]], 0}, {k, 4}]]}]

Scope  (8)

Numerical Evaluation  (3)

Evaluate numerically:

Wolfram Language code: ZetaZero[-1, 5.6]
Wolfram Language code: ZetaZero[-2, 15.]

Evaluate to high precision:

Wolfram Language code: N[ZetaZero[54], 50]
Wolfram Language code: N[ZetaZero[46], 20]

Evaluate efficiently at high precision:

Wolfram Language code: N[ZetaZero[10, 5`100]]//Timing
Wolfram Language code: ZetaZero[32, 3`1000];//Timing

Specific Values  (3)

The first three zeros:

Wolfram Language code: {ZetaZero[1], ZetaZero[2], ZetaZero[3]}//N

Find the first zero of Zeta[1/2+ x] using FindRoot:

Wolfram Language code: xzero = x /. FindRoot[Re[Zeta[1 / 2 + I x]], {x, 13}]
Wolfram Language code: Plot[Im[Zeta[1 / 2 + I x]], {x, 0, 50}, Epilog -> Style[Point[{xzero, Zeta[1 / 2 + I xzero]}], PointSize[Large], Red]]

ZetaZero threads elementwise over lists:

Wolfram Language code: ZetaZero[{1, 2, 3, 4, 5}]//N

Visualization  (2)

Display zeros of Im[Zeta[1/2+ z]] function:

Wolfram Language code: Plot[Im[Zeta[1 / 2 + I z]], {z, 0, 50}, Epilog -> {PointSize[0.03], Point[Table[{Im[ZetaZero[k]], 0}, {k, 10}]]}]

Show the first zero greater than 15:

Wolfram Language code: Plot[Im[Zeta[1 / 2 + I z]], {z, 0, 30}, Epilog -> {PointSize[0.03], Red, Point[{Im[ZetaZero[1, 15]], 0}]}]

Generalizations & Extensions  (1)

Negative order is interpreted as a reflected root of the Zeta function:

Wolfram Language code: ZetaZero[-1] == Conjugate[ZetaZero[1]]//N
Wolfram Language code: N[ZetaZero[-3, 20], 50]
Wolfram Language code: N[ZetaZero[2, -20], 50]

Applications  (5)

Plot distances between successive zeros:

Wolfram Language code: ListLinePlot[Differences[Table[Im[ZetaZero[n]], {n, 50}]]]

Visualize the first 10 zeros:

Wolfram Language code: Plot[Im[Zeta[1 / 2 + I t]], {t, 0, 50}, Epilog -> {PointSize[.02], Red, Point[Table[{Im[ZetaZero[n]], 0}, {n, 10}]]}]

Compute Gram points:

Wolfram Language code: gp[k_] := Block[{t}, t /. FindRoot[RiemannSiegelTheta[t] - Pi k, {t, (1 / 4 + 2k)Pi / ProductLog[(1 / 8 + k) / E]}]]

Show good Gram points, where RiemannSiegelZ changes sign for consecutive points:

Wolfram Language code: Plot[RiemannSiegelZ[t], {t, 0, 40}, Epilog -> {PointSize[0.03], Red, Point[Table[{gp[k], RiemannSiegelZ[1.0gp[k]]}, {k, -1, 6}]], Green, Point[Table[{Im[ZetaZero[k]], 0}, {k, 1, 6}]]}]

Show a bad Gram point:

Wolfram Language code: Plot[RiemannSiegelZ[t], {t, gp[125], gp[127]}, Epilog -> {PointSize[0.03], Green, Point[Table[{Im[ZetaZero[k]], 0}, {k, 126, 128}]], Red, Point[Table[{gp[k], RiemannSiegelZ[1.0gp[k]]}, {k, 125, 127}]]}, Ticks -> {{282, 283, 284}, {-6, -4, -2, 0}}]

First occurrence of Lehmer's phenomenon:

Wolfram Language code: N[{ZetaZero[6709], ZetaZero[6710]}, 20]

Plot an approximation of the number of primes and prime powers using MangoldtLambda and ZetaZero:

Wolfram Language code: f[x_, n_] := Module[{zero = Flatten[N[Table[ZetaZero[{j, -j}], {j, n}]]]}, x - Log[2Pi] - Total[x ^ zero / zero] - Log[1 - 1 / x ^ 2] / 2]; g[x_] := Sum[MangoldtLambda[j], {j, 1, Floor[x]}]; vis[n_] := Plot[{g[x], f[x, n]}, {x, 2, 15}, Exclusions -> None, Frame -> True, PlotRange -> {0, 15}, PlotLegends -> {g, f}];
Wolfram Language code: vis[1]

The more zeros used, the closer the approximation:

Wolfram Language code: vis[15]

Properties & Relations  (1)

Compute an exact value involving ZetaZero:

Wolfram Language code: RiemannSiegelZ[Im[ZetaZero[10]]]

Possible Issues  (1)

ZetaZero[0] is not defined:

Wolfram Language code: N[ZetaZero[0]]
Wolfram Research (2007), ZetaZero, Wolfram Language function, https://reference.wolfram.com/language/ref/ZetaZero.html.

Text

Wolfram Research (2007), ZetaZero, Wolfram Language function, https://reference.wolfram.com/language/ref/ZetaZero.html.

CMS

Wolfram Language. 2007. "ZetaZero." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ZetaZero.html.

APA

Wolfram Language. (2007). ZetaZero. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ZetaZero.html

BibTeX

@misc{reference.wolfram_2026_zetazero, author="Wolfram Research", title="{ZetaZero}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ZetaZero.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_zetazero, organization={Wolfram Research}, title={ZetaZero}, year={2007}, url={https://reference.wolfram.com/language/ref/ZetaZero.html}, note=[Accessed: 13-June-2026]}