WOLFRAM

Wolfram Language & System Documentation Center

AnnotationDelete[obj]

deletes all annotations of the object obj.

AnnotationDelete[{obj,itemspec}]

deletes all annotations of the items of obj specified by itemspec.

AnnotationDelete[spec,key]

deletes the annotation key specified by spec.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graph & Networks  
Graph annotations  
Vertex annotations  
Edge annotations  
Regions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

AnnotationDelete

AnnotationDelete[obj]

deletes all annotations of the object obj.

AnnotationDelete[{obj,itemspec}]

deletes all annotations of the items of obj specified by itemspec.

AnnotationDelete[spec,key]

deletes the annotation key specified by spec.

Details

  • Typically used to delete annotations for objects and specific items in an object.
  • AnnotationDelete[spec,key] returns the object specified in spec with the annotation key deleted.
  • For standard annotations, AnnotationDelete effectively resets the value to the annotation default value.
  • Possible objects with items that can be annotated:
  • Audiotime points and time intervals
    BoundaryMeshRegionmesh cells
    CSGRegiongeometric regions
    Graphvertices and edges
    MeshRegionmesh cells
  • Item specification itemspec for each type of object is given in its reference page.

Examples

open all close all

Basic Examples  (3)

Remove a vertex or edge annotation:

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> "here"}, EdgeStyle -> {12 -> Red}]
Wolfram Language code: {AnnotationDelete[{g, 1}, VertexLabels], AnnotationDelete[{g, 12}, EdgeStyle]}

Remove a style or label annotation:

Wolfram Language code: mr = MengerMesh[1, MeshCellStyle -> {{1, All} -> Red}, MeshCellLabel -> {0 -> "Index"}]
Wolfram Language code: {AnnotationDelete[{mr, {1, All}}, MeshCellStyle], AnnotationDelete[{mr, 0}, MeshCellLabel]}

Annotate an Audio object:

Wolfram Language code: a = Import["ExampleData/rule30.wav"];res = AudioAnnotate[a, {"tag1" -> {.5 -> "v11", {1, 1.5} -> "v12"}, "tag2" -> {.1 -> "v21", {.7, 1.5} -> "v22"}}];

Remove the annotation with a specific tag:

Wolfram Language code: AnnotationDelete[res, "tag1"]//AudioAnnotationLookup

Scope  (11)

Graph & Networks  (7)

Graph annotations  (5)

Remove one annotation from vertices:

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> {1 -> Small}, EdgeStyle -> {12 -> Brown}, EdgeLabels -> {12 -> "hello"}]
Wolfram Language code: AnnotationDelete[{g, 1}, VertexStyle]

And from edges:

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeLabels]

Remove all annotations from vertices:

Wolfram Language code: AnnotationDelete[{g, 1}]

And from edges:

Wolfram Language code: AnnotationDelete[{g, 12}]

Remove several annotations from vertices:

Wolfram Language code: CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> {1 -> Small}, VertexLabels -> {1 -> "vertex"}];
Wolfram Language code: AnnotationDelete[{[image], 1}, {VertexLabels, VertexStyle}]

And from edges:

Wolfram Language code: WheelGraph[4, DirectedEdges -> True, EdgeStyle -> {_ -> Arrowheads[0.08], 12 -> Directive[Brown, Arrowheads[0.08]]}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, {EdgeStyle, EdgeLabels}]

AnnotationDelete works with undirected graphs:

Wolfram Language code: CycleGraph[3, EdgeStyle -> {12 -> Brown}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeStyle]

Directed graphs:

Wolfram Language code: CycleGraph[3, DirectedEdges -> True, EdgeStyle -> {12 -> Directive[Arrowheads[Small], Brown], Arrowheads[Small]}, EdgeLabels -> {12 -> "edge"}];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeStyle]

Weighted graphs:

Wolfram Language code: With[{g = CycleGraph[3], w = 0.3Range[3], pl = {Above, Right, Right} /. {Right -> {1 / 2, {-0.4, 1 / 2}}, Above -> {1 / 2, {1 / 2, 0}}}}, Graph[VertexList[g], EdgeList[g], EdgeWeight -> w, VertexShapeFunction -> "Name", EdgeLabels -> Thread[EdgeList[g] -> MapThread[Placed, {w, pl}]], VertexCoordinates -> GraphEmbedding[g]]];
Wolfram Language code: AnnotationDelete[{[image], 12}, EdgeLabels]

Vertex annotations  (1)

Set several annotations for a graph:

Wolfram Language code: g = CompleteGraph[4, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 4}, VertexStyle] = Red; AnnotationValue[{g, 1}, VertexLabels] = "hello"; AnnotationValue[{g, 1}, VertexShape] = [image]; AnnotationValue[{g, 1}, VertexSize] = Large; AnnotationValue[{g, 2}, VertexShapeFunction] = "Square";AnnotationValue[{g, 1}, VertexWeight] = 100;AnnotationValue[{g, 2}, "Material"] = "Wood";
Wolfram Language code: g

Remove vertex annotations including VertexStyle:

Wolfram Language code: AnnotationDelete[{g, 4}, VertexStyle]

VertexLabels:

Wolfram Language code: AnnotationDelete[{g, 1}, VertexLabels]

VertexSize:

Wolfram Language code: AnnotationDelete[{g, 1}, VertexSize]

VertexShape:

Wolfram Language code: AnnotationDelete[{g, 1}, VertexShape]

VertexShapeFunction:

Wolfram Language code: AnnotationDelete[{g, 2}, VertexShapeFunction]

VertexCoordinates:

Wolfram Language code: AnnotationDelete[{g, 1}, VertexCoordinates]

A custom annotation:

Wolfram Language code: MemberQ[PropertyList[{g, 2}], "Material"]
Wolfram Language code: AnnotationDelete[{g, 2}, "Material"];
Wolfram Language code: MemberQ[PropertyList[{%, 2}], "Material"]

Edge annotations  (1)

Set several annotations for a graph:

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 12}, EdgeStyle] = Brown; AnnotationValue[{g, 12}, EdgeLabels] = "hello"; AnnotationValue[{g, 34}, EdgeShapeFunction] = "HalfFilledDoubleArrow"; AnnotationValue[{g, 12}, EdgeWeight] = 42; AnnotationValue[{g, 24}, "Resistance"] = 50.;
Wolfram Language code: g

Remove edge annotations including EdgeStyle:

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeStyle]

EdgeLabels:

Wolfram Language code: AnnotationDelete[{g, 12}, EdgeLabels]

EdgeShapeFunction:

Wolfram Language code: AnnotationDelete[{g, 34}, EdgeShapeFunction]

A custom annotation:

Wolfram Language code: MemberQ[AnnotationKeys[{g, 24}], "Resistance"]
Wolfram Language code: AnnotationDelete[{g, 24}, "Resistance"];
Wolfram Language code: MemberQ[AnnotationKeys[{%, 24}], "Resistance"]

Regions  (4)

Remove one annotation from a child region:

Wolfram Language code: CSGRegion["Union", {Style[Ball[], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[{%, {1}}, "CSGRegionStyle"]

Remove all annotations from a child region:

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Metal"], Red], Cuboid[]}]
Wolfram Language code: AnnotationDelete[{%, {1}}]

Remove an annotation from all child regions:

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Wood"], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[%, "CSGRegionStyle"]
Wolfram Language code: AnnotationKeys[{%, {1}}]

Remove all annotations from a CSGRegion object:

Wolfram Language code: CSGRegion["Union", {Style[Annotation[Ball[], "Material" -> "Wood"], Red], Style[Cuboid[], Blue]}]
Wolfram Language code: AnnotationDelete[%]
Wolfram Language code: AnnotationKeys[{%, {1}}]

Applications  (2)

Linda wants to be anonymous in the presentation of the family gathering. Hide her vertex label:

Wolfram Language code: ExampleData[{"NetworkGraph", "FamilyGathering"}]
Wolfram Language code: AnnotationDelete[{%, "Linda"}, VertexLabels]

Use Fold to apply AnnotationDelete repeatedly:

Wolfram Language code: g = CycleGraph[8, VertexStyle -> Table[i -> RandomChoice[{Red, Green, Blue}], {i, 8}], VertexSize -> Large]
Wolfram Language code: Fold[AnnotationDelete[{#1, #2}, VertexStyle]&, g, Range[1, 7]]

See all the partial results:

Wolfram Language code: FoldList[AnnotationDelete[{#1, #2}, VertexStyle]&, g, Range[1, 7]]

Properties & Relations  (6)

Use Annotation as a wrapper to specify annotations in functions such as Graph:

Wolfram Language code: Graph[{Annotation[1, {VertexSize -> Medium, VertexStyle -> Red}], 2, 3}, {12, 23, 31}]

Use AnnotationValue to extract values:

Wolfram Language code: g = CompleteGraph[4, VertexStyle -> {1 -> Red}, VertexSize -> Small]
Wolfram Language code: AnnotationValue[{g, 1}, VertexStyle]

For undefined annotations, the value $Failed is returned:

Wolfram Language code: AnnotationValue[{g, 1}, "foo"]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], "foo"]

Use AnnotationValue to set annotations in a graph:

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: AnnotationValue[{g, 1}, VertexSize] = Small;

The original graph has changed:

Wolfram Language code: g

Use AnnotationValue to unset annotations in a graph:

Wolfram Language code: g = CompleteGraph[4, VertexSize -> {1 -> Small}]
Wolfram Language code: AnnotationValue[{g, 1}, VertexSize]=.;

The original graph has changed:

Wolfram Language code: g

Use AnnotationKeys to test for the presence of a annotation:

Wolfram Language code: g = CompleteGraph[4, VertexLabels -> {1 -> one, 4 -> four}]
Wolfram Language code: MemberQ[AnnotationKeys[{g, 1}], VertexLabels]

Generate a list of vertex label rules:

Wolfram Language code: Cases[VertexList[g], v_ /; MemberQ[AnnotationKeys[{g, v}], VertexLabels] :> v -> AnnotationValue[{g, v}, VertexLabels]]

Use Annotate to set a annotation without changing the original:

Wolfram Language code: g = CompleteGraph[4]
Wolfram Language code: Annotate[{g, 1}, VertexSize -> Medium]

The original graph is unchanged:

Wolfram Language code: g

Possible Issues  (1)

AnnotationValue is typically faster than AnnotationDelete:

Wolfram Language code: g = Graph[Annotation[#, VertexWeight -> 10.]& /@ Range[1000], {}];
Wolfram Language code: Timing@Do[AnnotationValue[{g, v}, VertexWeight]=., {v, VertexList[g]}]
Wolfram Language code: g = Graph[Annotation[#, VertexWeight -> 10.]& /@ Range[1000], {}];
Wolfram Language code: Timing@Do[g = AnnotationDelete[{g, v}, VertexWeight], {v, VertexList[g]}]
Wolfram Research (2019), AnnotationDelete, Wolfram Language function, https://reference.wolfram.com/language/ref/AnnotationDelete.html (updated 2025).

Text

Wolfram Research (2019), AnnotationDelete, Wolfram Language function, https://reference.wolfram.com/language/ref/AnnotationDelete.html (updated 2025).

CMS

Wolfram Language. 2019. "AnnotationDelete." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/AnnotationDelete.html.

APA

Wolfram Language. (2019). AnnotationDelete. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AnnotationDelete.html

BibTeX

@misc{reference.wolfram_2026_annotationdelete, author="Wolfram Research", title="{AnnotationDelete}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/AnnotationDelete.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_annotationdelete, organization={Wolfram Research}, title={AnnotationDelete}, year={2025}, url={https://reference.wolfram.com/language/ref/AnnotationDelete.html}, note=[Accessed: 13-June-2026]}