WOLFRAM

Wolfram Language & System Documentation Center

"BloombergTerminal" (Service Connection)

This service connection requires Wolfram Finance Platform »
Connect your Bloomberg Terminal account to the Wolfram Language to obtain and analyze live market data.
Bloomberg entities are automatically mapped to Wolfram Language entities for immediate or asynchronous lookup.

Connecting & Authenticating

ServiceConnect["BloombergTerminal"] creates a connection to the Bloomberg LP Desktop API. To use this service, you must have an active subscription with Bloomberg Professional Services and Bloomberg Terminal installed.
Authentication occurs via the Bloomberg Terminal app.

Entity Values

Entity["BloombergTerminal","name"]["property"] gets the value of the specified property for the Bloomberg Terminal entity with the specified name.

Requests

ServiceExecute["BloombergTerminal","request",params] sends a request to the BloombergTerminal API, using parameters params.
ServiceExecute[req] sends a ServiceRequest object req to the Bloomberg Terminal API.
ServiceSubmit["BloombergTerminal","request",params] submits an asynchronous task requesting data from the Bloomberg Terminal API, using parameters params.
ServiceSubmit[req] submits an asynchronous task requesting data from the Bloomberg Terminal API.
ServiceSubmit[ContinuousTask[req]] submits a ServiceRequest that object req be continually updated.
ServiceSubmit[ContinuousTask[req,end]] submits a ServiceRequest that object req be continually updated until the time specified by end.
ServiceSubmit[ContinuousTask[req,tspan]] submits a ServiceRequest that object req be continually updated over the time span tspan.
The following requests may be made:

Properties

Requests:

"Properties" — look up properties supported by Bloomberg Terminal service

Requests:

"PropertyInformation" — look up description for the specified properties.

Parameters:
  • "Properties"(required)Bloomberg properties
    • Requests:

    "PropertySearch" — look up description for the specified fields

    Parameters:
  • "Query"NoneBloomberg properties

    • Instruments

    Requests:

    "InstrumentSearch" — look up instruments

    Parameters:
  • "Query"Nonequery term
    "YellowKeyFilter"Nonefilter product type
    MaxItems100number of elements to return

    • Market Data

    Requests:

    "Lookup" — look up information on Bloomberg Terminal service

    Parameters:
  • "Instrument"(required)Bloomberg instrument name or Bloomberg Global ID (BBGID)
    "Properties"(required)Bloomberg properties
    • Requests:

    "TickData" — tick-by-tick history

    Parameters:
  • "Instrument"(required)Bloomberg instrument name or BBGID
    "Date"Automatictime interval of tick events
    "EventType""TRADE"tick events corresponding to the event type
    • Requests:

    "IntradayBars" — returns OHLC (open, high, low, close) prices

    Parameters:
  • "Instrument"(required)Bloomberg instrument name or BBGID
    "Date"Automaticdate range, specified as an Interval or Span
    "Event""TRADE"intraday bar data for the corresponding event
    • Requests:

    "HistoricalData" — returns historical data

    Parameters:
  • "Instruments"(required)Bloomberg instrument name or BBGID
    "Properties"(required)Bloomberg Properties
    "Date"Automaticdate range

    • Examples

    open all close all

    Basic Examples  (6)

    Create a new connection:

    Wolfram Language code: ServiceConnect["BloombergTerminal"]

    Get the property "PX_LAST" of the BloombergTerminal entity "MSFT US Equity":

    Wolfram Language code: Entity["BloombergTerminal", "MSFT US Equity"]["PX_LAST"]

    Get the first 5 Bloomberg Terminal properties:

    Wolfram Language code: Take[EntityProperties["BloombergTerminal"], 5]

    Count all Bloomberg Terminal properties:

    Wolfram Language code: Length[EntityProperties["BloombergTerminal"]]

    Get "TickEvents" for a "TRADE" event:

    Wolfram Language code: EntityValue[Entity["BloombergTerminal", "MSFT US Equity"], EntityProperty["BloombergTerminal", "TickEvents", { "Event" -> "TRADE", "Date" -> DateObject[{2019, 5, 16, 8, 30, 0}] ;; DateObject[{2019, 5, 16, 8, 35, 0}] } ] ]

    Get "IntradayBars" for a "TRADE" event:

    Wolfram Language code: EntityValue[Entity["BloombergTerminal", "MSFT US Equity"], EntityProperty[ "BloombergTerminal", "IntradayBars", { "Event" -> "TRADE", "Date" -> DateObject[{2018, 12, 18, 8, 30, 0}] ;; DateObject[{2018, 12, 18, 13, 35, 0}] ;; 60 } ] ]

    Get "IntradayBars" for a "BID" event:

    Wolfram Language code: ts = EntityValue[Entity["BloombergTerminal", "MSFT US Equity"], EntityProperty["BloombergTerminal", "IntradayBars", { "Event" -> "BID", "Date" -> DateObject[{2018, 12, 18, 8, 30, 0}] ;; DateObject[{2018, 12, 19, 13, 35, 0}] ;; 60 } ] ]

    Values stored in the TimeSeries:

    Wolfram Language code: Take[ts["Values"], 3]

    Continually update "BID", "ASK" and "PX_LAST" for an instrument:

    Wolfram Language code: task = ServiceSubmit[ ContinuousTask[ ServiceRequest[ "BloombergTerminal", "MarketData", { "Instrument" -> "MSFT US Equity", "TriggerFields" -> {"BID", "ASK", "PX_LAST"} } ] ] , HandlerFunctions -> <|"MarketDataEvents" -> ((mktData = #Result)&)|>]
    Wolfram Language code: Dynamic[mktData]
    Wolfram Language code: TaskRemove[task]

    Scope  (7)

    Get an Association for a list of entities:

    Wolfram Language code: EntityValue[ { Entity["BloombergTerminal", "VOD LN Equity"], Entity["BloombergTerminal", "AAPL US Equity"] } , "LAST_PRICE" , "EntityAssociation" ]

    Get index members:

    Wolfram Language code: Dataset[ServiceExecute["BloombergTerminal", "Lookup", <| "Instruments" -> {"SPX Index"}, "Fields" -> {"INDX_MEMBERS"} |> ]]

    Plot daily "OPEN" price for "GE US Equity" since January 1, 2018:

    Wolfram Language code: DateListPlot[ EntityValue[ Entity["BloombergTerminal", "GE US Equity"], EntityProperty[ "BloombergTerminal", "OPEN", {"Date" -> Interval[{DateObject[{2018}], Today}]} ] ] ]

    Plot "HIGH" price for "GE US Equity" for every "Month" since January 1, 1990:

    Wolfram Language code: DateListPlot[EntityValue[ Entity["BloombergTerminal", "GE US Equity"] , EntityProperty[ "BloombergTerminal", "HIGH", { "Date" -> DateObject[{1990}] ;; Today ;; "Month" } ] ] ]

    Create a ServiceRequest to submit:

    Wolfram Language code: requestBT = ServiceRequest["BloombergTerminal", <| "Request" -> "MarketData", "Parameters" -> <| "Instrument" -> "MSFT US Equity", "TriggerFields" -> {"BID", "ASK"} |> |> ]

    Submit the request and receive updates as they happen:

    Wolfram Language code: task = ServiceSubmit[ ContinuousTask[requestBT], HandlerFunctions -> <|"MarketDataEvents" -> ((mktData = #Result)&)|> ]
    Wolfram Language code: mktData

    Remove the task:

    Wolfram Language code: TaskRemove[task]

    Create a task:

    Wolfram Language code: requestBT = ServiceRequest["BloombergTerminal", <| "Request" -> "MarketData", "Parameters" -> <|"Instrument" -> "AAPL US Equity", "TriggerFields" -> {"BID", "ASK"}|> |> ]

    Submit the task:

    Wolfram Language code: task = ServiceSubmit[ ContinuousTask[requestBT], HandlerFunctions -> <|"MarketDataEvents" -> (Set[res, #]&)|> ]

    List the keys:

    Wolfram Language code: res//Keys

    Received result:

    Wolfram Language code: res["Result"]

    Remove all running tasks:

    Wolfram Language code: TaskRemove /@ Tasks[]

    Create a request to fetch fields:

    Wolfram Language code: req = ServiceRequest["BloombergTerminal", "Properties"]

    Asynchronously fetch fields:

    Wolfram Language code: fields = {}; ServiceSubmit[req, HandlerFunctions -> <|"FieldResponse" -> ((fields = Join[fields, #Result])&)|>]
    Wolfram Language code: Dynamic[Length[fields]]