ArcCotDegrees
gives the arc cotangent in degrees of the complex number 
.
Details
- ArcCotDegrees, along with other inverse trigonometric and trigonometric functions, is studied in high-school geometry courses and is also used in many scientific disciplines.
- All results are given in degrees.
- For real
, the results are always in the range 
to 
, excluding 0. - ArcCotDegrees[z] returns the angle
in degrees for which the ratio of the adjacent side to the opposite side of a right triangle is 
. - For certain special arguments, ArcCotDegrees automatically evaluates to exact values.
- ArcCotDegrees can be evaluated to arbitrary numerical precision.
- ArcCotDegrees automatically threads over lists.
- ArcCotDegrees[z] has a branch cut discontinuity in the complex
plane running from 
to 
. - ArcCotDegrees can be used with Interval, CenteredInterval and Around objects.
- Mathematical function, suitable for both symbolic and numerical manipulation.
Examples
open all close allBasic Examples (7)
ArcCotDegrees[1]Calculate the angle BAC of this right triangle:
β = ArcCotDegrees[6 / 4]The numerical value of this angle:
%//NSolve an inverse trigonometric equation:
Solve[ArcCotDegrees[x] == 60, x]Solve an inverse trigonometric inequality:
Reduce[ArcCotDegrees[x] > 60, x]Apply ArcCotDegrees to the following list:
ArcCotDegrees[{0, 2 - Sqrt[3], (1/Sqrt[3]), 1, Sqrt[3], 2 + Sqrt[3]}]Plot over a subset of the reals:
Plot[ArcCot[x], {x, -5, 5}]Asymptotic expansion at Infinity:
Series[ArcCotDegrees[x], {x, ∞, 5}]Scope (39)
Numerical Evaluation (6)
ArcCotDegrees[2.5]N[ArcCotDegrees[2 / 3], 50]The precision of the output tracks the precision of the input:
ArcCotDegrees[0.66666666666666666666666666666666666666666667]Evaluate for complex arguments:
ArcCotDegrees[1.5 + 0.3I]Evaluate ArcCotDegrees efficiently at high precision:
ArcCotDegrees[2.5`500]//TimingArcCotDegrees[2.5`100000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
ArcCotDegrees[Interval[{1, Sqrt[3]}]]ArcCotDegrees[CenteredInterval[1, 1 / 100]]ArcCotDegrees[CenteredInterval[1 + 2I, (1 + I) / 100]]Or compute average-case statistical intervals using Around:
ArcCotDegrees[Around[.9, 0.01]]Compute the elementwise values of an array:
ArcCotDegrees[{{1, Sqrt[3]}, {0, Sqrt[3]}}]Or compute the matrix ArcCotDegrees function using MatrixFunction:
MatrixFunction[ArcCotDegrees[#]&, {{1, Sqrt[3]}, {0, Sqrt[3]}}]Specific Values (5)
Values of ArcCotDegrees at fixed points:
Table[ArcCotDegrees[n ], {n, -1, 1}]Simple exact values are generated automatically:
ArcCotDegrees[(1/Sqrt[3])]ArcCotDegrees[Infinity]ArcCotDegrees[ComplexInfinity]Singular points of ArcCotDegrees:
{ArcCotDegrees[I], ArcCotDegrees[-I]}Find the value of 
satisfying equation 
:
f[x_] := ArcCotDegrees[x] - 60;sol = Solve[f[x] == 0, x]xzero = x /. First[sol]Plot[f[x], {x, 0, 2}, Rule[...]]Visualization (4)
Plot the ArcCotDegrees function:
Plot[ArcCotDegrees[x], {x, -10, 10}]Plot over a subset of the complexes:
ComplexPlot3D[ArcCotDegrees[z], {z, -3 - 2I, 3 + 2I}, Rule[...]]Plot the real part of ArcCotDegrees:
ComplexContourPlot[Re[ArcCotDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]Plot the imaginary part of ArcCotDegrees:
ComplexContourPlot[Im[ArcCotDegrees[z]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]Polar plot with ArcCotDegrees:
Table[PolarPlot[ArcCotDegrees[k ϕ], {ϕ, -3π, 3π}, ...], {k, 1, 4}]Function Properties (12)
ArcCotDegrees is defined for all real values:
FunctionDomain[ArcCotDegrees[x], x]FunctionDomain[ArcCotDegrees[z], z, Complexes]ArcCotDegrees achieves all real values except 0 from the interval 
:
FunctionRange[ArcCotDegrees[x], x, y]FunctionRange[ArcCotDegrees[x], x, y, Complexes]ArcCotDegrees is an odd function:
ArcCotDegrees[-x]ArcCotDegrees has the mirror property ![cot^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{cot, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]](Files/ArcCotDegrees.en/14.png "cot^(-1)(TemplateBox[{x}, Conjugate])=TemplateBox[{{{cot, ^, {(, {-, 1}, )}}, (, x, )}}, Conjugate]"){kind=small}
:
FullSimplify[ArcCotDegrees[Conjugate[x]] == Conjugate[ArcCotDegrees[x]]]ArcCotDegrees is not an analytic function:
FunctionAnalytic[ArcCotDegrees[x], x]FunctionMeromorphic[ArcCotDegrees[x], x]ArcCotDegrees is neither non-decreasing nor non-increasing:
FunctionMonotonicity[ArcCotDegrees[x], x]ArcCotDegrees is injective:
FunctionInjective[ArcCotDegrees[x], x]Plot[{ArcCotDegrees[x], 1 / 2}, {x, -360, 360}]ArcCotDegrees is not surjective:
FunctionSurjective[ArcCotDegrees[x], x]Plot[{ArcCotDegrees[x], 2, 0}, {x, -180, 180}]ArcCotDegrees is neither non-negative nor non-positive:
FunctionSign[ArcCotDegrees[x], x]ArcCotDegrees has both singularity and discontinuity at zero:
FunctionSingularities[ArcCotDegrees[x], x]FunctionDiscontinuities[ArcCotDegrees[x], x]ArcCotDegrees is neither convex nor concave:
FunctionConvexity[ArcCotDegrees[x], x]ArcCotDegrees is convex for x in [0,100]:
FunctionConvexity[{ArcCotDegrees[x], 0 <= x <= 100}, x]Plot[ArcCotDegrees[x], {x, 0, 100}]TraditionalForm formatting:
ArcCotDegrees[α]//TraditionalFormDifferentiation (3)
derivative:Integration (2)
Indefinite integral of ArcCotDegrees:
Integrate[ArcCotDegrees[x], x]Definite integral of ArcCotDegrees over an interval centered at the origin is 0:
Integrate[ArcCotDegrees[x], {x, -1, 1}]Series Expansions (4)
Find the Taylor expansion using Series:
Series[ArcCotDegrees[x], {x, 1, 7}]Plot the first three approximations for ArcCotDegrees around 
:
terms = Normal@Table[Series[ArcCotDegrees[x], {x, 1, m}], {m, 1, 5, 2}];
Plot[{ArcCotDegrees[x], terms}, {x, 0, 2}]Find series expansions at branch points and branch cuts:
Series[ArcCotDegrees[x], {x, I, 1}]Series[ArcCotDegrees[x], {x, I / 2, 1}]Asymptotic expansion at a singular point:
Series[ArcCotDegrees[x], {x, I, 3}, Assumptions -> x > 0]//FullSimplifyArcCotDegrees can be applied to a power series:
ArcCotDegrees[SeriesData[x, 0, {1, 0, -1/3, 0, -1/45, 0, -2/945, 0, -1/4725, 0, -2/93555}, -1, 10, 1]]Function Identities and Simplifications (2)
Use FullSimplify to simplify expressions with ArcCotDegrees:
FullSimplify[16 ArcCotDegrees[5] - 4 ArcCotDegrees[239]]Use TrigToExp to express ArcCotDegrees using Log:
TrigToExp[ArcCotDegrees[z]]Function Representations (1)
Represent using ArcTanDegrees:
ArcTanDegrees[1 / x]//FullSimplifyApplications (8)
Solve inverse trigonometric equations:
Solve[ArcCotDegrees[α x + β] == 4, x]Solve[ArcCotDegrees[z]^2 + 3 ArcCotDegrees[z] == 2, z]Solve an inverse trigonometric equation with a parameter:
Reduce[ArcCotDegrees[CotDegrees[z]] == w, z]Use Reduce to solve inequalities involving ArcCotDegrees:
Reduce[ArcCotDegrees[x] > 60, x]Numerically find a root of a transcendental equation:
FindRoot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] == -3, {z, 0, 1 / 2}]Plot the function to check if the solution is correct:
Plot[ArcTanDegrees[z]^2 - 2 ArcTanDegrees[z + 1 / 3] + 3, {z, 0, 1 / 2}]Plot the real and imaginary parts of ArcCotDegrees:
ReImPlot[ArcCotDegrees[x], {x, -3, 3}]Different combinations of ArcCotDegrees with trigonometric functions:
{TanDegrees[ArcCotDegrees[z]], SecDegrees[ArcCotDegrees[1 / z]], SinDegrees[ArcCotDegrees[z ^ 2]], CosDegrees[ArcCotDegrees[z - 1]]}Addition theorem for cotangent function:
CotDegrees[ArcCotDegrees[x] + ArcCotDegrees[y]]//TrigExpand//SimplifyFind angles of the right triangle with sides 3, 4 and hypotenuse 5:
N[{ArcCotDegrees[4 / 3], ArcCotDegrees[3 / 4]}]Total[%]Properties & Relations (5)
Compositions with the inverse trigonometric functions:
{CotDegrees[ArcCotDegrees[z]], ArcCotDegrees[CotDegrees[z]]}Use PowerExpand to disregard multivaluedness of the ArcCotDegrees:
PowerExpand[%]Alternatively, evaluate under additional assumptions:
Refine[ArcCotDegrees[CotDegrees[z]], 0 < z < 90]Branch cut of ArcCotDegrees runs along the imaginary axis:
Plot3D[Re[ArcCotDegrees[x + I y]], {y, -2, 2}, {x, -2.5, 2.5}]ArcCotDegrees gives the angle in degrees, while ArcCot gives the same angle in radians:
ArcCotDegrees[1]ArcCot[1]FunctionExpand applied to ArcCotDegrees generates expressions in trigonometric functions in radians:
FunctionExpand[ArcCotDegrees[x]]FunctionExpand[ArcCotDegrees[x ^ 2]ArcCotDegrees[120 - x / 2]]ExpToTrig applied to the outputs of TrigToExp will generate trigonometric functions in radians:
ArcCotDegrees[z]//TrigToExpExpToTrig[%]Possible Issues (1)
Neat Examples (2)
Solve trigonometric equations involving ArcCotDegrees:
Reduce[ArcCotDegrees[z] + ArcCotDegrees[z - 1] == 90, z]//QuietNumerical value of this angle in degrees:
%//NPlot ArcCotDegrees at integer points:
ArrayPlot[Table[FractionalPart[Abs[ArcCotDegrees[x y]]], {x, -40, 40}, {y, -40, 40}]]Text
Wolfram Research (2024), ArcCotDegrees, Wolfram Language function, https://reference.wolfram.com/language/ref/ArcCotDegrees.html.
CMS
Wolfram Language. 2024. "ArcCotDegrees." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArcCotDegrees.html.
APA
Wolfram Language. (2024). ArcCotDegrees. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcCotDegrees.html