WOLFRAM

Wolfram Language & System Documentation Center

AppellF1[a,b1,b2,c,x,y]

is the Appell hypergeometric function of two variables .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

AppellF1

AppellF1[a,b1,b2,c,x,y]

is the Appell hypergeometric function of two variables .

Details

  • AppellF1 belongs to the family of Appell functions that generalizes the hypergeometric series and solves the system of Horn PDEs with polynomial coefficients.
  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • has a primary definition through the hypergeometric series sum_(m=0)^inftysum_(n=0)^infty(TemplateBox[{a, {m, +, n}}, Pochhammer] TemplateBox[{{b, _, 1}, m}, Pochhammer] TemplateBox[{{b, _, 2}, n}, Pochhammer] )/(TemplateBox[{c, {m, +, n}}, Pochhammer]m! n!)x^m y^n, which is convergent inside the region max(TemplateBox[{x}, Abs],TemplateBox[{y}, Abs])<1.
  • The region of convergence of the Appell F1 series for real values of its arguments is the following:
  • In general satisfies the following Horn PDE system »: .
  • reduces to when or .
  • For certain special arguments, AppellF1 automatically evaluates to exact values.
  • AppellF1 can be evaluated to arbitrary numerical precision.
  • AppellF1[a,b1,b2,c,x,y] has singular lines in two‐variable complex space at Re(x)=1 and Re(y)=1, and has branch cut discontinuities along the rays from to in and .
  • FullSimplify and FunctionExpand include transformation rules for AppellF1.

Examples

open all close all

Basic Examples  (8)

Evaluate numerically:

Wolfram Language code: AppellF1[2, 1, 1, 3, 0.7, 0.3]

Evaluate symbolically:

Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//Simplify

The defining sum:

Wolfram Language code: Sum[x^m y^n(Pochhammer[a, m + n]/Pochhammer[c, m + n])( Pochhammer[b1, m] Pochhammer[b2, n]/m! n! ), {m, 0, Infinity}, {n, 0, Infinity}]

Plot over a subset of the reals:

Wolfram Language code: Plot[AppellF1[1, 1, 1, 1, 4, x], {x, -2, 3}, PlotRange -> Automatic]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[AppellF1[1, 1, 1, 1, 4, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 0, 3}]

Series expansion at Infinity:

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, ∞, 5}]//Normal//FullSimplify

Series expansion at a singular point:

Wolfram Language code: Series[AppellF1[1, 1, 1, 1, 4, x], {x, 1, 2}]

Scope  (28)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 5.2]
Wolfram Language code: AppellF1[2, -1, 2, 5, 0.4, 1.3]

Evaluate to high precision:

Wolfram Language code: N[AppellF1[3, 2, 5, 2, 3, 5], 10]

The precision of the output tracks the precision of the input:

Wolfram Language code: AppellF1[1, 1, 3 / 5, 3, 2 / 3, 0.400000000024000000000000]

Complex number inputs:

Wolfram Language code: AppellF1[I, 1, 1 + I, 3.2, 0.5, 0.2 + 0.5 I]

Evaluate AppellF1 efficiently at high precision:

Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100]//Timing
Wolfram Language code: AppellF1[3, 2, 1, 2, 7, 7 / 4`100];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: AppellF1[ 1 / 2, 1, 5 / 2, 3, 1, Around[2.1, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1 / 2, {{1 / 2, 2}, {2, 1 / 2}}, {{1 / 2, 2}, {2, 1 / 2}}]

Or compute the matrix AppellF1 function using MatrixFunction:

Wolfram Language code: MatrixFunction[AppellF1[1 / 2, 1, 1 / 2, 1, #, #]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

Specific Values  (4)

Values at fixed points:

Wolfram Language code: AppellF1[1 / 2, 1, 1 / 2, 1, 2, 2]
Wolfram Language code: AppellF1[1 / 2, 1, 5 / 2, 3, 2, 2]

Evaluate symbolically:

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, 0]
Wolfram Language code: AppellF1[a, b, b, c, x, -x]

Value at zero:

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, 0, 0]

For simple parameters, AppellF1 evaluates to simpler functions:

Wolfram Language code: AppellF1[1, 1 / 2, 1, 1, x, y]//FullSimplify
Wolfram Language code: AppellF1[1, 1, 1, 2, x, y]//FullSimplify
Wolfram Language code: AppellF1[1 / 2, 1 / 2, 1, 3 / 2, x, y]//FullSimplify

Visualization  (4)

Plot the AppellF1 function for various parameters:

Wolfram Language code: Plot[{AppellF1[1, 1 / 2, 1, 1, x, 2], AppellF1[1, 1 / 2, 3, 1, x, 3], AppellF1[1, 1 / 2, 1, 1, x, 4]}, {x, -2, 2}]

Plot AppellF1 as a function of its second parameter :

Wolfram Language code: Plot[{AppellF1[1, 1, 2, 1, 2, y], AppellF1[1, 1, 4, 1, 3, y], AppellF1[1, 1, 1, 1, 4, y]}, {y, -2, 4}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[AppellF1[1, 1, 4, 1, 0, z]], {z, -5 - 5I, 5 + 5I}]

Plot the real part of F_1(2,1,4,3,0,z) in three dimensions:

Wolfram Language code: Plot3D[Re[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

Plot the imaginary part of F_1(2,1,4,3,0,z) in three dimensions:

Wolfram Language code: Plot3D[Im[AppellF1[2, 1, 4, 3, 0, x + I y]], {x, -4, 4}, {y, -4, 4}]

Function Properties  (9)

Real domain of AppellF1:

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x]

Complex domain of AppellF1:

Wolfram Language code: FunctionDomain[AppellF1[1, 1, 1, 2, x, y], x, Complexes]
Wolfram Language code: FunctionDomain[AppellF1[1, 1, 2, 2, x, y], x, Complexes]

AppellF1 is not an analytic function:

Wolfram Language code: FunctionAnalytic[AppellF1[1, 1, 1, 2, 4, x], x]

Has both singularities and discontinuities:

Wolfram Language code: FunctionSingularities[AppellF1[1, 1, 1, 2, 4, x], x]
Wolfram Language code: FunctionDiscontinuities[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] is injective:

Wolfram Language code: FunctionInjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], -2}, {x, 0, 3}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] is not surjective:

Wolfram Language code: FunctionSurjective[AppellF1[1, 1, 1, 1, 4, x], x]
Wolfram Language code: Plot[{AppellF1[1, 1, 1, 1, 4, x], 0}, {x, -5, 5}]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[AppellF1[1, 1, 1, 1, 4, x], x]

TemplateBox[{1, 1, 1, 1, 4, x}, AppellF1] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[AppellF1[1, 1, 1, 1, 4, x], x]

TraditionalForm formatting:

Wolfram Language code: AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y]//TraditionalForm

Differentiation  (3)

First derivative with respect to y:

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], y]

Higher derivatives with respect to y:

Wolfram Language code: Table[D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to y when a=b1=b2=2, c=10 and x=1/2:

Wolfram Language code: Plot[Evaluate[% /. {a -> 2, Subscript[b, 1] -> 2, Subscript[b, 2] -> 2, c -> 10, x -> 1 / 2}], {y, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to y:

Wolfram Language code: D[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {y, k}]// FullSimplify

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, 0, 2}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[AppellF1[2, 1, 1, 3, x, .3], {x, 0, m}], {m, 1, 5, 2}]; Plot[{AppellF1[2, 1, 1, 3, x, .3], terms//Evaluate}, {x, 0, 10}, PlotRange -> {-30, 30}]

Taylor expansion at a generic point:

Wolfram Language code: Series[AppellF1[a, Subscript[b, 1], Subscript[b, 2], c, x, y], {x, x0, 2}]//Normal// FullSimplify

Applications  (1)

The Appell function solves the following system of PDEs with polynomial coefficients:

Wolfram Language code: pde = {x(1 - x) f^(2, 0)[x, y] + y (1 - x) f^(1, 1)[x, y] + (c - (a + Subscript[b, 1] + 1)x) f^(1, 0)[x, y] - Subscript[b, 1] y f^(0, 1)[x, y] - a Subscript[b, 1] f[x, y] == 0, y (1 - y) f^(0, 2)[x, y] + x (1 - y) f^(1, 1)[x, y] + (c - (a + Subscript[b, 2] + 1)y) f^(0, 1)[x, y] - Subscript[b, 2] x f^(1, 0)[x, y] - a Subscript[b, 2] f[x, y] == 0};

Check that is a solution:

Wolfram Language code: (pde /. {a -> 1 / 4, Subscript[b, 1] -> 1 / 4, Subscript[b, 2] -> 1 / 4, c -> 1}) /. f -> Function[{x, y}, AppellF1[1 / 4, 1 / 4, 1 / 4, 1, x, y]];
Wolfram Language code: % /. Thread[{x, y} -> RandomReal[{-1, 1}, {2}, WorkingPrecision -> 50]]

Properties & Relations  (2)

Evaluate integrals in terms of AppellF1:

Wolfram Language code: Integrate[Sqrt[x](x + 1)^n (x + 2)^k , x]
Wolfram Language code: Integrate[Sin[x]^1 / 2 Cos[x]^1 / 2 (2 - Sin[x]^2)^1 / 2, x]

Use FullSimplify to simplify some expressions involving AppellF1:

Wolfram Language code: FullSimplify[x^5 AppellF1[(3/2), 1, 2, (5/2), x^3, x^5] + x^3 AppellF1[(3/2), 2, 1, (5/2), x^3, x^5] - (3 / 2/1 - x^3 - x^5 + x^8)]

Neat Examples  (1)

Many elementary and special functions are special cases of AppellF1:

Wolfram Language code: funclist = Inactivate[...];
Wolfram Language code: Grid[...]//TraditionalForm
Wolfram Research (1999), AppellF1, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF1.html (updated 2023).

Text

Wolfram Research (1999), AppellF1, Wolfram Language function, https://reference.wolfram.com/language/ref/AppellF1.html (updated 2023).

CMS

Wolfram Language. 1999. "AppellF1." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/AppellF1.html.

APA

Wolfram Language. (1999). AppellF1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AppellF1.html

BibTeX

@misc{reference.wolfram_2026_appellf1, author="Wolfram Research", title="{AppellF1}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/AppellF1.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_appellf1, organization={Wolfram Research}, title={AppellF1}, year={2023}, url={https://reference.wolfram.com/language/ref/AppellF1.html}, note=[Accessed: 12-June-2026]}