WOLFRAM

Wolfram Language & System Documentation Center

CarmichaelLambda[n]

gives the Carmichael function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Applications  
Basic Applications  
Primality Testing  
Cryptography  
Number Theory  
Properties & Relations  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

CarmichaelLambda

CarmichaelLambda[n]

gives the Carmichael function .

Details

  • CarmichaelLambda is also known as the reduced totient function or the least universal exponent function.
  • CarmichaelLambda is typically used in primality testing to find a composite number that cannot be proved composite by some primality tests.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • CarmichaelLambda[n] is the smallest positive integer such that for all relatively prime to .
  • For a number with a unit and primes, CarmichaelLambda[n] returns LCM[(p1-1),…,(pm-1)].

Examples

open all close all

Basic Examples  (2)

Compute CarmichaelLambda of :

Wolfram Language code: CarmichaelLambda[10]

Plot the sequence:

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 50}]

Scope  (7)

Numerical Evaluation  (4)

Compute using integers:

Wolfram Language code: CarmichaelLambda[10]
Wolfram Language code: CarmichaelLambda[-10]

Compute for large integers:

Wolfram Language code: CarmichaelLambda[10 ^ 90 + 1]

CarmichaelLambda threads over lists:

Wolfram Language code: CarmichaelLambda[{2, 4, 7}]

TraditionalForm formatting:

Wolfram Language code: CarmichaelLambda[n]//TraditionalForm

Symbolic Manipulation  (3)

Find an integer solution instance:

Wolfram Language code: FindInstance[CarmichaelLambda[n] == EulerPhi[n] && n > 0, n, Integers]

Simplify an expression:

Wolfram Language code: FullSimplify[Mod[a ^ CarmichaelLambda[n], n], Element[a | n, Integers] && GCD[a, n] == 1 && n > 1]

Identify the CarmichaelLambda sequence:

Wolfram Language code: FindSequenceFunction[{1, 1, 2, 2, 4, 2, 6, 2, 6, 4}, n]

Applications  (7)

Basic Applications  (3)

The first 20 values of CarmichaelLambda:

Wolfram Language code: Grid[{Prepend[Range[20], "n"], Prepend[Table[CarmichaelLambda[n], {n, 20}], "TraditionalFormλ(n)"]}, Background -> {None, {Orange, StandardGray}}, Dividers -> Lighter[Gray, .5], Spacings -> {Automatic, .8}]

Discrete plot:

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 100}]

Number line plot:

Wolfram Language code: NumberLinePlot[Table[CarmichaelLambda[n], {n, 100}]]

Plot the generating function:

Wolfram Language code: CarmichaelGF[z_] := Sum[CarmichaelLambda[n] * z ^ n, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelGF[x], {x, 0, 1}], ContourPlot[Re[CarmichaelGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

Exponential generating function:

Wolfram Language code: CarmichaelEGF[z_] := Sum[CarmichaelLambda[n] * z ^ n / n!, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelEGF[x], {x, 0, 5}], ContourPlot[Re[CarmichaelEGF[x + I * y]], {x, -3, 3}, {y, -3, 3}, ContourStyle -> None]}]

Dirichlet series:

Wolfram Language code: CarmichaelDirichlet[s_] := Sum[CarmichaelLambda[n] / n ^ s, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelDirichlet[x], {x, 0, 1}], ContourPlot[Re[CarmichaelDirichlet[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

Primality Testing  (2)

Given a prime, for all positive numbers a less than p:

Wolfram Language code: Table[Mod[a ^ (11 - 1), 11] == 1, {a, 1, 10}]

A natural test for primality:

Wolfram Language code: primeQ[n_, a_ : 2] := Mod[a ^ (n - 1), n] == 1
Wolfram Language code: {primeQ[3], primeQ[9], primeQ[23]}
Wolfram Language code: {primeQ[341, 2], primeQ[341, 3]}

This test can be inconclusive for composite integers n satisfying :

Wolfram Language code: Mod[561, CarmichaelLambda[561]]
Wolfram Language code: primeQ[561, 2]

Verify for all a coprime to 561:

Wolfram Language code: AllTrue[Select[Range[561], CoprimeQ[#, 561]&], primeQ[561, #]&]

Recognize Carmichael numbers, composite numbers with an≡1 mod n for all a coprime to n:

Wolfram Language code: CarmichaelNumberQ[n_] := CompositeQ[n] && Mod[n, CarmichaelLambda[n]] == 1

The number is a Carmichael number, is not:

Wolfram Language code: CarmichaelNumberQ[561]
Wolfram Language code: CarmichaelNumberQ[1310]

Cryptography  (1)

Build RSA-like encryption scheme. Start with the modulus:

Wolfram Language code: {p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]]; n = p q

Find the universal exponent of the multiplication group modulo n:

Wolfram Language code: λ = CarmichaelLambda[n]

Private key:

Wolfram Language code: d = NestWhile[#1 + 1&, Round[n / 3], GCD[λ, #1] =!= 1&]

Public key:

Wolfram Language code: e = ModularInverse[d, λ]

Encrypt a message:

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

Decrypt it:

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

Number Theory  (1)

Find the number of elements in the largest subgroup of Z_n^*:

Wolfram Language code: FindCycles[n_] := Cases[GroupElements[CyclicGroup[EulerPhi[n]]], Cycles[{x_}] -> x]
Wolfram Language code: EulerPhi[12]
Wolfram Language code: subgroups = FindCycles[14]
Wolfram Language code: Dimensions[subgroups][[2]]
Wolfram Language code: CarmichaelLambda[12]

Properties & Relations  (7)

The result is non-negative:

Wolfram Language code: CarmichaelLambda[{-2, -1, 0, 1, 2}]

Divisibility is preserved:

Wolfram Language code: {Divisible[24, 8], Divisible[CarmichaelLambda[24], CarmichaelLambda[8]]}

The LCM of CarmichaelLambda is equal to CarmichaelLambda of the LCM:

Wolfram Language code: {LCM@@CarmichaelLambda[{3, 8}], CarmichaelLambda[LCM[3, 8]]}

If is square-free then a≡aλ(n)+1mod n:

Wolfram Language code: SquareFreeQ[17]
Wolfram Language code: Mod[3 ^ (CarmichaelLambda[17] + 1), 17]

The multiplicative order of an element modulo divides CarmichaelLambda[n]:

Wolfram Language code: Divisible[CarmichaelLambda[9], MultiplicativeOrder[4, 9]]

CarmichaelLambda divides EulerPhi:

Wolfram Language code: Divisible[EulerPhi[8], CarmichaelLambda[8]]

If has a primitive root, then CarmichaelLambda and EulerPhi are the same:

Wolfram Language code: Cases[Range[2, 20], n_ /; IntegerQ[PrimitiveRoot[n]]]
Wolfram Language code: CarmichaelLambda[%]
Wolfram Language code: EulerPhi[%%]

Neat Examples  (2)

A plot of varying CarmichaelLambda values:

Wolfram Language code: ArrayPlot[Table[CarmichaelLambda[j + 5k], {j, 1, 100}, {k, 1, 100}], ColorFunction -> "AvocadoColors"]

Ulam spiral where numbers are colored based on the values of CarmichaelLambda:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]
Wolfram Language code: ArrayPlot[CarmichaelLambda[ulam[101]], ColorFunction -> "Rainbow"]
Wolfram Research (1999), CarmichaelLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/CarmichaelLambda.html (updated 2018).

Text

Wolfram Research (1999), CarmichaelLambda, Wolfram Language function, https://reference.wolfram.com/language/ref/CarmichaelLambda.html (updated 2018).

CMS

Wolfram Language. 1999. "CarmichaelLambda." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/CarmichaelLambda.html.

APA

Wolfram Language. (1999). CarmichaelLambda. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarmichaelLambda.html

BibTeX

@misc{reference.wolfram_2026_carmichaellambda, author="Wolfram Research", title="{CarmichaelLambda}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/CarmichaelLambda.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_carmichaellambda, organization={Wolfram Research}, title={CarmichaelLambda}, year={2018}, url={https://reference.wolfram.com/language/ref/CarmichaelLambda.html}, note=[Accessed: 12-June-2026]}