WOLFRAM

Wolfram Language & System Documentation Center

KelvinKer[z]

gives the Kelvin function TemplateBox[{z}, KelvinKer].

KelvinKer[n,z]

gives the Kelvin function TemplateBox[{n, z}, KelvinKer2].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Integration  
Series Expansions  
Generalizations & Extensions  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

KelvinKer

KelvinKer[z]

gives the Kelvin function TemplateBox[{z}, KelvinKer].

KelvinKer[n,z]

gives the Kelvin function TemplateBox[{n, z}, KelvinKer2].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For positive real values of parameters, TemplateBox[{n, z}, KelvinKer2]=Re(e^(-npii/2)TemplateBox[{n, {z, , {e, ^, {(, {pi, , {i, /, 4}}, )}}}}, BesselK]). For other values, is defined by analytic continuation.
  • KelvinKer[n,z] has a branch cut discontinuity in the complex z plane running from to .
  • KelvinKer[z] is equivalent to KelvinKer[0,z].
  • For certain special arguments, KelvinKer automatically evaluates to exact values.
  • KelvinKer can be evaluated to arbitrary numerical precision.
  • KelvinKer automatically threads over lists.

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: KelvinKer[2.5]
Wolfram Language code: KelvinKer[2, 2.5]

Plot over a subset of the reals:

Wolfram Language code: ReImPlot[KelvinKer[x], {x, 0, 5}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[KelvinKer[3, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[KelvinKer[x], {x, 0, 3}]

Series expansion at Infinity:

Wolfram Language code: Series[KelvinKer[x], {x, ∞, 2}]//FullSimplify//Normal

Series expansion at a singular point:

Wolfram Language code: Series[KelvinKer[n, x], {x, -1, 2}, Assumptions -> x > 1]//FullSimplify

Scope  (35)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: KelvinKer[-1, .5]
Wolfram Language code: KelvinKer[1, 8.]

Evaluate to high precision:

Wolfram Language code: N[KelvinKer[-6, 8], 50]
Wolfram Language code: N[KelvinKer[2], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: KelvinKer[3, 0.20444444000555555008005]

Complex number inputs:

Wolfram Language code: N[KelvinKer[2.7, 5 - I]]
Wolfram Language code: N[KelvinKer[I + 1.27, 5]]

Evaluate efficiently at high precision:

Wolfram Language code: KelvinKer[5, 3`100]//Timing
Wolfram Language code: KelvinKer[7, 25`1000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: KelvinKer[Around[.9, 0.1]]

Compute the elementwise values of an array:

Wolfram Language code: KelvinKer[2, {{0, 1.2I}, {1.2I, 0}}]

Or compute the matrix KelvinKer function using MatrixFunction:

Wolfram Language code: MatrixFunction[KelvinKer[2, #]&, {{0, 1.2I}, {1.2, 0}}]

Specific Values  (3)

Values at zero:

Wolfram Language code: KelvinKer[0]
Wolfram Language code: KelvinKer[2, 0]

Find the first positive maximum of KelvinKer[0,x]:

Wolfram Language code: xmax = x /. FindRoot[D[KelvinKer[0, x], x] == 0, {x, 5}]
Wolfram Language code: Plot[Re[KelvinKer[0, x]], {x, 0, 10}, Epilog -> Style[Point[{xmax, KelvinKer[0, xmax]}], PointSize[Large], Red]]

For some half-integer orders, KelvinKer evaluates to the same elementary functions:

Wolfram Language code: Table[KelvinKer[n, x Sqrt[2 ] ], {n, {-1 / 2, 1 / 2}}]//FunctionExpand

Visualization  (3)

Plot the KelvinKer function for integer () and half-integer () orders:

Wolfram Language code: Plot[{KelvinKer[0, x], KelvinKer[1, x], KelvinKer[-1 / 2, x]}, {x, 0, 10}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[KelvinKer[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[KelvinKer[0, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[KelvinKer[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[KelvinKer[-1 / 4, z]], {z, -3 - 6I, 3 + 6I}, IconizedObject[«PlotOptions»]]

Function Properties  (12)

The real domain of TemplateBox[{0, x}, KelvinKer2]:

Wolfram Language code: FunctionDomain[KelvinKer[0, x], x]

The complex domain of TemplateBox[{0, x}, KelvinKer2]:

Wolfram Language code: FunctionDomain[KelvinKer[0, z], z, Complexes]

TemplateBox[{{-, {1, /, 2}}, x}, KelvinKer2] is defined for all real values greater than 0:

Wolfram Language code: FunctionDomain[KelvinKer[-1 / 2, x], x]

The complex domain is the whole plane except :

Wolfram Language code: FunctionDomain[KelvinKer[-1 / 2, z], z, Complexes]

Approximate function range of TemplateBox[{0, x}, KelvinKer2]:

Wolfram Language code: FunctionRange[KelvinKer[0, x], x, y]//N//Quiet

Approximate function range of TemplateBox[{1, x}, KelvinKer2]:

Wolfram Language code: FunctionRange[KelvinKer[1, x], x, y]//Quiet

Functional identity:

Wolfram Language code: KelvinKer[n, x] == -(1/2 Sqrt[2] n)x (KelvinKei[-1 + n, x] + KelvinKei[1 + n, x] + KelvinKer[-1 + n, x] + KelvinKer[1 + n, x])//FullSimplify

TemplateBox[{0, z}, KelvinKer2] is not an analytic function:

Wolfram Language code: FunctionAnalytic[KelvinKer[n, z], z, Assumptions -> n∈Reals]

KelvinKer is neither non-decreasing nor non-increasing:

Wolfram Language code: Table[FunctionMonotonicity[{KelvinKer[n, x], x > 0}, x], {n, 4}]
Wolfram Language code: Table[FunctionMonotonicity[{KelvinKer[1 / n, x], x > 0}, x], {n, 4}]

KelvinKer is not injective:

Wolfram Language code: Table[FunctionInjective[KelvinKer[n, x], x], {n, 4}]
Wolfram Language code: Table[FunctionInjective[KelvinKer[1 / n, x], x], {n, 4}]
Wolfram Language code: Plot[{KelvinKer[1, x], KelvinKer[2, x], KelvinKer[1 / 3, x], -.1}, {x, 0, 6}]

KelvinKer[2,z] is not surjective:

Wolfram Language code: FunctionSurjective[{KelvinKer[2, x], 1 < x < 4}, x]
Wolfram Language code: Plot[{KelvinKer[2, x], -1}, {x, 0, 5}]

KelvinKer is neither non-negative nor non-positive:

Wolfram Language code: Table[FunctionSign[{KelvinKer[n, x], x > 0}, x], {n, 4}]

TemplateBox[{n, z}, KelvinKer2] has both singularity and discontinuity for :

Wolfram Language code: FunctionSingularities[KelvinKer[n, x], x]
Wolfram Language code: FunctionDiscontinuities[KelvinKer[n, x], x]

KelvinKer is neither convex nor concave:

Wolfram Language code: Table[FunctionConvexity[{KelvinKer[a, x], x > 0}, x], {a, 5}]

TraditionalForm formatting:

Wolfram Language code: KelvinKer[n, x]//TraditionalForm

Differentiation  (3)

The first derivative with respect to :

Wolfram Language code: D[KelvinKer[x], x]

The first derivative with respect to when :

Wolfram Language code: D[KelvinKer[1, x], x]

Higher derivatives with respect to :

Wolfram Language code: Table[D[KelvinKer[x], {x, k}], {k, 1, 5}]//Simplify

Plot the higher derivatives with respect to :

Wolfram Language code: Plot[%, {x, 0, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative", "Fifth Derivative"}]

Formula for the ^(th) derivative with respect to :

Wolfram Language code: D[KelvinKer[x], {x, k}]

Integration  (3)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[KelvinKer[x], x]// FullSimplify

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, x]]// FullSimplify

The definite integral:

Wolfram Language code: Integrate[KelvinKer[x], {x, 0, 5}]

More integrals:

Wolfram Language code: Integrate[x KelvinKer[x]^2, x]// FullSimplify
Wolfram Language code: Integrate[x^2 KelvinKer[x], {x, 0, 10}]// FullSimplify

Series Expansions  (5)

Find the Taylor expansion using Series:

Wolfram Language code: Series[KelvinKer[n, x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[KelvinKer[x], {x, 3, m}], {m, 1, 5, 2}]; Plot[{KelvinKer[x], terms}, {x, 0, 10}]

The general term in the series expansion using SeriesCoefficient:

Wolfram Language code: SeriesCoefficient[KelvinKer[x], {x, 1, m}]//FullSimplify

Find the series expansion at Infinity:

Wolfram Language code: Series[KelvinKer[x], {x, Infinity, 1}]//FullSimplify

Find the series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[KelvinKer[x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0 && z > 0]//FullSimplify//Quiet

The Taylor expansion at a generic point:

Wolfram Language code: Series[KelvinKer[x], {x, x0, 2}]//FullSimplify

Generalizations & Extensions  (1)

KelvinKer can be applied to a power series:

Wolfram Language code: KelvinKer[1, Sin[x] + O[x] ^ 3]

Applications  (3)

Solve the Kelvin differential equation:

Wolfram Language code: DSolve[x^4 Derivative[4][f][x] + 2 x^3 Derivative[3][f][x] - (1 + 2 n^2) (-x Derivative[1][f][x] + x^2 Derivative[2][f][x]) + (-4 n^2 + n^4 + x^4) f[x] == 0, f[x], x]

Plot the radial density profile for alternating current within a hollow cylinder:

Wolfram Language code: Plot[Abs[KelvinKer[0, r] + I KelvinKei[0, r]], {r, 1, 4}]

The derivative of MeijerG for some values is KelvinKer:

Wolfram Language code: D[(1/4) MeijerG[{{}, {1}}, {{(1/8), (3/8), (5/8), (7/8)}, {0}}, (x/4), (1/4)], x]//FullSimplify

Properties & Relations  (4)

The one‐argument form evaluates to the two-argument form:

Wolfram Language code: KelvinKer[x]

Use FullSimplify to simplify expressions involving Kelvin functions:

Wolfram Language code: D[x KelvinKer[1, Sqrt[2]x], x]
Wolfram Language code: FullSimplify[%]

Use FunctionExpand to expand Kelvin functions of half-integer orders:

Wolfram Language code: FunctionExpand[KelvinKer[1 / 2, x]]

KelvinKer can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[KelvinKer[n, x], x]
Wolfram Language code: Activate[%]//FullSimplify
Wolfram Research (2007), KelvinKer, Wolfram Language function, https://reference.wolfram.com/language/ref/KelvinKer.html.

Text

Wolfram Research (2007), KelvinKer, Wolfram Language function, https://reference.wolfram.com/language/ref/KelvinKer.html.

CMS

Wolfram Language. 2007. "KelvinKer." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/KelvinKer.html.

APA

Wolfram Language. (2007). KelvinKer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KelvinKer.html

BibTeX

@misc{reference.wolfram_2026_kelvinker, author="Wolfram Research", title="{KelvinKer}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/KelvinKer.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_kelvinker, organization={Wolfram Research}, title={KelvinKer}, year={2007}, url={https://reference.wolfram.com/language/ref/KelvinKer.html}, note=[Accessed: 13-June-2026]}