WOLFRAM

Wolfram Language & System Documentation Center

CarlsonRF[x,y,z]

gives the Carlson's elliptic integral TemplateBox[{x, y, z}, CarlsonRF].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Differentiation and Integration  
Function Representations  
Function Identities and Simplifications  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

CarlsonRF

CarlsonRF[x,y,z]

gives the Carlson's elliptic integral TemplateBox[{x, y, z}, CarlsonRF].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For , and , TemplateBox[{x, y, z}, CarlsonRF]=1/2int_0^infty(t+x)^(-1/2)(t+y)^(-1/2)(t+z)^(-1/2)dt.
  • CarlsonRF[x,y,z] has a branch cut discontinuity for .
  • For certain arguments, CarlsonRF automatically evaluates to exact values.
  • CarlsonRF can be evaluated to arbitrary numerical precision.
  • CarlsonRF automatically threads over lists.
  • CarlsonRF can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: CarlsonRF[1., 2., 3.]

Plot over a range of arguments:

Wolfram Language code: Plot[{CarlsonRF[t, 2, 3], CarlsonRF[1, t, 3], CarlsonRF[1, 2, t]}, {t, 0, 6}, PlotLegends -> "Expressions"]

CarlsonRF is related to the Legendre elliptic integral of the first kind TemplateBox[{phi, m}, EllipticF] for :

Wolfram Language code: Sin[ϕ] CarlsonRF[Cos[ϕ]^2, 1 - m Sin[ϕ]^2, 1] /. {ϕ -> Pi / 3, m -> 0.7}
Wolfram Language code: EllipticF[ϕ, m] /. {ϕ -> Pi / 3, m -> 0.7}

Scope  (17)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: N[CarlsonRF[4, 6, 8]]
Wolfram Language code: N[CarlsonRF[4, -6, 8]]

Evaluate at high precision:

Wolfram Language code: N[CarlsonRF[1, 4, 9], 50]

Precision of the output tracks the precision of the input:

Wolfram Language code: CarlsonRF[5, 3, 1.234567890123456789012345]
Wolfram Language code: CarlsonRF[5, 3, 1.2345678901234567890123456789012345]

Evaluate for complex arguments:

Wolfram Language code: CarlsonRF[I, 1 - 2I, 3. + I]

Evaluate efficiently at high precision:

Wolfram Language code: Timing[CarlsonRF[2, 6, 7`500]]
Wolfram Language code: Timing[Precision[CarlsonRF[2, 6, 7`100000]]]

CarlsonRF threads elementwise over lists:

Wolfram Language code: CarlsonRF[{1., 2., 3.}, {2., 3., 1.}, {3., 1., 2.}]

CarlsonRF can be used with Interval and CenteredInterval objects:

Wolfram Language code: CarlsonRF[Interval[{1.23, 1.24}], Interval[{2.34, 2.35}], Interval[{3.45, 3.46}]]
Wolfram Language code: CarlsonRF[CenteredInterval[3 / 2, 1 / 100], CenteredInterval[5 / 4, 1 / 100], CenteredInterval[7 / 6, 1 / 100]]

Specific Values  (4)

Simple exact results are generated automatically:

Wolfram Language code: CarlsonRF[x, x, x]
Wolfram Language code: CarlsonRF[x, 2, 2]

When one argument of CarlsonRF is zero, CarlsonRF reduces to the complete elliptic integral CarlsonRK:

Wolfram Language code: CarlsonRF[0, x, y]

When two of the arguments of CarlsonRF are identical and do not lie on the negative real axis, CarlsonRF reduces to CarlsonRC:

Wolfram Language code: CarlsonRF[x, 2 + 3I, 2 + 3I]

When all arguments of CarlsonRF are identical and do not lie on the negative real axis, CarlsonRF reduces to an elementary function:

Wolfram Language code: CarlsonRF[2 + 3I, 2 + 3I, 2 + 3I]

Differentiation and Integration  (2)

Derivative of CarlsonRF is proportional to CarlsonRD:

Wolfram Language code: D[CarlsonRF[x, y, z], z]
Wolfram Language code: D[CarlsonRF[x, y, z], y]

Indefinite integral of CarlsonRF:

Wolfram Language code: Integrate[CarlsonRF[x, y, z], z]

Function Representations  (1)

TraditionalForm formatting:

Wolfram Language code: CarlsonRF[x, y, z]//TraditionalForm

Function Identities and Simplifications  (4)

An equation relating CarlsonRF, CarlsonRG and CarlsonRD:

Wolfram Language code: 2CarlsonRG[x, y, z] == z CarlsonRF[x, y, z] + (Sqrt[x]Sqrt[y]/Sqrt[z]) - (1/3)(z - x)(z - y)CarlsonRD[x, y, z]//FullSimplify

CarlsonRF satisfies the Euler–Poisson partial differential equation:

Wolfram Language code: (x - y)Subscript[∂, x⁣y]CarlsonRF[x, y, z] + (1/2) Subscript[∂, y]CarlsonRF[x, y, z] - (1/2)Subscript[∂, x]CarlsonRF[x, y, z] == 0//FunctionExpand//FullSimplify

CarlsonRF satisfies Euler's homogeneity relation:

Wolfram Language code: x Subscript[∂, x]CarlsonRF[x, y, z] + y Subscript[∂, y]CarlsonRF[x, y, z] + z Subscript[∂, z]CarlsonRF[x, y, z] == -(1/2)CarlsonRF[x, y, z]//FunctionExpand//FullSimplify

A partial differential equation satisfied by CarlsonRF:

Wolfram Language code: Subscript[∂, x]CarlsonRF[x, y, z] + Subscript[∂, y]CarlsonRF[x, y, z] + Subscript[∂, z]CarlsonRF[x, y, z] == -(1/2Sqrt[x]Sqrt[y]Sqrt[z])//FunctionExpand//FullSimplify

Applications  (3)

Distance along a meridian of the Earth:

Wolfram Language code: With[{a = UnitConvert[GeodesyData["ITRF00", "SemimajorAxis"], $UnitSystem], e = GeodesyData["ITRF00", "Eccentricity"], ϕ = 29°}, a(1 - e^2)(Sin[ϕ]CarlsonRF[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1] + (e^2/3)Sin[ϕ]^3CarlsonRD[Cos[ϕ]^2, 1 - e^2Sin[ϕ]^2, 1])]

Compare with the result of GeoDistance:

Wolfram Language code: GeoDistance[GeoPosition[{0, 0}], GeoPosition[{29, 0}]]

Expectation value of the reciprocal square root of a quadratic form over a normal distribution:

Wolfram Language code: MatrixForm[mat = HilbertMatrix[3]]
Wolfram Language code: NExpectation[(Sqrt[2]/Sqrt[{u, v, w}.mat.{u, v, w}]), {u, v, w}ProductDistribution[{NormalDistribution[], 3}], Method -> "MonteCarlo"]//Quiet

Compare with the closed-form result in terms of CarlsonRF:

Wolfram Language code: N[(Gamma[(3 - 1/2)]/Gamma[(3/2)])(CarlsonRF@@Eigenvalues[mat]), 25]

Express EllipticLog in terms of CarlsonRF:

Wolfram Language code: With[{x = 1, a = 2, b = 6}, N[{-CarlsonRF[x, x + (a + Sqrt[a^2 - 4b]/2), x + (2b/a + Sqrt[a^2 - 4b])], EllipticLog[{x, Sqrt[x^3 + a x^2 + b x]}, {a, b}]}, 25]]

Properties & Relations  (1)

CarlsonRF is invariant under a permutation of its arguments:

Wolfram Language code: CarlsonRF[x, y, z] == CarlsonRF[z, x, y]
Wolfram Research (2021), CarlsonRF, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRF.html (updated 2023).

Text

Wolfram Research (2021), CarlsonRF, Wolfram Language function, https://reference.wolfram.com/language/ref/CarlsonRF.html (updated 2023).

CMS

Wolfram Language. 2021. "CarlsonRF." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/CarlsonRF.html.

APA

Wolfram Language. (2021). CarlsonRF. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRF.html

BibTeX

@misc{reference.wolfram_2026_carlsonrf, author="Wolfram Research", title="{CarlsonRF}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRF.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrf, organization={Wolfram Research}, title={CarlsonRF}, year={2023}, url={https://reference.wolfram.com/language/ref/CarlsonRF.html}, note=[Accessed: 12-June-2026]}