WOLFRAM

Wolfram Language & System Documentation Center

KelvinKei[z]

gives the Kelvin function TemplateBox[{z}, KelvinKei].

KelvinKei[n,z]

gives the Kelvin function TemplateBox[{n, z}, KelvinKei2].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

KelvinKei

KelvinKei[z]

gives the Kelvin function TemplateBox[{z}, KelvinKei].

KelvinKei[n,z]

gives the Kelvin function TemplateBox[{n, z}, KelvinKei2].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For positive real values of parameters, TemplateBox[{n, z}, KelvinKei2]=Im(e^(-npii/2)TemplateBox[{n, {z, , {e, ^, {(, {pi, , {i, /, 4}}, )}}}}, BesselK]). For other values, is defined by analytic continuation.
  • KelvinKei[n,z] has a branch cut discontinuity in the complex z plane running from to .
  • KelvinKei[z] is equivalent to KelvinKei[0,z].
  • For certain special arguments, KelvinKei automatically evaluates to exact values.
  • KelvinKei can be evaluated to arbitrary numerical precision.
  • KelvinKei automatically threads over lists.

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: KelvinKei[2.5]
Wolfram Language code: KelvinKei[2, 2.5]

Plot over a subset of the reals:

Wolfram Language code: ReImPlot[KelvinKei[x], {x, 0, 5}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[KelvinKei[3, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[KelvinKei[x], {x, 0, 5}]

Series expansion at Infinity:

Wolfram Language code: Series[KelvinKei[x], {x, ∞, 2}]//FullSimplify//Normal

Series expansion at a singular point:

Wolfram Language code: Series[KelvinKei[n, x], {x, -1, 2}, Assumptions -> x > 1]//FullSimplify

Scope  (34)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: KelvinKei[7.]
Wolfram Language code: KelvinKei[-1, .5]

Evaluate to high precision:

Wolfram Language code: N[KelvinKei[-6, 8], 50]
Wolfram Language code: N[KelvinKei[2], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: KelvinKei[3, 0.20444444000555555008005]

Complex number inputs:

Wolfram Language code: N[KelvinKei[2.7, 5 - I]]
Wolfram Language code: N[KelvinKei[I + 1.47, 5]]

Evaluate efficiently at high precision:

Wolfram Language code: KelvinKei[7, 5`100]//Timing
Wolfram Language code: KelvinKei[7, 5`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: KelvinKei[Around[1 / 9, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: KelvinKei[{{0, 1.2}, {1.2, 0}}]

Or compute the matrix KelvinKei function using MatrixFunction:

Wolfram Language code: MatrixFunction[KelvinKei, {{0, 1.2}, {1.2, 0}}]

Specific Values  (3)

Values at zero:

Wolfram Language code: KelvinKei[0]
Wolfram Language code: KelvinKei[2, 0]

Find the first positive maximum of KelvinKei[0,x]:

Wolfram Language code: xmax = x /. FindRoot[D[KelvinKei[0, x], x] == 0, {x, 5}]
Wolfram Language code: Plot[Re[KelvinKei[0, x]], {x, 0, 20}, Epilog -> Style[Point[{xmax, KelvinKei[0, xmax]}], PointSize[Large], Red]]

For some half-integer orders, KelvinKei evaluates to the same elementary functions:

Wolfram Language code: Table[KelvinKei[n, x Sqrt[2]], {n, {1 / 2, 3 / 2}}]//FunctionExpand

Visualization  (3)

Plot the KelvinKei function for integer () and half-integer () orders:

Wolfram Language code: Plot[{KelvinKei[0, x], KelvinKei[1, x], KelvinKei[-1 / 2, x]}, {x, 0, 10}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[KelvinKei[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[KelvinKei[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[KelvinKei[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[KelvinKei[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Function Properties  (11)

The real domain of TemplateBox[{0, x}, KelvinKei2]:

Wolfram Language code: FunctionDomain[KelvinKei[0, x], x]

The complex domain of TemplateBox[{0, x}, KelvinKei2]:

Wolfram Language code: FunctionDomain[KelvinKei[0, z], z, Complexes]

TemplateBox[{{-, {1, /, 2}}, x}, KelvinKei2] is defined for all real values greater than 0:

Wolfram Language code: FunctionDomain[KelvinKei[-1 / 2, x], x]

The complex domain is the whole plane except :

Wolfram Language code: FunctionDomain[KelvinKei[-1 / 2, z], z, Complexes]

Approximate function range of TemplateBox[{0, x}, KelvinKei2]:

Wolfram Language code: FunctionRange[KelvinKei[0, x], x, y]//N//Quiet

Approximate function range of TemplateBox[{1, x}, KelvinKei2]:

Wolfram Language code: FunctionRange[KelvinKei[1, x], x, y]//Quiet

Recurrence relations:

Wolfram Language code: KelvinKei[n, x] == -KelvinKei[2 + n, x] - (Sqrt[2] (1 + n) (KelvinKei[1 + n, x] + KelvinKer[1 + n, x])/x)//FullSimplify

TemplateBox[{n, z}, KelvinKei2] is not an analytic function:

Wolfram Language code: FunctionAnalytic[KelvinKei[n, z], z, Assumptions -> n∈Reals]

KelvinKei is neither non-decreasing nor non-increasing:

Wolfram Language code: Table[FunctionMonotonicity[KelvinKei[n, x], x, PositiveReals], {n, 4}]
Wolfram Language code: Table[FunctionMonotonicity[KelvinKei[1 / n, x], x, PositiveReals], {n, 4}]

KelvinKei is not injective:

Wolfram Language code: Table[FunctionInjective[KelvinKei[n, x], x], {n, 4}]
Wolfram Language code: Table[FunctionInjective[KelvinKei[1 / n, x], x], {n, 4}]
Wolfram Language code: Plot[{KelvinKei[1, x], KelvinKei[2, x], KelvinKei[1 / 3, x], .009}, {x, 0, 8}]

KelvinKei is neither non-negative nor non-positive:

Wolfram Language code: Table[FunctionSign[KelvinKei[n, x], x, PositiveReals], {n, 4}]

TemplateBox[{n, x}, KelvinKei2] has both singularity and discontinuity for :

Wolfram Language code: FunctionSingularities[KelvinKei[n, x], x]
Wolfram Language code: FunctionDiscontinuities[KelvinKei[n, x], x]

KelvinKei is neither convex nor concave:

Wolfram Language code: Table[FunctionConvexity[{KelvinKei[a, x], x > 0}, x], {a, 5}]

TraditionalForm formatting:

Wolfram Language code: KelvinKei[n, x]//TraditionalForm

Differentiation  (3)

The first derivative with respect to :

Wolfram Language code: D[KelvinKei[x], x]

The first derivative with respect to when :

Wolfram Language code: D[KelvinKei[1, x], x]

Higher derivatives with respect to :

Wolfram Language code: Table[D[KelvinKei[x], {x, k}], {k, 1, 5}]//Simplify

Plot the higher derivatives with respect to :

Wolfram Language code: Plot[%, {x, 0, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative", "Fifth Derivative"}]

Formula for the ^(th) derivative with respect to :

Wolfram Language code: D[KelvinKei[x], {x, k}]// FullSimplify

Integration  (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[KelvinKei[x], x]// FullSimplify

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, x]]// FullSimplify

The definite integral:

Wolfram Language code: Integrate[KelvinKei[x], {x, 0, 3}]

More integrals:

Wolfram Language code: Integrate[x KelvinKei[x]^2 , x]// FullSimplify
Wolfram Language code: Integrate[x^2KelvinKei[x], {x, 0, 10}]// FullSimplify

Series Expansions  (5)

Find the Taylor expansion using Series:

Wolfram Language code: Series[KelvinKei[n, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[KelvinKei[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{KelvinKei[x], terms}, {x, 0, 6}]

The general term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[KelvinKei[x], {x, 1, m}]//FullSimplify

Find the series expansion at Infinity:

Wolfram Language code: Series[KelvinKei[x], {x, Infinity, 1}]//FullSimplify

Find the series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[KelvinKei[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0 && z > 0]//Normal//FullSimplify//Quiet

The Taylor expansion at a generic point:

Wolfram Language code: Series[KelvinKei[x], {x, x0, 2}]//FullSimplify

Generalizations & Extensions  (1)

KelvinKei can be applied to a power series:

Wolfram Language code: KelvinKei[1, Sin[x] + O[x] ^ 3]

Applications  (3)

Solve the Kelvin differential equation:

Wolfram Language code: DSolve[x^4 Derivative[4][f][x] + 2 x^3 Derivative[3][f][x] - (1 + 2 n^2) (-x Derivative[1][f][x] + x^2 Derivative[2][f][x]) + (-4 n^2 + n^4 + x^4) f[x] == 0, f[x], x]

Plot the radial density profile for alternating current within a hollow cylinder:

Wolfram Language code: Plot[Abs[KelvinKer[0, r] + I KelvinKei[0, r]], {r, 1, 4}]

For some values, expressions with MeijerG are represented with KelvinKei:

Wolfram Language code: -(1/4) MeijerG[{{}, {(n/2)}}, {{-(n/4), (n/4), (-n + 2/4), (n + 2/4)}, {(n/2)}}, (x/4), (1/4)]//FullSimplify

Properties & Relations  (5)

The one‐argument form evaluates to the two-argument form:

Wolfram Language code: KelvinKei[x]

Use FullSimplify to simplify expressions involving Kelvin functions:

Wolfram Language code: D[x KelvinKei[1, Sqrt[2]x], x]
Wolfram Language code: FullSimplify[%]

Use FunctionExpand to expand Kelvin functions of half-integer orders:

Wolfram Language code: FunctionExpand[KelvinKei[1 / 2, x]]

Integrate expressions involving Kelvin functions:

Wolfram Language code: Integrate[x(KelvinKer[0, x]^2 + KelvinKei[0, x]^2), x]

KelvinKei can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[KelvinKei[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify
Wolfram Research (2007), KelvinKei, Wolfram Language function, https://reference.wolfram.com/language/ref/KelvinKei.html.

Text

Wolfram Research (2007), KelvinKei, Wolfram Language function, https://reference.wolfram.com/language/ref/KelvinKei.html.

CMS

Wolfram Language. 2007. "KelvinKei." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/KelvinKei.html.

APA

Wolfram Language. (2007). KelvinKei. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KelvinKei.html

BibTeX

@misc{reference.wolfram_2026_kelvinkei, author="Wolfram Research", title="{KelvinKei}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/KelvinKei.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_kelvinkei, organization={Wolfram Research}, title={KelvinKei}, year={2007}, url={https://reference.wolfram.com/language/ref/KelvinKei.html}, note=[Accessed: 13-June-2026]}