ArcCurvature
ArcCurvature[{x1,…,xn},t]
gives the curvature of the parametrized curve whose Cartesian coordinates xi are functions of t.
ArcCurvature[{x1,…,xn},t,chart]
interprets the xi as coordinates in the specified coordinate chart.
Details
- The arc curvature is sometimes referred to as the unsigned or Frenet curvature.
- The arc curvature of the curve
in three-dimensional Euclidean space is given by ![(TemplateBox[{{{{x, ^, {(, ', )}}, (, t, )}, x, {{x, ^, {(, {', '}, )}}, , {(, t, )}}}}, Norm])/(TemplateBox[{{{x, ^, {(, ', )}}, (, t, )}}, Norm]^3)](Files/ArcCurvature.en/2.png "(TemplateBox[{{{{x, ^, {(, ', )}}, (, t, )}, x, {{x, ^, {(, {', '}, )}}, , {(, t, )}}}}, Norm])/(TemplateBox[{{{x, ^, {(, ', )}}, (, t, )}}, Norm]^3)")
. - In a general space, the arc curvature of the curve
is given by ![TemplateBox[{{{D, /, {(, {D, , t}, )}}, {{(, { , {{x, ^, {(, ', )}}, (, t, )}}, )}, /, {(, TemplateBox[{{{x, ^, {(, ', )}}, (, t, )}}, Norm], )}}}}, Norm]](Files/ArcCurvature.en/4.png "TemplateBox[{{{D, /, {(, {D, , t}, )}}, {{(, { , {{x, ^, {(, ', )}}, (, t, )}}, )}, /, {(, TemplateBox[{{{x, ^, {(, ', )}}, (, t, )}}, Norm], )}}}}, Norm]")
. - In ArcCurvature[x,t], if x is a scalar expression, ArcCurvature gives the curvature of the parametric curve {t,x}.
- Coordinate charts in the third argument of ArcCurvature can be specified as triples {coordsys,metric,dim} in the same way as in the first argument of CoordinateChartData. The short form in which dim is omitted may be used.
Examples
open all close allBasic Examples (2)
A circle has constant curvature:
ArcCurvature[{Sin[θ], Cos[θ]}, θ]The curvature of Fermat's spiral expressed in polar coordinates:
Simplify[ArcCurvature[{t, t^2}, t, "Polar"], t > 0]Simplify[ArcCurvature[{-t, t^2}, t, "Polar"], t > 0]Visualize both branches of the curve:
PolarPlot[{Sqrt[t], -Sqrt[t]}, {t, 0, 4Pi}]Scope (5)
Curvature of loxodromes on a sphere:
ArcCurvature[{r Cos[t] / Cosh[Cot[b]t], r Sin[t] / Cosh[Cot[b]t], r Tanh[Cot[b]t]}, t]//SimplifyShow[ParametricPlot3D[Table[{Cos[t] / Cosh[Cot[b]t], Sin[t] / Cosh[Cot[b]t], Tanh[Cot[b]t]}, {b, {Pi / 2 - .1, Pi / 2, Pi / 2 + .1}}]//Evaluate, {t, 0, 30}, PlotStyle -> Thick, PlotRange -> All], Graphics3D[{Opacity[.5], Sphere[]}]]A parabola has maximal curvature ![2 TemplateBox[{a}, Abs]](Files/ArcCurvature.en/5.png "2 TemplateBox[{a}, Abs]"){kind=small}
at its vertex, which decreases to 0 at infinity:
ArcCurvature[a x ^ 2 + b x + c, x]Simplify[% /. x -> -b / (2a), a∈Reals]Curvature specifying metric, coordinate system, and parameters:
ArcCurvature[{1, t, 2t}, t, {{"Toroidal", {a}}, "Euclidean"}]Parallels and meridians can be considered either curves in flat space or on the two-dimensional sphere:
Show[ParametricPlot3D[{{Cos[2 t]Sin[1], Sin[1]Sin[2 t], Cos[1]}, {Cos[1]Sin[t], -Sin[1]Sin[t], Cos[t]}}, {t, 0, π}, PlotStyle -> Thick, PlotLegends -> {"Parallel", "Meridian"}], Graphics3D[{Opacity[.5], Sphere[]}], PlotRange -> All]As curves in three-space, they have the expected curvature inverse to their radius:
ArcCurvature[{R Sin[θ] Cos[φ], R Sin[θ] Sin[φ], R Cos[θ]}, θ, "Cartesian"]//SimplifyArcCurvature[{R Sin[θ] Cos[φ], R Sin[θ] Sin[φ], R Cos[θ]}, φ, "Cartesian"]//SimplifyOn the sphere, meridians, being geodesics, have zero curvature, but non-equatorial parallels do not:
ArcCurvature[{θ, φ}, θ, {"Standard", {"Sphere", {R}}}]ArcCurvature[{θ, φ}, φ, {"Standard", {"Sphere", {R}}}]% /. θ -> π / 2Curvature in higher-dimensional Euclidean space:
ArcCurvature[{t, t ^ 2, t ^ 3, t ^ 4, t ^ 5}, t]Applications (2)
Compute the radius of curvature of Bernoulli's lemniscate:
lem[t_] := (Cos[t]/1 + Sin[t]^2){1, Sin[t]}1 / ArcCurvature[lem[t], t]//SimplifyParametricPlot[lem[t], {t, 0, 2Pi}]The Fary–Milnor theorem states that a closed curve with total curvature 
less than 
cannot be knotted. Thus, a circle, which has total curvature 
, cannot be a knot:
unknot = 2{Sin[#], Cos[#], 0}&Integrate[ArcCurvature[unknot[t], t] Norm[unknot'[t]], {t, 0, 2Pi}]The trefoil knot must have total curvature at least 
, and it does:
knot = KnotData["Trefoil", "SpaceCurve"]NIntegrate[ArcCurvature[knot[t], t] Norm[knot'[t]], {t, 0, 2Pi}]ParametricPlot3D[{knot[t], unknot[t]}, {t, 0, 2Pi}, PlotStyle -> {Thick, Directive[Thick, Dashed]}, PlotLegends -> {"Trefoil (Knot)", "Circle (Unknot)"}]Properties & Relations (2)
ArcCurvature returns only a single curvature:
ArcCurvature[{t, 0, -t ^ 2, 2t ^ 3}, t]FrenetSerretSystem returns all 
curvatures in dimension 
:
First[FrenetSerretSystem[{t, 0, -t ^ 2, 2t ^ 3}, t]]ArcCurvature is unsigned:
ArcCurvature[{Sin[θ], Cos[θ]}, θ]ArcCurvature[{-Sin[θ], Cos[θ]}, θ]Extract the two-dimensional signed curvature from FrenetSerretSystem:
FrenetSerretSystem[{Sin[θ], Cos[θ]}, θ][[1, 1]]FrenetSerretSystem[{-Sin[θ], Cos[θ]}, θ][[1, 1]]Text
Wolfram Research (2014), ArcCurvature, Wolfram Language function, https://reference.wolfram.com/language/ref/ArcCurvature.html.
CMS
Wolfram Language. 2014. "ArcCurvature." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ArcCurvature.html.
APA
Wolfram Language. (2014). ArcCurvature. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ArcCurvature.html