WOLFRAM

Wolfram Language & System Documentation Center

CloudExport[expr,"format"]

exports expr to a new anonymous cloud object in the specified format.

CloudExport[expr,"format","uri"]

exports to a cloud object at a given URI.

CloudExport[expr,"format",CloudObject["uri"]]

exports to a given cloud object.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
AppearanceElements  
AutoCopy  
AutoRemove  
Show More Show More
CachePersistence  
CloudBase  
CloudObjectNameFormat  
CloudObjectURLType  
CloudRenderingMethod  
IconRules  
Magnification  
MetaInformation  
Permissions  
SourceLink  
Applications  
Possible Issues  
See Also
Related Guides
Related Links
History
Cite this Page

CloudExport

CloudExport[expr,"format"]

exports expr to a new anonymous cloud object in the specified format.

CloudExport[expr,"format","uri"]

exports to a cloud object at a given URI.

CloudExport[expr,"format",CloudObject["uri"]]

exports to a given cloud object.

Details and Options

Examples

open all close all

Basic Examples  (2)

Export an image to the cloud:

Wolfram Language code: CloudExport[[image], "PNG"]

Export to a named cloud object:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot"]

Scope  (1)

Export to a named cloud object specified by a string:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot"]

Export to a named cloud object specified by a CloudObject:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", CloudObject["plot"]]

Export to a named cloud object specified by a URL:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", URL["https://www.wolframcloud.com/obj/documentation/plot"]]

Options  (13)

AppearanceElements  (1)

Export a CSV file with no appearance elements:

Wolfram Language code: data = Map[{DateString[#[[1]]], QuantityMagnitude[#[[2]]]}&, Normal[FinancialData["NVDA", Today - Quantity[1, "Month"]]]]; CloudExport[data, "JSON", AppearanceElements -> None]

When viewing the object on the web, only the content is shown with no header or footer:

AutoCopy  (1)

Export an expression with AutoCopy enabled:

Wolfram Language code: obj = CloudExport[TreeGraph[{12, 13, 14}], "NB", "treeGraph", AutoCopy -> True]

Construct a CloudObject with the environment view URL:

Wolfram Language code: CloudObject[obj, CloudObjectURLType -> "Environment"]

Click the URL to open the notebook, and click the link "Create a copy of this file" to make a copy:

AutoRemove  (1)

Export a plot to a temporary object:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", AutoRemove -> True]

CachePersistence  (1)

Export an image that will be cached in the browser with a cache timeout of 1 day:

Wolfram Language code: obj = CloudExport[RandomImage[1, {250, 250}, ColorSpace -> "RGB"], "PNG", CachePersistence -> Quantity[1, "Days"]]

Check the value of the "cache-control" header from the response:

Wolfram Language code: Lookup[URLRead[obj]["Headers"], "cache-control"]

CloudBase  (1)

Export an object to a different cloud:

Wolfram Language code: CloudExport[WeatherData[$GeoLocation, "Temperature", "NonMetricValue"], "Text", "temperature", CloudBase -> "https://www.epc.example.com"]

CloudObjectNameFormat  (1)

Export to a cloud object, returning the URL in the user UUID format:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot", CloudObjectNameFormat -> "CloudUserUUID"]

CloudObjectURLType  (1)

Write to a cloud object and return the URL in the form for opening within the cloud environment:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plot", CloudObjectURLType -> "Environment"]

CloudRenderingMethod  (1)

Export a notebook with CloudRenderingMethod"InteractiveBoxes" to ensure it is rendered interactively, even if the automatic choice would be "Bitmap":

Wolfram Language code: CloudExport[ Notebook[{Cell[BoxData[ToBoxes[DynamicModule[{x = 0}, Table[Slider[Dynamic[x]], 2]]]], "Output"]}], "NB", CloudRenderingMethod -> "InteractiveBoxes"]

IconRules  (1)

Export an expression with no icons:

Wolfram Language code: obj = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", IconRules -> None]

Confirm the expression has no icons:

Wolfram Language code: Options[obj, IconRules]

Magnification  (1)

Export a notebook with quadruple magnification:

Wolfram Language code: CloudExport[Grid[Partition[Range[9], 3], Frame -> All], "NB", Magnification -> 4]

MetaInformation  (1)

Export a web search of current events, saving the current geolocated city in metainformation:

Wolfram Language code: obj = CloudExport[WebSearch["events near " <> CommonName[$GeoLocationCity]], "WL", MetaInformation -> {"City" -> $GeoLocationCity}]

Retrieve the metainformation later:

Wolfram Language code: Options[obj, MetaInformation]

Permissions  (1)

Export a cloud object that will require another user to be logged in to access it:

Wolfram Language code: CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", Permissions -> {"Authenticated" -> "Read"}]

SourceLink  (1)

Export an image with a cloud object given as the source:

Wolfram Language code: source = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "plotOrig"]; obj = CloudExport[Plot[Sin[x], {x, 0, 10}], "GIF", "sinePlot", SourceLink -> source]

View the source link:

Wolfram Language code: Options[CloudObject["sinePlot"], SourceLink]

Applications  (1)

Export a list of all countries as a CSV file on the Wolfram Cloud:

Wolfram Language code: CloudExport[EntityClass["Country", "Countries"][{"Name", "Population"}] /. q_Quantity :> QuantityMagnitude[q], "CSV", "countriespopulation.csv"]

The data can be imported using CloudImport:

Wolfram Language code: CloudImport["countriespopulation.csv"]//Short

Possible Issues  (1)

Using CloudExport for expressions like APIFunction that have special behavior in the cloud does not activate their special behavior:

Wolfram Language code: api = CloudExport[APIFunction[{"P" -> Number, "r" -> Number, "t" -> Number}, #P(1 + #r * #t)&], "WL"]

Calling the cloud object does not do any computation since an expression is simply displayed using text, which happens to be imported as something readable by URLExecute:

Wolfram Language code: URLExecute[api, {"P" -> 1000, "r" -> 2.3, "t" -> 72}]

In order to create a usable APIFunction, it must be deployed with CloudDeploy or CloudPublish:

Wolfram Language code: api = CloudDeploy[APIFunction[{"P" -> Number, "r" -> Number, "t" -> Number}, #P(1 + #r * #t)&]]

Now it reads the parameters and evaluates the function when invoked, as intended:

Wolfram Language code: URLExecute[api, {"P" -> 1000, "r" -> 2.3, "t" -> 72}]
Wolfram Research (2014), CloudExport, Wolfram Language function, https://reference.wolfram.com/language/ref/CloudExport.html (updated 2019).

Text

Wolfram Research (2014), CloudExport, Wolfram Language function, https://reference.wolfram.com/language/ref/CloudExport.html (updated 2019).

CMS

Wolfram Language. 2014. "CloudExport." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/CloudExport.html.

APA

Wolfram Language. (2014). CloudExport. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CloudExport.html

BibTeX

@misc{reference.wolfram_2026_cloudexport, author="Wolfram Research", title="{CloudExport}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/CloudExport.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_cloudexport, organization={Wolfram Research}, title={CloudExport}, year={2019}, url={https://reference.wolfram.com/language/ref/CloudExport.html}, note=[Accessed: 12-June-2026]}