WOLFRAM

Wolfram Language & System Documentation Center

BarabasiAlbertGraphDistribution[n,k]

represents a Barabasi–Albert graph distribution for n-vertex graphs where a new vertex with k edges is added at each step.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

BarabasiAlbertGraphDistribution

BarabasiAlbertGraphDistribution[n,k]

represents a Barabasi–Albert graph distribution for n-vertex graphs where a new vertex with k edges is added at each step.

Details

Examples

open all close all

Basic Examples  (2)

Generate a pseudorandom graph:

Wolfram Language code: RandomGraph[BarabasiAlbertGraphDistribution[30, 2]]

Degree distribution:

Wolfram Language code: RandomGraph[BarabasiAlbertGraphDistribution[10 ^ 4, 2]];
Wolfram Language code: EmpiricalDistribution[VertexDegree[%]]

Probability density function:

Wolfram Language code: DiscretePlot[PDF[%, k], {k, 7, 30}]

Scope  (3)

Generate simple undirected graphs:

Wolfram Language code: RandomGraph[BarabasiAlbertGraphDistribution[10, 3]]

Generate a set of pseudorandom graphs:

Wolfram Language code: RandomGraph[BarabasiAlbertGraphDistribution[10, 3], 4]

Compute probabilities and statistical properties:

Wolfram Language code: 𝒟 = GraphPropertyDistribution[VertexDegree[g, 1], gBarabasiAlbertGraphDistribution[30, 4]];
Wolfram Language code: NProbability[x ≥ 10, x𝒟]

Applications  (3)

The internet at the level of autonomous systems can be modeled with BarabasiAlbertGraphDistribution:

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Internet"}];
Wolfram Language code: 𝒢 = BarabasiAlbertGraphDistribution[VertexCount[g], Round[EdgeCount[g] / VertexCount[g]]]

The model captures the power-law nature of the empirical degree distribution:

Wolfram Language code: {Histogram[VertexDegree[g], {"Log", 10}, {"Log", "PDF"}], Histogram[VertexDegree[RandomGraph[𝒢]], {"Log", 10}, {"Log", "PDF"}]}

The model has a lower clustering coefficient:

Wolfram Language code: N[GlobalClusteringCoefficient[RandomGraph[𝒢]]]
Wolfram Language code: N[GlobalClusteringCoefficient[g]]

Use the Barabasi–Albert graph distribution as a model of the Western States Power Grid network:

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];
Wolfram Language code: 𝒢 = BarabasiAlbertGraphDistribution[VertexCount[g], Round[EdgeCount[g] / VertexCount[g]]]

The model captures the power-law nature of the empirical degree distribution:

Wolfram Language code: f[g_] := Map[{#[[1]], #[[2]] / VertexCount[g]}&, Tally[VertexDegree[g]]];
Wolfram Language code: {ListLogLogPlot[f[g]], ListLogLogPlot[f[RandomGraph[𝒢]]]}

A social network with 400 people and prominent hubs is modeled with BarabasiAlbertGraphDistribution. Find the expected number of ties separating a person at the hub from the most remote person in the network:

Wolfram Language code: 𝒟 = GraphPropertyDistribution[VertexEccentricity[g, First[GraphHub[g]]], gBarabasiAlbertGraphDistribution[400, 3]];
Wolfram Language code: NExpectation[x, x𝒟]

Properties & Relations  (5)

Distribution of the number of vertices:

Wolfram Language code: GraphPropertyDistribution[VertexCount[g], gBarabasiAlbertGraphDistribution[n, k]]

Distribution of the number of edges:

Wolfram Language code: GraphPropertyDistribution[EdgeCount[g], gBarabasiAlbertGraphDistribution[n, k]]

Degree distribution:

Wolfram Language code: 𝒟[n_, k_] := EmpiricalDistribution[VertexDegree[RandomGraph[BarabasiAlbertGraphDistribution[n, k]]]];

The distribution can be approximated by ZipfDistribution:

Wolfram Language code: ℰ = TruncatedDistribution[{5, ∞}, ZipfDistribution[2]];
Wolfram Language code: DiscretePlot[Evaluate[{PDF[𝒟[10 ^ 4, 6], d], PDF[ℰ, d]}], {d, 7, 25}, Joined -> True]

The degree distribution follows a power law:

Wolfram Language code: PDF[ℰ, d]

Use RandomSample to simulate a BarabasiAlbertGraphDistribution:

Wolfram Language code: barabasi[n_, k_] /; n ≤ k + 1 := CompleteGraph[n]
Wolfram Language code: barabasi[n_, k_] /; n > k + 1 := Module[{g = barabasi[n - 1, k]}, Graph[Join[EdgeList[g], Map[n#&, RandomSample[VertexDegree[g] -> VertexList[g], k]]]]]

Pseudorandom graphs:

Wolfram Language code: Table[barabasi[n, 2], {n, 4, 7}]

In BarabasiAlbertGraphDistribution[n,k], there is a maximum clique of size k+1:

Wolfram Language code: RandomGraph[BarabasiAlbertGraphDistribution[8, 3]]
Wolfram Language code: FindClique[%]

Neat Examples  (1)

Randomly colored vertices:

Wolfram Language code: HighlightGraph[RandomGraph[BarabasiAlbertGraphDistribution[10 ^ 2, 3]], Table[Style[i, RandomChoice[ColorData[45, "ColorList"]]], {i, 10 ^ 2}]]
Wolfram Research (2010), BarabasiAlbertGraphDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html.

Text

Wolfram Research (2010), BarabasiAlbertGraphDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html.

CMS

Wolfram Language. 2010. "BarabasiAlbertGraphDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html.

APA

Wolfram Language. (2010). BarabasiAlbertGraphDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html

BibTeX

@misc{reference.wolfram_2026_barabasialbertgraphdistribution, author="Wolfram Research", title="{BarabasiAlbertGraphDistribution}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_barabasialbertgraphdistribution, organization={Wolfram Research}, title={BarabasiAlbertGraphDistribution}, year={2010}, url={https://reference.wolfram.com/language/ref/BarabasiAlbertGraphDistribution.html}, note=[Accessed: 13-June-2026]}