Wolfram Language & System Documentation Center

BesselK

BesselK[n,z]

gives the modified Bessel function of the second kind .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
satisfies the differential equation .
BesselK[n,z] has a branch cut discontinuity in the complex z plane running from to .
FullSimplify and FunctionExpand include transformation rules for BesselK.
For certain special arguments, BesselK automatically evaluates to exact values.
BesselK can be evaluated to arbitrary numerical precision.
BesselK automatically threads over lists.
BesselK can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: BesselK[0, 0.53]

Plot over a subset of the reals:

Wolfram Language code: Plot[BesselK[0, x], {x, 0.5, 3}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[BesselK[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[BesselK[0, x], {x, 0, 3}]

Series expansion at Infinity:

Wolfram Language code: Series[BesselK[0, x], {x, ∞, 4}]//Normal

Scope (45)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: BesselK[0, 4.0]

Evaluate to high precision:

Wolfram Language code: N[BesselK[0, 4], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: BesselK[1, 4.000000000000000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: BesselK[1 + I, 3.0 - 2I]

Evaluate BesselK efficiently at high precision:

Wolfram Language code: BesselK[0, 4`500]//Timing

Wolfram Language code: BesselK[0, 4`5000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: BesselK[1 / 2, Interval[{2.15, 2.16}]]

Wolfram Language code: BesselK[1 / 2, CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: BesselK[2, Around[2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: BesselK[0.5, {{1, 2}, {3, 4}}]

Or compute the matrix BesselK function using MatrixFunction:

Wolfram Language code: MatrixFunction[BesselK[0.5, #]&, {{1, 2}, {3, 4}}]

Specific Values (4)

Value of BesselK for integers () orders at :

Wolfram Language code: {BesselK[0, 0], BesselK[1, 0]}

For half-integer index, BesselK evaluates to elementary functions:

Wolfram Language code: Table[BesselK[(2n - 1/2), x], {n, 1, 3}]

Limiting value at infinity:

Wolfram Language code: Limit[BesselK[n, x], x -> Infinity]

Find the value of satisfying equation :

Wolfram Language code: sol = Solve[BesselK[0, x] == 2, x]//Quiet

Visualize the result:

Wolfram Language code:

xzero = x /. First[sol];
Plot[BesselK[0, x], {x, 0, 1}, Epilog -> Style[Point[{xzero, BesselK[0, xzero]}], Red, PointSize[Large]]]

Visualization (3)

Plot the BesselK function for integer orders ():

Wolfram Language code: Plot[{BesselK[0, x], BesselK[1, x]}, {x, 0, 5}]

Plot the real and imaginary parts of the BesselK function for integer orders ():

Wolfram Language code: ReImPlot[{BesselK[0, x], BesselK[1, x]}, {x, -3, 3}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

Function Properties (11)

is defined for all real values greater than 0:

Wolfram Language code: FunctionDomain[BesselK[n, x], x]

Complex domain:

Wolfram Language code: FunctionDomain[BesselK[n, z], z, Complexes]

For real , achieves all positive real values:

Wolfram Language code: FunctionRange[BesselK[π, x], x, y]

BesselK is an even function with respect to the first parameter:

Wolfram Language code: BesselK[-n, z]//FullSimplify

is not an analytic function:

Wolfram Language code: Table[FunctionAnalytic[BesselK[n, z], z], {n, -2, 2}]

BesselK is neither non-decreasing nor non-increasing:

Wolfram Language code: Table[FunctionMonotonicity[BesselK[n, z], z], {n, 5}]

Wolfram Language code: Table[FunctionMonotonicity[BesselK[1 / n, z], z], {n, 5}]

is injective for all real :

Wolfram Language code: FunctionInjective[BesselK[n, z], z, Assumptions -> n∈Reals]

Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], .5}, {z, 0, 5}]

is not surjective for any real :

Wolfram Language code: FunctionSurjective[BesselK[n, z], z, Assumptions -> n∈Reals]

Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], -1}, {z, 0, 5}]

BesselK is neither non-negative nor non-positive:

Wolfram Language code: Table[FunctionSign[BesselK[n, z], z], {n, 4}]

BesselK has both singularity and discontinuity for z≤0:

Wolfram Language code: FunctionSingularities[BesselK[n, z], z]

Wolfram Language code: FunctionDiscontinuities[BesselK[n, z], z]

is convex on its real domain:

Wolfram Language code: FunctionConvexity[{BesselK[n, z], z > 0}, z, Assumptions -> n∈Reals]

TraditionalForm formatting:

Wolfram Language code: BesselK[n, r]//TraditionalForm

Differentiation (3)

First derivative:

Wolfram Language code: D[BesselK[n, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[BesselK[n, x], {x, k}], {k, 1, 4}]

Plot higher derivatives for order :

Wolfram Language code:

Plot[Evaluate[derivs /. n -> 0], {x, 0, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Formula for the derivative:

Wolfram Language code: D[BesselK[n, x], {x, j}]

Integration (3)

Indefinite integral of BesselK:

Wolfram Language code: Integrate[BesselK[n, x], x]

Integrate expressions involving BesselK:

Wolfram Language code: Integrate[x^n BesselK[0, x], {x, 0, Infinity}, Assumptions -> n ≥ 0]

Wolfram Language code: Integrate[BesselJ[n, x] BesselK[n, x], x]

Definite integral of BesselK over its real domain:

Wolfram Language code: Integrate[BesselK[n, x], {x, 0, Infinity}]

Series Expansions (5)

Series expansion for around :

Wolfram Language code: Series[BesselK[0, x], {x, 0, 5}]

Plot the first three approximations for around :

Wolfram Language code:

terms = Normal@Table[Series[BesselK[0, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{BesselK[0, x], terms}, {x, 0, 3}]

General term in the series expansion of BesselK:

Wolfram Language code: SeriesCoefficient[BesselK[0, x], {x, 1, n}]

Asymptotic expansion for BesselK:

Wolfram Language code: Series[BesselK[n, x], {x, Infinity, 2}]//Normal

Taylor expansion at a generic point:

Wolfram Language code: Series[BesselK[n, x], {x, x0, 2}]// FullSimplify

BesselK can be applied to a power series:

Wolfram Language code: BesselK[0, Log[1 + x] + O[x] ^ 2]

Integral Transforms (3)

LaplaceTransform:

Wolfram Language code: LaplaceTransform[BesselK[n, t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[BesselK[n, r], r, s ]

Compute the Mellin transform using MellinTransform:

Wolfram Language code: MellinTransform[BesselK[n, x], x, s ]

Function Identities and Simplifications (3)

Use FullSimplify to simplify Bessel functions:

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

Verify the identity :

Wolfram Language code: BesselI[ν, z] BesselK[ν + 1, z] + BesselI[ν + 1, z] BesselK[ν, z] == (1/z)//FullSimplify

Recurrence relations :

Wolfram Language code: FullSimplify[z(BesselK[n + 1, z] - BesselK[n - 1, z]) == 2n BesselK[n, z]]

Function Representations (4)

Integral representation of BesselK:

Wolfram Language code: (Sqrt[π]z^n/2^nGamma[n + (1/2)])Integrate[Exp[-z t](t^2 - 1)^n - (1/2), {t, 1, Infinity}]

Represent using BesselI and Sin:

Wolfram Language code: FullSimplify[(Pi/2)(BesselI[-n, x] - BesselI[n, x]/Sin[n Pi])]

BesselK can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[BesselK[n, x], x]

Wolfram Language code: Activate[%]

BesselK can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[BesselK[k, z], k]

Applications (3)

Specific heat of the relativistic ideal gas per particle:

Wolfram Language code: cv[β_] := 3 + β(β - (BesselK[1, β]/BesselK[2, β])(3 + β (BesselK[1, β]/BesselK[2, β])))

Find the ultra‐relativistic limit:

Wolfram Language code: Series[cv[β], {β, 0, 4}, Assumptions -> β > 0]

PDF of geometric mean of two independent exponential random variables:

Wolfram Language code:

PDF[TransformedDistribution[GeometricMean[{x, y}], {xExponentialDistribution[λ], yExponentialDistribution[μ]}], z]

Wolfram Language code: FullSimplify[%]

Surface tension of an electrolyte solution as a function of concentration y:

Wolfram Language code:

2 BesselK[0, 2Sqrt[y]]HypergeometricPFQ[{1}, {2 / 3, 5 / 3}, y] + 3Sqrt[y]BesselK[1, 2Sqrt[y]]HypergeometricPFQ[{1}, {5 / 3, 5 / 3}, y];

Onsager law for small concentrations:

Wolfram Language code: Normal[Series[%, {y, 0, 0}, Assumptions -> y > 0]]

Properties & Relations (2)

Use FullSimplify to simplify Bessel functions:

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

The exponential generating function for BesselK:

Wolfram Language code: ExponentialGeneratingFunction[BesselK[n, k], n, x]

Possible Issues (1)

With numeric arguments, half-integer Bessel functions are not automatically evaluated:

Wolfram Language code: BesselK[11 / 2, 1]

For symbolic arguments they are:

Wolfram Language code: BesselK[11 / 2, x]

This can lead to inaccuracies in machine-precision evaluation:

Wolfram Language code: {BesselK[55 / 2, -20.], BesselK[55 / 2, x] /. x -> -20.}

Neat Examples (1)

Plot the Riemann surface of :

Wolfram Language code:

With[{n = 0, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[(-1)^n kBesselK[n, r Exp[I φ]] + (-1)^n(k - 1) - 1π I k BesselI[n, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.46], Opacity[0.6]]]]

Plot the Riemann surface of :

Wolfram Language code:

With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[-k ν π I] BesselK[ν, r Exp[I φ]] - π I ChebyshevU[k - 1, Cos[ν π]] BesselI[ν, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

BesselK

Details

Examples

Basic Examples (5)

Scope (45)

Numerical Evaluation (6)

Specific Values (4)

Visualization (3)

Function Properties (11)

Differentiation (3)

Integration (3)

Series Expansions (5)

Integral Transforms (3)

Function Identities and Simplifications (3)

Function Representations (4)

Applications (3)

Properties & Relations (2)

Possible Issues (1)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

BesselK

Details

Examples

Basic Examples (5)

Scope (45)

Numerical Evaluation (6)

Specific Values (4)

Visualization (3)

Function Properties (11)

Differentiation (3)

Integration (3)

Series Expansions (5)

Integral Transforms (3)

Function Identities and Simplifications (3)

Function Representations (4)

Applications (3)

Properties & Relations (2)

Possible Issues (1)

Neat Examples (1)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX