WOLFRAM

Wolfram Language & System Documentation Center

MangoldtLambda[n]

gives the von Mangoldt function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MangoldtLambda

MangoldtLambda[n]

gives the von Mangoldt function .

Details

  • MangoldtLambda is also know as von Mangoldt function.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • MangoldtLambda[n] gives zero unless n is a prime power, in which case it gives the logarithm of the prime.
  • For a positive integer n= p1k1⋯ pmkm with pi primes, MangoldtLambda[n] returns 0 unless m is equal to 1, in which case it gives Log[p1].

Examples

open all close all

Basic Examples  (2)

Compute the Mangoldt function at :

Wolfram Language code: MangoldtLambda[25]

Plot the MangoldtLambda sequence for the first 100 numbers:

Wolfram Language code: DiscretePlot[MangoldtLambda[n], {n, 100}]

Scope  (8)

Numerical Evaluation  (3)

MangoldtLambda works over integers:

Wolfram Language code: MangoldtLambda[125]

Compute for large integers:

Wolfram Language code: MangoldtLambda[7 ^ 300]

MangoldtLambda threads over lists:

Wolfram Language code: MangoldtLambda[{2, 6, 9, 8, 15}]

Symbolic Manipulation  (5)

TraditionalForm formatting:

Wolfram Language code: MangoldtLambda[n]//TraditionalForm

Reduce expressions:

Wolfram Language code: Reduce[MangoldtLambda[n] == Log[2] && 0 < n < 10, n, Integers]

Solve equations:

Wolfram Language code: Solve[MangoldtLambda[a + b ^ 2] == Log[b] && 0 < a < 10 && 0 < b < 10, {a, b}, Integers]

Sum of MangoldtLambda over divisors:

Wolfram Language code: DivisorSum[x, MangoldtLambda[#]&]

DirichletTransform of MangoldtLambda:

Wolfram Language code: DirichletTransform[MangoldtLambda[n], n, s]

Equivalently:

Wolfram Language code: Sum[MangoldtLambda[k] / k ^ s, {k, 1, Infinity}]

Applications  (5)

Basic Applications  (3)

Highlight numbers n for which in blue, and the prime bases of numbers n for which in red:

Wolfram Language code: Multicolumn[If[MangoldtLambda[#] == 0, Style[#, Blue, Bold], Style[Exp[MangoldtLambda[#]], Red, Bold]]& /@ Range[100], 10, ...]

Compare MangoldtLambda sequence with logarithm function:

Wolfram Language code: Show[LogPlot[x, {x, 1, 100}, PlotStyle -> Orange], ListLinePlot[MangoldtLambda[Range[100]]]]

Plot the second Chebyshev function: [more info]

Wolfram Language code: ψ[x_] := Total@MangoldtLambda[Range[Floor[x]]];

Demonstrate that it is asymptotic with :

Wolfram Language code: DiscretePlot[ψ[x] / x, {x, 200}]

Number Theory  (2)

Use MangoldtLambda to test for a prime power:

Wolfram Language code: MangoldtLambda[81] ≠ 0
Wolfram Language code: PrimePowerQ[81]

Plot an approximation of the number of primes and prime powers using MangoldtLambda and ZetaZero:

Wolfram Language code: f[x_, n_] := Module[{zero = Flatten[N[Table[ZetaZero[{j, -j}], {j, n}]]]}, x - Log[2 Pi] - Total[x ^ zero / zero] - Log[1 - 1 / x ^ 2] / 2]; g[x_] := Sum[MangoldtLambda[j], {j, 1, Floor[x]}]; vis[n_] := Plot[{g[x], f[x, n]}, {x, 2, 15}, Exclusions -> None, Frame -> True, PlotRange -> {0, 15}, PlotLegends -> {g, f}];
Wolfram Language code: vis[1]

The more zeros used, the closer the approximation:

Wolfram Language code: vis[15]

Properties & Relations  (7)

MangoldtLambda gives zero except for prime powers:

Wolfram Language code: MangoldtLambda[2 3]
Wolfram Language code: MangoldtLambda[2 ^ 3]

MangoldtLambda is neither additive or multiplicative:

Wolfram Language code: {MangoldtLambda[2 3], MangoldtLambda[2] + MangoldtLambda[3]}
Wolfram Language code: {MangoldtLambda[2 3], MangoldtLambda[2]MangoldtLambda[3]}

MangoldtLambda satisfies the identity :

Wolfram Language code: Log[16] == DivisorSum[16, MangoldtLambda[#] &]

Use MoebiusMu to compute MangoldtLambda:

Wolfram Language code: DivisorSum[n, MoebiusMu[n / #] Log[#] &]

Use LCM to compute MangoldtLambda:

Wolfram Language code: Log[ LCM@@Range[5] / LCM@@Range[4]]

Compare with:

Wolfram Language code: MangoldtLambda[5]

The sum of MangoldtLambda of the first n integers is equal to the natural log of the LCM of the first n integers:

Wolfram Language code: Sum[MangoldtLambda[n], {n, 20}]//Simplify
Wolfram Language code: Log[Apply[LCM, Range[20]]]

MangoldtLambda satisfies the following identities:

Wolfram Language code: n = 16;
Wolfram Language code: Log[n] == DivisorSum[n, MangoldtLambda[#] &]
Wolfram Language code: DivisorSum[n, MoebiusMu[n / #] Log[#]&] == MangoldtLambda[n]
Wolfram Language code: DivisorSum[n, MoebiusMu[#] Log[#]&] == -MangoldtLambda[n]
Wolfram Language code: DivisorSum[n, MoebiusMu[n / #] MangoldtLambda[#]&] == -MoebiusMu[n] Log[n]

Neat Examples  (3)

Plot MangoldtLambda for the sum of two squares:

Wolfram Language code: ArrayPlot[Table[MangoldtLambda[a ^ 2 + b ^ 2], {a, 50}, {b, 50}], ColorFunction -> "BlueGreenYellow"]

Plot the arguments of the Fourier transform of MangoldtLambda:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[MangoldtLambda[m + n], {m, 200}, {n, 200}]]], ColorFunction -> Hue]

Plot the Ulam spiral of MangoldtLambda:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[MangoldtLambda[ulam[101]], ColorFunction -> "Rainbow"]
Wolfram Research (2008), MangoldtLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/MangoldtLambda.html.

Text

Wolfram Research (2008), MangoldtLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/MangoldtLambda.html.

CMS

Wolfram Language. 2008. "MangoldtLambda." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MangoldtLambda.html.

APA

Wolfram Language. (2008). MangoldtLambda. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MangoldtLambda.html

BibTeX

@misc{reference.wolfram_2026_mangoldtlambda, author="Wolfram Research", title="{MangoldtLambda}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/MangoldtLambda.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mangoldtlambda, organization={Wolfram Research}, title={MangoldtLambda}, year={2008}, url={https://reference.wolfram.com/language/ref/MangoldtLambda.html}, note=[Accessed: 13-June-2026]}