WOLFRAM

Wolfram Language & System Documentation Center

WebP (.webp)

Background & Context

    • Registered MIME type: image/webp
    • WebP raster image format.
    • Binary format.
    • Stores both static and animated images.
    • Stores color bitmaps at a resolution of 8 bits per channel.
    • Supports alpha channels.
    • Introduced in 2010 by Google to provide both lossy and lossless compression of images on the web.

Import & Export

  • Import["file.webp"] imports a WebP file, returning a single Image object or a list of images.
  • Import["file.webp",elem] imports the specified element from a WebP file.
  • The import format can be specified with Import["file","WebP"] or Import["file",{"WebP",elem,…}].
  • Export["file.webp",expr] exports the expression expr to WebP.
  • The expression expr can be any of the following:
  • imagean Image expression
    graphicsrasterized graphics
    expran arbitrary expression, rasterized
    {expr1,expr2,…}an animation of rasterized expressions
    AnimatedImage[…]an animation of an AnimatedImage frame
    Manipulate[…]an animation of a Manipulate expression
  • When exporting graphics or arbitrary expressions, the resulting image has the same raster size as its displayed form.
  • Image objects are by default exported at their raster size.
  • See the following reference pages for full general information:
  • Import, Exportimport from or export to a file
    CloudImport, CloudExportimport from or export to a cloud object
    ImportString, ExportStringimport from or export to a string
    ImportByteArray, ExportByteArrayimport from or export to a byte array

Import Elements

  • General Import elements:
  • "Elements" list of elements and options available in this file
    "Rules"list of rules for all available elements
    "Summary"summary of the file
  • Data representation elements:
  • "Data"array of color values
    "Graphics"Graphics object representing an image
    "Image"raster image, given as an Image object
    "Thumbnail"thumbnail of the first image
  • Data representation elements for animated WebP files:
  • "AnimatedImage"data returned as AnimatedImage object
    "GraphicsList"data returned as Graphics objects
    "ImageList"data returned as Image objects
    "ThumbnailList"data returned as thumbnails
  • Import by default uses the "Image" element for a static WebP and "ImageList" for an animated WebP.
  • Import of an animated WebP with element "Image" gives the first frame of the animation.
  • Subelements for data elements can be used with animated WebP files in the form {elem,frame}, where frame can be any of the following:
  • nnth frame
    -ncounts from the end
    n;;mfrom n through m
    n;;m;;sfrom n through m with steps of s
    {n1,n2,…}specific frames ni
  • Advanced Import elements:
  • "AnimationRepetitions"how many times the animation is played before stopping
    "BitDepth"bits used to represent each color channel
    "Channels"the number of color channels
    "ColorProfileData"embedded color profile, given as a ColorProfileData object
    "ColorSpace"color encoding used in the file
    "DisplayDurations"display durations of animation frames, given in seconds
    "ImageCount"number of frames
    "RasterSize"raster dimensions
    "Summary"summary of the file
    "SummarySlideView"slide view summary of all frames
  • Metadata class elements:
  • "Exif"formatted Exif (Exchange image file format)
    "XMP"formatted XMP (Extensible metadata platform)
    "MetaInformation"combination of all formatted metadata present in the file
  • Raw metadata, as stored in the file, can be imported using "RawExif", "RawXMP" and "RawIPTC" elements, returned as an association.
  • All Exif tags can be imported individually. Common tags include:
  • "ApertureValue"lens aperture
    "DateTime"image creation date and time
    "ExposureTime"exposure time, given in seconds
    "FNumber"F number
    "FocalLength"actual focal length of the lens, given in millimeters
    "Make"manufacturer of the recording equipment
    "Model"model name or model number of the equipment
    "Software"name and version of the software or firmware of the camera or image input device used to generate the image
  • Derived metadata elements:
  • "CameraTopOrientation"orientation of the camera when the picture was taken
    "FlashUsed"whether the flash was fired
    "GeoPosition"latitude and longitude represented as GeoPosition object
    "GPSDateTime"image creation date and time registered by GPS

Import Options

Export Options

Examples

open all close all

Basic Examples  (4)

Import a WebP file:

Wolfram Language code: Import["ExampleData/flowers.webp"]

Summary of an image:

Wolfram Language code: Import["ExampleData/flowers.webp", "Summary"]

Import a multi-frame WebP:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp"]

Export an image to WebP:

Wolfram Language code: Export["image.webp", [image]]

Scope  (8)

Import  (2)

Import a static WebP image:

Wolfram Language code: Import["ExampleData/flowers.webp"]

Summary of a WebP image:

Wolfram Language code: Import["ExampleData/flowers.webp", "Summary"]

Import an animated WebP:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp"]

Summary of an animated WebP:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "Summary"]

Summary of frames in an animated WebP:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "SummarySlideView"]

Export  (6)

Export an image to WebP:

Wolfram Language code: Export["image.webp", [image]]

Export graphics to WebP:

Wolfram Language code: Export["plot.webp", [image]]

Export an arbitrary expression that gets rasterized:

Wolfram Language code: Export["expr.webp", Nest[Subsuperscript[#, #, #]&, o, 4]];
Wolfram Language code: Import["expr.webp"]

Create an animated WebP file from a list of images:

Wolfram Language code: Export["animated.webp", {[image], [image], [image], [image], [image]}]

Create an animated WebP file from an AnimatedImage object:

Wolfram Language code: anim = AnimatedImage["ExampleData/pearls.png"];
Wolfram Language code: Export["animated.webp", anim]

Create an animated WebP from a Manipulate:

Wolfram Language code: m = Manipulate[Blur[[image], r], {r, 1, 10, 1}]
Wolfram Language code: Export["blur.webp", %]

Read the number of exported frames:

Wolfram Language code: Import["blur.webp", "ImageCount"]

Note that duplicate frames are stored as one and the display durations are adjusted accordingly:

Wolfram Language code: Import["blur.webp", "DisplayDurations"]

Import Elements  (33)

Available Elements  (1)

List of available elements:

Wolfram Language code: Import["ExampleData/flowers.webp", "Elements"]

Data Representation  (12)

"AnimatedImage"  (1)

Import as an AnimatedImage object:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "AnimatedImage"]
Wolfram Language code: Head[%]

"Data"  (1)

Import the image data:

Wolfram Language code: data = Import["ExampleData/flowers.webp", "Data"]

Construct images of the proper type:

Wolfram Language code: Image[data, "Byte"]

"Graphics"  (1)

Import as a Graphics object:

Wolfram Language code: Import["ExampleData/flowers.webp", "Graphics"]
Wolfram Language code: Head[%]

"GraphicsList"  (2)

Get the data as a list of Graphics objects:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "GraphicsList"][[1 ;; 3]]

Specify the frames to import:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", {"GraphicsList", 1 ;; 3}]

"Image"  (1)

Import as an Image object:

Wolfram Language code: Import["ExampleData/flowers.webp", "Image"]
Wolfram Language code: Head[%]

This is the default import element for a single-frame WebP:

Wolfram Language code: Import["ExampleData/flowers.webp"]//Head

"ImageList"  (3)

Get the data as a list of Image objects:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "ImageList"]

This is the default import element for animated WebP:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp"]

Specify the frames to import:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", {"ImageList", 1 ;; 3}]

"Thumbnail"  (1)

Import thumbnail of an image:

Wolfram Language code: Import["ExampleData/flowers.webp", "Thumbnail"]

"ThumbnailList"  (2)

Import a list of thumbnails of a multi-framed image:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "ThumbnailList"][[1 ;; 3]]

Specify the frames to import:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", {"ThumbnailList", 1 ;; 3}]

Metadata  (20)

"AnimationRepetitions"  (1)

Get the number of times the animation is expected to repeat:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "AnimationRepetitions"]

"BitDepth"  (1)

Get the number of bits used for representing each color channel:

Wolfram Language code: Import["ExampleData/flowers.webp", "BitDepth"]

"CameraTopOrientation"  (1)

Get the camera orientation at the capture time:

Wolfram Language code: Import["ExampleData/flowers.webp", "CameraTopOrientation"]

"Channels"  (1)

Get the color encoding used on export:

Wolfram Language code: Import["ExampleData/flowers.webp", "Channels"]

"ColorSpace"  (1)

Get the color encoding used on export:

Wolfram Language code: Import["ExampleData/flowers.webp", "ColorSpace"]

Use ImageColorSpace to get the color space of an imported image:

Wolfram Language code: Import["ExampleData/flowers.webp"]//ImageColorSpace

"DateTime"  (1)

Get the date and time that the image was captured:

Wolfram Language code: Import["ExampleData/flowers.webp", "DateTime"]

"Exif"  (3)

Get Exif metadata:

Wolfram Language code: Import["ExampleData/flowers.webp", "Exif"]

Extract an individual tag from the association:

Wolfram Language code: Import["ExampleData/flowers.webp", "Exif"]["Image", "FNumber"]

Individual Exif tags can also be imported directly:

Wolfram Language code: Import["ExampleData/flowers.webp", "FNumber"]

Some Exif tags are processed to give more detailed information:

Wolfram Language code: Import["ExampleData/flowers.webp", "FlashInfo"]

Compare with the raw "Flash" tag:

Wolfram Language code: Import["ExampleData/flowers.webp", "RawExif"]["Image", "Flash"]

"DisplayDurations"  (1)

Get the duration of each frame in the animations:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "DisplayDurations"]

"FlashUsed"  (1)

Import a tag that shows whether the flash fired:

Wolfram Language code: Import["ExampleData/flowers.webp", "FlashUsed"]

"FlashUsed" is a subelement of the "FlashInfo" element:

Wolfram Language code: Import["ExampleData/flowers.webp", "Exif"]["Image", "FlashInfo"]

Extract "FlashUsed" from the full "Exif":

Wolfram Language code: Import["ExampleData/flowers.webp", "Exif"]["Image", "FlashInfo", "FlashUsed"]

"ImageCount"  (1)

Get the number of frames:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "ImageCount"]

"MetaInformation"  (1)

Get all the metadata:

Wolfram Language code: Import["ExampleData/flowers.webp", "MetaInformation"]//Keys

"RasterSize"  (1)

Get the dimensions of the image stored in the file:

Wolfram Language code: Import["ExampleData/flowers.webp", "RasterSize"]

Use ImageDimensions on an imported image gives the same result:

Wolfram Language code: Import["ExampleData/flowers.webp"]//ImageDimensions

"RawExif"  (1)

Import raw Exif data:

Wolfram Language code: Import["ExampleData/flowers.webp", "RawExif"]

Raw Exif tags return the actual values stored in the file:

Wolfram Language code: Import["ExampleData/flowers.webp", "RawExif"]["Image", "FocalLength"]

When importing "Exif", most tags are processed:

Wolfram Language code: Import["ExampleData/flowers.webp", "Exif"]["Image", "FocalLength"]

"RawXMP"  (1)

Import unprocessed XMP metadata:

Wolfram Language code: Import["ExampleData/flowers.webp", "RawXMP"]

"RedEyeCorrection"  (1)

Check whether a red-eye correction was performed:

Wolfram Language code: Import["ExampleData/flowers.webp", "RedEyeCorrection"]

"Summary"  (1)

Get the image summary:

Wolfram Language code: Import["ExampleData/flowers.webp", "Summary"]

"SummarySlideView"  (1)

Get the image frames' summary:

Wolfram Language code: Import["http://exampledata.wolfram.com/sample.webp", "SummarySlideView"]

"XMP"  (1)

Get XMP metadata:

Wolfram Language code: Import["ExampleData/flowers.webp", "XMP"]

Extract the XMP "BasicSchema" metadata:

Wolfram Language code: Import["ExampleData/flowers.webp", "XMP"]["XMPBasicSchema"]

Import Options  (6)

ImageResolution  (1)

By default, the image resolution is extracted from the file:

Wolfram Language code: Options[Import["ExampleData/flowers.webp"], ImageResolution]

Specify the resolution of the imported image:

Wolfram Language code: Options[Import["ExampleData/flowers.webp", ImageResolution -> 144], ImageResolution]

Specify different resolutions in and directions:

Wolfram Language code: Options[Import["ExampleData/flowers.webp", ImageResolution -> {72, 144}], ImageResolution]

"ImageTopOrientation"  (1)

By default, images are imported with the top orientation:

Wolfram Language code: Import["ExampleData/flowers.webp"]

Specify the side that is supposed to be on the top:

Wolfram Language code: Import["ExampleData/flowers.webp", "ImageTopOrientation" -> Left]

The correct orientation can also be achieved by rotating the image to be upright:

Wolfram Language code: ImageRotate[Import["ExampleData/flowers.webp", "ImageTopOrientation" -> Left], Top -> Left]

IncludeMetaInformation  (3)

By default, all available metadata is imported:

Wolfram Language code: Options[Import["ExampleData/flowers.webp"], MetaInformation]//Short

Possible classes of metadata for JPEG files are "Exif" and "XMP":

Wolfram Language code: Options[Import["ExampleData/flowers.webp"], MetaInformation][[1, 2]]//Keys

Import the image with no metadata:

Wolfram Language code: Options[Import["ExampleData/flowers.webp", IncludeMetaInformation -> None], MetaInformation]

Import the image with "XMP" metadata only:

Wolfram Language code: Options[Import["ExampleData/flowers.webp", IncludeMetaInformation -> {"XMP"}], MetaInformation]//Short

RasterSize  (1)

By default, images are imported in their full resolution:

Wolfram Language code: Import["ExampleData/flowers.webp"]
Wolfram Language code: ImageDimensions[%]

Specify the raster size of the imported WebP image:

Wolfram Language code: Import["ExampleData/flowers.webp", RasterSize -> 50]
Wolfram Language code: ImageDimensions[%]

Export Options  (7)

AnimationRepetitions  (1)

By default, animation is set to be repeated infinitely:

Wolfram Language code: anim = AnimatedImage[{[image], [image], [image], [image], [image]}];
Wolfram Language code: Export["animated.webp", anim]
Wolfram Language code: Import["animated.webp", "AnimationRepetitions"]

Specify the number of repetitions:

Wolfram Language code: Export["animated.webp", anim, AnimationRepetitions -> 2]
Wolfram Language code: Import["animated.webp", "AnimationRepetitions"]

CompressionLevel  (1)

By default, no compression is used during export:

Wolfram Language code: i = [image];
Wolfram Language code: Export["image.webp", i]
Wolfram Language code: ImageDifference[i, Import["image.webp"]]//MinMax

A larger CompressionLevel can decrease the file size:

Wolfram Language code: Export["image2.webp", i, CompressionLevel -> 1]
Wolfram Language code: FileByteCount /@ {"image.webp", "image2.webp"}

Notice the decreased quality of the exported image:

Wolfram Language code: Import["image2.webp"]

Compare the change in file size and quality difference using different compression levels:

Wolfram Language code: t = Table[{FileSize[Export["file.webp", i, CompressionLevel -> level]], ImageDistance[Import["file.webp"], i]}, {level, 0, 1, .05}];
Wolfram Language code: ListLinePlot[Transpose[t], ...]

"DisplayDurations"  (2)

By default, a fixed duration is used for all frames:

Wolfram Language code: anim = ConstantImage[#, 50]& /@ {Red, Green, Blue, Black}
Wolfram Language code: Export["animated.webp", anim]
Wolfram Language code: Import["animated.webp", "DisplayDurations"]

Specify the duration of each frame:

Wolfram Language code: Export["animated.webp", anim, "DisplayDurations" -> {.1, .2, .3, .4}]
Wolfram Language code: Import["animated.webp", "DisplayDurations"]

Duplicate frames are combined and the frame duration is adjusted accordingly:

Wolfram Language code: anim = ConstantImage[#, 50]& /@ {Red, Green, Blue, Black, Black, Black}
Wolfram Language code: Export["animated.webp", anim]
Wolfram Language code: Import["animated.webp", "DisplayDurations"]
Wolfram Language code: Import["animated.webp", "ImageCount"]

"ImageTopOrientation"  (1)

By default, the upright image is exported using "ImageTopOrientation"->Top:

Wolfram Language code: i = [image];
Wolfram Language code: Export["test.webp", i]
Wolfram Language code: Import[%]

Specify top orientation of the exported image:

Wolfram Language code: Export["test.webp", i, "ImageTopOrientation" -> Left]
Wolfram Language code: Import[%]

IncludeMetaInformation  (1)

By default, all existing metainformation is exported:

Wolfram Language code: i = [image];
Wolfram Language code: Export["image.webp", i]
Wolfram Language code: Import[%]//Options

Export no metadata:

Wolfram Language code: Export["image.webp", i, IncludeMetaInformation -> None]
Wolfram Language code: Import[%]//Options

RasterSize  (1)

By default, the image is exported in the full resolution:

Wolfram Language code: i = [image];
Wolfram Language code: ImageDimensions[i]
Wolfram Language code: Export["test.webp", i]
Wolfram Language code: Import[%, "RasterSize"]

Specify the raster size of the exported image:

Wolfram Language code: Export["test.webp", i, RasterSize -> 47]
Wolfram Language code: Import[%, "RasterSize"]