WOLFRAM

Wolfram Language & System Documentation Center

ClebschGordan[{j1,m1},{j2,m2},{j,m}]

gives the Clebsch–Gordan coefficient for the decomposition of in terms of .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

ClebschGordan

ClebschGordan[{j1,m1},{j2,m2},{j,m}]

gives the Clebsch–Gordan coefficient for the decomposition of in terms of .

Details

  • The Clebsch–Gordan coefficients vanish except when and the satisfy a triangle inequality.
  • The parameters of ClebschGordan can be integers, half‐integers, or symbolic expressions.
  • The Wolfram Language uses the standard conventions of Edmonds for the phase of the Clebsch–Gordan coefficients.
  • The Clebsch–Gordan coefficients and 3‐ symbols in the Wolfram Language satisfy the relation .

Examples

open all close all

Basic Examples  (2)

Evaluate a Clebsch–Gordan coefficient with integer arguments:

Wolfram Language code: ClebschGordan[{5, 0}, {4, 0}, {1, 0}]

Use symbolic arguments to obtain exact symbolic answers:

Wolfram Language code: ClebschGordan[{5, 0}, {4, m}, {1, 0}]

Scope  (2)

ClebschGordan works with integer and half‐integer arguments:

Wolfram Language code: ClebschGordan[{1 / 2, -1 / 2}, {1 / 2, -1 / 2}, {1, -1}]
Wolfram Language code: ClebschGordan[{1 / 2, -1 / 2}, {1, 0}, {1 / 2, -1 / 2}]

For symbolic input ClebschGordan evaluates to ThreeJSymbol:

Wolfram Language code: ClebschGordan[{j, m}, {j1, m1}, {j2, m2}]

Applications  (3)

Plot Clebsch–Gordan coefficients as a function of and :

Wolfram Language code: ListPlot3D[Table[ClebschGordan[{10, m1}, {20, m2}, {30, m1 + m2}], {m1, -10, 10}, {m2, -20, 20}]]

Decompose a spherical harmonic into a sum of products of two spherical harmonics:

Wolfram Language code: With[{j = 5, m = 3, j1 = 2, j2 = 3}, Sqrt[(4 π (2 j + 1)/(2 j1 + 1) (2 j2 + 1))] Underoverscript[∑, m1 = -j1, j1]Underoverscript[∑, m2 = -j2, j2]KroneckerDelta[m1 + m2 - m] ClebschGordan[{j1, m1}, {j2, m2}, {j, m1 + m2}] SphericalHarmonicY[j1, m1, θ, ϕ] SphericalHarmonicY[j2, m2, θ, ϕ] == ClebschGordan[{j1, 0}, {j2, 0}, {j, 0}] SphericalHarmonicY[j, m, θ, ϕ]]
Wolfram Language code: Simplify[%]

Apply angular momentum operators to spherical harmonics:

Wolfram Language code: ℒ[-1][θ_, ϕ_] := -1 / Sqrt[2]Exp[-I ϕ]( Subscript[∂, θ]#1 - I Cot[θ]Subscript[∂, ϕ]#1)& ℒ[0][θ_, ϕ_] := -I Subscript[∂, ϕ]#1& ℒ[+1][θ_, ϕ_] := -1 / Sqrt[2]Exp[I ϕ]( Subscript[∂, θ]#1 + I Cot[θ]Subscript[∂, ϕ]#1)&
Wolfram Language code: With[{j = 5, m = 3}, Table[ ℒ[μ][θ, ϕ] @ SphericalHarmonicY[j, m, θ, ϕ] == Sqrt[j(j + 1)]ClebschGordan[{j, m}, {1, μ}, {j, m + μ}]SphericalHarmonicY[j, m + μ, θ, ϕ], {μ, -1, 1}]] // Simplify

Properties & Relations  (2)

Evaluate the completely symbolic case of ClebschGordan:

Wolfram Language code: ClebschGordan[{j1, m1}, {j2, m2}, {j1 + j2, m1 + m2}]

Demonstrate ‐sum orthogonality:

Wolfram Language code: With[{j1 = 3, j2 = 2}, Table[Sum[If[Abs[m1 + m2] > j || Abs[m1 + m2] > ji, 0, ClebschGordan[{j1, m1}, {j2, m2}, {j, m1 + m2}]ClebschGordan[{j1, m1}, {j2, m2}, {ji, m1 + m2}]], {m1, -j1, j1}, {m2, -j2, j2}], {j, Abs[j1 - j2], j1 + j2}, {ji, Abs[j1 - j2], j1 + j2}]]//MatrixForm

Possible Issues  (1)

A message is issued and the result of 0 is returned when :

Wolfram Language code: ClebschGordan[{2, 1}, {2, 4}, {4, 2}]

Neat Examples  (1)

Visualize contours constructed from Clebsch–Gordan coefficients:

Wolfram Language code: With[{λ = 3}, ListContourPlot3D[N@Table[If[Abs[m1] ≥ λ || Abs[m2] ≥ λ || Abs[m1 + m2] ≥ j, 0, ClebschGordan[{λ, m1}, {λ, m2}, {j, m1 + m2}]], {j, 0, 2λ}, {m1, -λ, λ}, {m2, -λ, λ}]]]
Wolfram Research (1991), ClebschGordan, Wolfram Language function, https://reference.wolfram.com/language/ref/ClebschGordan.html.

Text

Wolfram Research (1991), ClebschGordan, Wolfram Language function, https://reference.wolfram.com/language/ref/ClebschGordan.html.

CMS

Wolfram Language. 1991. "ClebschGordan." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ClebschGordan.html.

APA

Wolfram Language. (1991). ClebschGordan. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ClebschGordan.html

BibTeX

@misc{reference.wolfram_2026_clebschgordan, author="Wolfram Research", title="{ClebschGordan}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/ClebschGordan.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_clebschgordan, organization={Wolfram Research}, title={ClebschGordan}, year={1991}, url={https://reference.wolfram.com/language/ref/ClebschGordan.html}, note=[Accessed: 12-June-2026]}