Details

The 6‐ symbols vanish except when certain triples of the satisfy triangle inequalities.
The parameters of SixJSymbol can be integers, half‐integers, or symbolic expressions.

Examples

open all close all

Basic Examples (2)

Evaluate a 6‐ symbol with integer arguments:

Wolfram Language code: SixJSymbol[{1, 2, 3}, {2, 1, 2}]

Use symbolic arguments to obtain exact symbolic answers:

Wolfram Language code: SixJSymbol[{1, 2, 3}, {2, m, 2}]

Scope (2)

SixJSymbol works with integer and half‐integer arguments:

Wolfram Language code: SixJSymbol[{1 / 2, 1 / 2, 1}, {5 / 2, 7 / 2, 3}]

TraditionalForm formatting:

Wolfram Language code: SixJSymbol[{j1, j2, j3}, {m1, m2, m3}]//TraditionalForm

Applications (2)

Plot the 6‐ symbol as a function of and :

Wolfram Language code: ListPlot3D[Table[SixJSymbol[{j1, j2, j1 + j2}, {6, j1 + j2 + 6, j2 + 6}], {j1, 0, 10}, {j2, 0, 20}]]

Confirm the Wigner formula for the asymptotic value of SixJSymbol:

Wolfram Language code:

{j1, j2, j3, j4, j5, j6} = {105, 107, 106, 106, 102, 109};
{j12, j13, j14, j23, j24, j34} = {j1, j2, j3, j6, j5, j4} + 1 / 2;
Vs = Det[{{0, j34^2, j24^2, j23^2, 1}, {j34^2, 0, j14^2, j13^2, 1}, {j24^2, j14^2, 0, j12^2, 1}, {j23^2, j13^2, j12^2, 0, 1}, {1, 1, 1, 1, 0}}] / 288;
{SixJSymbol[{j1, j2, j3}, {j4, j5, j6}] ^ 2, 1 / (24 Pi Sqrt[Vs])} // N

Properties & Relations (2)

Generate a 6-j symbol from a generating function:

Wolfram Language code:

{j1, j2, j3, j4, j5, j6} = {1, 2, 3, 1, 2, 2}; 
1 / ((Sqrt[(1 + j1 + j2 + j3)!] Sqrt[(1 + j3 + j4 + j5)!] Sqrt[(1 + j2 + j4 + j6)!] Sqrt[(1 + j1 + j5 + j6)!]) / (Sqrt[(j1 + j2 - j3)!] Sqrt[(j1 - j2 + j3)!] Sqrt[(-j1 + j2 + j3)!] Sqrt[(j3 + j4 - j5)!] Sqrt[(j3 - j4 + j5)!] Sqrt[(-j3 + j4 + j5)!] Sqrt[(j2 + j4 - j6)!] Sqrt[(j1 + j5 - j6)!] Sqrt[(j2 - j4 + j6)!] Sqrt[(-j2 + j4 + j6)!] Sqrt[(j1 - j5 + j6)!] Sqrt[(-j1 + j5 + j6)!]) / SeriesCoefficient[Series[1 / (1 + u v z + u w y + v w x + x y z + u v x y + u w x z + v w y z) ^ 2, {u, 0, 2 j1}, {v, 0, 2 j2}, {w, 0, 2 j3}, {x, 0, 2 j4}, {y, 0, 2 j5}, {z, 0, 2 j6}], {2 j1, 2 j2, 2 j3, 2 j4, 2 j5, 2 j6}])

Wolfram Language code: SixJSymbol[{j1, j2, j3}, {j4, j5, j6}]

Express 6‐ symbols in terms of Clebsch–Gordan coefficients:

Wolfram Language code:

With[{j1 = 1, j2 = 2, j12 = 1, j3 = 2, j = 3, j23 = 2, m = 0}, 
	(-1) ^ (j1 + j2 + j3 + j) / Sqrt[(2j12 + 1)(2j23 + 1)]Sum[ClebschGordan[{j12, m12}, {j3, m3}, {j, m}]ClebschGordan[{j1, m1}, {j2, m2}, {j12, m12}]ClebschGordan[{j1, m1}, {j23, m23}, {j, m}]ClebschGordan[{j2, m2}, {j3, m3}, {j23, m23}], {m1, -j1, j1}, {m2, -j2, j2}, {m3, -j3, j3}, {m12, -j12, j12}, {m23, -j23, j23}]]//Quiet

Wolfram Language code: With[{j1 = 1, j2 = 2, j12 = 1, j3 = 2, j = 3, j23 = 2, m = 0}, SixJSymbol[{j1, j2, j12}, {j3, j, j23}]]