WOLFRAM

Wolfram Language & System Documentation Center

LCM[n1,n2,…]

gives the least common multiple of the ni.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Symbolic Manipulation  
Applications  
Basic Applications  
Number Theory  
Properties & Relations  
Possible Issues  
Interactive Examples  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

LCM

LCM[n1,n2,…]

gives the least common multiple of the ni.

Details

  • LCM is also known as smallest common multiple.
  • Integer mathematical function, suitable for both symbolic and numerical manipulation.
  • LCM[n1,n2,…] is the smallest positive integer that is a multiple of each of the integers n1,n2,….
  • For rational numbers ri, LCM[r1,r2,…] gives the least rational number r for which all the r/ri are integers.
  • LCM works over Gaussian integers.

Examples

open all close all

Basic Examples  (2)

Find the least common multiple of a set of numbers:

Wolfram Language code: LCM[2, 3, 5]

Plot the least common multiple for a number with :

Wolfram Language code: DiscretePlot[LCM[12, n], {n, 100}]

Scope  (11)

Numerical Evaluation  (7)

LCM works over integers:

Wolfram Language code: LCM[3, -5, 7]

Gaussian integers:

Wolfram Language code: LCM[-4 + 5I, 2 + 3I]

Real rational numbers:

Wolfram Language code: LCM[1 / 3, 2 / 5, 3 / 7]

Complex rational numbers:

Wolfram Language code: LCM[1 / 2 + 3 / 5I, 1 / 3 + I]

The one-argument form is identity for positive integers:

Wolfram Language code: LCM[5]

Compute for large integers:

Wolfram Language code: LCM[20!, 10 ^ 100 + 3]

LCM threads elementwise over lists:

Wolfram Language code: LCM[12, {3, 7, 40}]

Symbolic Manipulation  (4)

TraditionalForm formatting:

Wolfram Language code: TraditionalForm[LCM[n, m]]

Reduce inequalities:

Wolfram Language code: Reduce[LCM[a, 3] < 3a && -10 < a < 10, a, Integers]

Solve equations:

Wolfram Language code: Solve[LCM[m, n] == n ^ 2 + n && 1 < n < 10 && 1 < m < 10, {m, n}, Integers]

Simplify expressions:

Wolfram Language code: FullSimplify[LCM[p, q], {p, q}∈Primes && p ≠ q]
Wolfram Language code: FullSimplify[LCM[m, n]GCD[m, n], {m, n}∈Integers]

Applications  (9)

Basic Applications  (4)

Table of the LCMs of the first 100 pairs of integers:

Wolfram Language code: Grid[Table[If[i * j == 0, If[i + j == 0, "", Style[i + j, Red, Italic, Bold]], LCM[i, j]], {i, 0, 10}, {j, 0, 10}], ...]

Visualize the LCMs of two integers:

Wolfram Language code: ArrayPlot[Table[LCM[m, n], {m, 50}, {n, 50}]]

Fibonacci numbers:

Wolfram Language code: ArrayPlot[Mod[Table[LCM[Fibonacci[j], Fibonacci[k]], {j, 100}, {k, 100}], Fibonacci[11]]]

The LCM of the first 100 integers:

Wolfram Language code: Apply[LCM, Range[100]]

Compute LCM for positive integers:

Wolfram Language code: lcm[a0_, b0_] := Module[{a = a0, b = b0}, While[b ≠ 0, {a, b} = {b, Mod[a, b]};];a0 * b0 / a];
Wolfram Language code: lcm[10, 15]

Compare with:

Wolfram Language code: LCM[10, 15]

Number Theory  (5)

Cumulative LCMs:

Wolfram Language code: FoldList[LCM, 1, Range[2, 10]]

Plot the logarithm of the data (if Riemann's hypothesis holds, this grows linearly):

Wolfram Language code: ListPlot[Log[FoldList[LCM, 1, Range[2, 100]]]]

The sum of MangoldtLambda of the first n integers is equal to the natural log of the LCM of the first n integers:

Wolfram Language code: Sum[MangoldtLambda[n], {n, 10}]//Simplify
Wolfram Language code: Log[Apply[LCM, Range[10]]]

Maximal order of group elements from the symmetric group of order n (Landau's function):

Wolfram Language code: Table[Max[LCM@@@IntegerPartitions[n]], {n, 20}]

LCMs of binomial coefficients:

Wolfram Language code: Table[LCM@@Binomial[n, Range[0, n]], {n, 0, 12}]

Compare with:

Wolfram Language code: Table[1 / n LCM@@Range[1, n], {n, 13}]

Simplify expressions containing LCM:

Wolfram Language code: FullSimplify[LCM[p, q], {p, q}∈Primes && p ≠ q]
Wolfram Language code: FullSimplify[LCM[m, n]GCD[m, n], {m, n}∈Integers]
Wolfram Language code: FullSimplify[LCM[LCM[l, m], n], {l, m, n}∈Integers]

Properties & Relations  (7)

Every divisor of a and b is a divisor of :

Wolfram Language code: AllTrue[Union[Divisors[24], Divisors[70]], Divisible[840, #]&]

Use GCD to compute LCM:

Wolfram Language code: 27 81 / GCD[27, 81]

Compare with:

Wolfram Language code: LCM[27, 81]

The LCM of coprime numbers is equal to their product:

Wolfram Language code: CoprimeQ[6, 11, 25]
Wolfram Language code: LCM[6, 11, 25] == 6 11 25

LCM for prime numbers is their product:

Wolfram Language code: PrimeQ[{5, 7, 2}]
Wolfram Language code: LCM[5, 7, 2] == 5 7 2

LCM for prime power representation :

Wolfram Language code: nvec = {1, 2, 3, 4, 5}; mvec = {5, 4, 3, 2, 1};
Wolfram Language code: LCM[Subsuperscript[∏, i = 1, 5]Prime[i]^nvec[[i]], Subsuperscript[∏, i = 1, 5]Prime[i]^mvec[[i]]] == Subsuperscript[∏, i = 1, 5]Prime[i]^Max[nvec[[i]], mvec[[i]]]

LCM is commutative :

Wolfram Language code: FullSimplify[LCM[a, b] == LCM[b, a], {a, b}∈Integers]

LCM is associative :

Wolfram Language code: FullSimplify[LCM[a, LCM[b, c]] == LCM[LCM[a, b], c], {a, b, c}∈Integers]

LCM is distributive :

Wolfram Language code: FullSimplify[m LCM[a, b] == LCM[m a, m b], {a, b, m}∈Integers && m > 0]

Use LCM to compute MangoldtLambda:

Wolfram Language code: Log[LCM@@Range[5] / LCM@@Range[4]]

Compare with:

Wolfram Language code: MangoldtLambda[5]

Possible Issues  (3)

Signs are discarded:

Wolfram Language code: LCM[-3, 7]

The arguments must be explicit integers:

Wolfram Language code: LCM[2.4, 5]

LCM sorts its arguments:

Wolfram Language code: LCM[b, a]

Interactive Examples  (1)

Visualize the LCMs of three numbers:

Wolfram Language code: Manipulate[ArrayPlot[Table[LCM[m, n, a], {m, 50, 100}, {n, 50, 100}], ColorFunction -> "Rainbow"], {a, 50, 100, 1}]

Neat Examples  (4)

Visualize the LCMs of Fibonacci numbers:

Wolfram Language code: ImageCollage[Table[ArrayPlot[Mod[Table[LCM[Fibonacci[j], Fibonacci[k]], {j, 100}, {k, 100}], Fibonacci[n]]], {n, 5, 30, 5}]]

Plot the arguments of the Fourier transform of the LCM:

Wolfram Language code: ArrayPlot[Arg[Fourier[Table[LCM[m, n], {m, 100}, {n, 100}]]], ColorFunction -> Hue]

Plot the Ulam spiral of the LCM:

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]
Wolfram Language code: ArrayPlot[LCM[ulam[125], 45], ColorFunction -> "BlueGreenYellow"]

Form the LCMs of with rational numbers:

Wolfram Language code: ListPlot[{#, LCM[1, #]}& /@ Union[Flatten[Table[i / j, {j, 40}, {i, 2j}]]]]
Wolfram Research (1988), LCM, Wolfram Language function, https://reference.wolfram.com/language/ref/LCM.html (updated 1999).

Text

Wolfram Research (1988), LCM, Wolfram Language function, https://reference.wolfram.com/language/ref/LCM.html (updated 1999).

CMS

Wolfram Language. 1988. "LCM." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1999. https://reference.wolfram.com/language/ref/LCM.html.

APA

Wolfram Language. (1988). LCM. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LCM.html

BibTeX

@misc{reference.wolfram_2026_lcm, author="Wolfram Research", title="{LCM}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/LCM.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_lcm, organization={Wolfram Research}, title={LCM}, year={1999}, url={https://reference.wolfram.com/language/ref/LCM.html}, note=[Accessed: 12-June-2026]}