WOLFRAM

Wolfram Language & System Documentation Center
"Number" (Comparison Method)

"Number" (Comparison Method)

Compare two numeric quantities based on a tolerance.

Details

  • The number comparison method considers two numeric quantities to be equivalent if they do not differ numerically beyond a given tolerance.
  • The numeric tolerance should usually be set using the Tolerance option in AssessmentFunction. The default value of 0 allows only machine precision differences.
  • By default, the tolerance is compared to the absolute difference between the answer key value and the answer. The DistanceFunction option can be used to specify a different distance metric.
  • When multiple values in the answer key are within the tolerance range of an answer, the closest value is selected.
  • The following table shows a comparison of "Number" with other comparison methods for a typical answer key and two possible submitted answers:

Examples

open all close all

Basic Examples  (3)

Create an AssessmentFunction for a number comparison question:

Wolfram Language code: numberaf = AssessmentFunction[2024, "Number"]

Use it to assess an answer:

Wolfram Language code: numberaf[2024]

Numerically, approximation is always performed and equivalence is tested by default at machine precision level:

Wolfram Language code: numberaf[2024.0]

Create a check for an approximate number:

Wolfram Language code: tolerancetest = AssessmentFunction[1.414, "Number", Tolerance -> 0.01]

Answers within the tolerance range are correct:

Wolfram Language code: tolerancetest[1.415]

Any other value is marked incorrect:

Wolfram Language code: tolerancetest[1.4]

"Number" is chosen automatically when all values in the answer key are numeric. Define assessment for a problem with multiple correct answers:

Wolfram Language code: numberaf = AssessmentFunction[{1, Pi, Pi ^ 2}]

Use it to assess answers:

Wolfram Language code: numberaf[Pi]
Wolfram Language code: numberaf[1.0]

With no Tolerance specified, values not in the key are incorrect:

Wolfram Language code: numberaf[3.14]

Scope  (5)

Create an assessment for a list of answers, with each element assessed individually:

Wolfram Language code: ewAF = AssessmentFunction[{2, 3, 5, 7, 11, 13, 17, 19, 23, 29}, <|"ListAssessment" -> "SeparatelyScoreElements"|>]

Assess a list of answers:

Wolfram Language code: assessment = ewAF[{44, 17, 23}]

Each answer is assessed and scored separately. By default, any incorrect answer gives an overall incorrect result:

Wolfram Language code: assessment[All]

Use "ListAssessment""AllElementsOrdered" to create an assessment function for an ordered list of numbers, where all values must be included in the answer:

Wolfram Language code: orderedAF = AssessmentFunction[{{1, 2, 3}}, <|"ListAssessment" -> "AllElementsOrdered"|>, Tolerance -> 0.2]

Evaluate multiple answers:

Wolfram Language code: orderedAF[{1.1, 2.1, 2.9}]
Wolfram Language code: orderedAF[{1.1, 2.9, 2.1}]

Use "ListAssessment""AllElementsOrderless" to create an assessment function for a list of numbers, where all values must be included in the answer but the order does not matter:

Wolfram Language code: anyorder = AssessmentFunction[{{1, 2, 3}}, <|"ListAssessment" -> "AllElementsOrderless"|>, Tolerance -> 0.2]

Apply the function to an answer:

Wolfram Language code: anyorder[{1.1, 2.9, 2.1}]

Use "Number" comparison in a QuestionObject:

Wolfram Language code: QuestionObject[QuestionInterface["NumericRange", <|"Prompt" -> "Approximately how many ounces are in a cup?", "Range" -> {1, 10}|>], AssessmentFunction[8.0 -> 3, "Number", Tolerance -> 0.5]]

Use "Number" comparison in a QuestionGenerator:

Wolfram Language code: g7pool = QuestionSelector@KeyValueMap[QuestionObject[ QuestionInterface["NumericRange", <|"Prompt" -> Row[{"In millions, what is the approximate population of ", #1, "?"}], "Range" -> {5, 500}|>], AssessmentFunction[{QuantityMagnitude@#2 / 10 ^ 6 -> 1}, Tolerance -> 20] ]&, EntityValue[EntityClass["Country", "GroupOf7"], "Population", "EntityAssociation"]]
Wolfram Language code: g7pool[]

Applications  (1)

Create a QuestionGenerator for reading values from a plot of a random polynomial:

Wolfram Language code: qg = QuestionGenerator[{"poly" :> 3 + 3 x + RandomReal[{1, 3}] * x ^ 2 - RandomReal[{1, 3}] x ^ 3 - x ^ 4}, With[{max = NMaximize[#poly, x], roots = NSolveValues[#poly == 0, x, Reals], plot = Plot[#poly, ...]}, QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> Column[{"Estimate the values below based on the plot:", plot}, Alignment -> Center], "Template" -> "The maximum value is `` and occurs at ``. The roots occur at `` and ``.", "Interpreter" -> "Number"|>], AssessmentFunction[{{First@max, max[[2, 1, 2]], roots[[1]], roots[[2]]}}, <|"ComparisonMethod" -> "Number", "ListAssessment" -> "AllElementsOrdered"|>, Tolerance -> .2]]]& ]

Generate a random instance of the question:

Wolfram Language code: qg[]

Properties & Relations  (4)

Specify an answer key containing values that differ by less than the tolerance:

Wolfram Language code: overlaps = AssessmentFunction[{ 1 -> 1 , 3.1 -> 2, Pi -> 5}, Tolerance -> 0.1]

The closest value to the answer is chosen:

Wolfram Language code: overlaps[3.14][All]

Assessment will match exact and inexact values, even with zero tolerance:

Wolfram Language code: AssessmentFunction[8, "Number"][8.]

For an exact match, without numerical approximation applied, consider "ArithmeticResult" or "Expression":

Wolfram Language code: AssessmentFunction[8, "Expression"][8.]
Wolfram Language code: AssessmentFunction[8, "ArithmeticResult"][3 + 5.]

With no Tolerance specified, the tolerance is effectively based on $MachinePrecision:

Wolfram Language code: AssessmentFunction[1][1 + 10 ^ -($MachinePrecision - 1)]
Wolfram Language code: AssessmentFunction[1][1 + 10 ^ -($MachinePrecision + 1)]