WOLFRAM

Wolfram Language & System Documentation Center

ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}]

gives the values of the Wigner 3‐ symbol.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

ThreeJSymbol

ThreeJSymbol[{j1,m1},{j2,m2},{j3,m3}]

gives the values of the Wigner 3‐ symbol.

Details

  • The 3‐ symbols vanish except when and the satisfy a triangle inequality.
  • The parameters of ThreeJSymbol can be integers, half‐integers or symbolic expressions.
  • The 3‐ symbols and Clebsch–Gordan coefficients in the Wolfram Language satisfy the relation .

Examples

open all close all

Basic Examples  (2)

Evaluate a 3‐ symbol with integer arguments:

Wolfram Language code: ThreeJSymbol[{6, 0}, {4, 0}, {2, 0}]

Use symbolic arguments to obtain exact symbolic answers:

Wolfram Language code: ThreeJSymbol[{6, 0}, {4, 0}, {2, m}]

Scope  (2)

ThreeJSymbol works with integer and half‐integer arguments:

Wolfram Language code: ThreeJSymbol[{1 / 2, -1 / 2}, {1 / 2, -1 / 2}, {1, 1}]

TraditionalForm formatting:

Wolfram Language code: ThreeJSymbol[{j, m}, {Subscript[j, 1], Subscript[m, 1]}, {Subscript[j, 2], Subscript[m, 2]}]//TraditionalForm

Applications  (3)

Plot 3‐ symbol coefficients as a function of and :

Wolfram Language code: ListPlot3D[Table[ThreeJSymbol[{10, m1}, {20, m2}, {30, -m1 - m2}], {m1, -10, 10}, {m2, -20, 20}], Mesh -> None]

Apply angular momentum operators to spherical harmonics:

Wolfram Language code: ℒ[-1][θ_, ϕ_] := -1 / Sqrt[2]Exp[-I ϕ]( D[#, θ] - I Cot[θ]D[#, ϕ])& ℒ[0][θ_, ϕ_] := -I D[#, ϕ]& ℒ[+1][θ_, ϕ_] := -1 / Sqrt[2]Exp[+I ϕ]( D[#, θ] + I Cot[θ]D[#, ϕ])&
Wolfram Language code: {j, m} = {5, 3}; Table[ ℒ[μ][θ, ϕ] @ SphericalHarmonicY[j, m, θ, ϕ] - (-1) ^ (j - 1 + m + μ)Sqrt[j(j + 1)(2j + 1)]ThreeJSymbol[{j, m}, {1, μ}, {j, -(m + μ)}]SphericalHarmonicY[j, m + μ, θ, ϕ], {μ, -1, 1}]//Simplify

Evaluate Gaunt coefficients:

Wolfram Language code: With[{l1 = 4, m1 = 0, l2 = 3, m2 = 2, l3 = 3, m3 = 2}, Sqrt[((2 l1 + 1) (2 l2 + 1) (2 l3 + 1)/4 π)] ThreeJSymbol[{l1, 0}, {l2, 0}, {l3, 0}] ThreeJSymbol[{l1, m1}, {l2, m2}, {l3, -m3}]]

Evaluate as an explicit triple integral of spherical harmonics:

Wolfram Language code: With[{l1 = 4, m1 = 0, l2 = 3, m2 = 2, l3 = 3, m3 = 2}, Integrate[SphericalHarmonicY[l1, m1, θ, ϕ]SphericalHarmonicY[l2, m2, θ, ϕ]Conjugate[SphericalHarmonicY[l3, m3, θ, ϕ]]Sin[θ], {θ, 0, Pi}, {ϕ, 0, 2Pi}]]

Properties & Relations  (4)

Evaluate the completely symbolic case of ThreeJSymbol:

Wolfram Language code: ThreeJSymbol[{j1, m1}, {j2, m2}, {j1 + j2, -m1 - m2}]

Demonstrate ‐sum orthogonality:

Wolfram Language code: {j1, j2} = {3, 2}; Table[Sum[If[Abs[m1 + m2] > j || Abs[m1 + m2] > ji, 0, Sqrt[(2j + 1)(2ji + 1)]ThreeJSymbol[{j1, m1}, {j2, m2}, {j, -(m1 + m2)}]ThreeJSymbol[{j1, m1}, {j2, m2}, {ji, -(m1 + m2)}]], {m1, -j1, j1}, {m2, -j2, j2}], {j, Abs[j1 - j2], j1 + j2}, {ji, Abs[j1 - j2], j1 + j2}]

Convert a 3‐ symbol to a Regge R symbol:

Wolfram Language code: ToReggeR[ThreeJSymbol[{j1_, m1_}, {j2_, m2_}, {j3_, m3_}]] := ReggeR[{{-j1 + j2 + j3, j1 - j2 + j3, j1 + j2 - j3}, {j1 + m1, j2 + m2, j3 + m3}, {j1 - m1, j2 - m2, j3 - m3}}]
Wolfram Language code: ToReggeR[ThreeJSymbol[{j1, m1}, {j2, m2}, {j3, -m1 - m2}]]

Check the symmetry of the Regge R symbol:

Wolfram Language code: {Total[%[[1]], {2}], Total[Transpose[%[[1]]], {2}]}

Compare with the sum definition:

Wolfram Language code: ThreeJSymbol[{2, 1}, {2, 2}, {4, -3}]
Wolfram Language code: With[{j1 = 2, m1 = 1, j2 = 2, m2 = 2, j3 = 4, m3 = -1 - 2}, (1/Sqrt[(1 + j1 + j2 + j3)!])(-1)^-j1 + j2 + m3 Sqrt[(j1 + j2 - j3)!] Sqrt[(j1 - j2 + j3)!] Sqrt[(-j1 + j2 + j3)!] Sqrt[(j1 - m1)!] Sqrt[(j1 + m1)!] Sqrt[(j2 - m2)!] Sqrt[(j2 + m2)!] Sqrt[(j3 - m3)!] Sqrt[(j3 + m3)!] KroneckerDelta[m1 + m2, -m3] Underoverscript[∑, k = Max[0, j2 - j3 - m1, j1 - j3 + m2], Min[j1 - m1, j2 + m2]](-1)^k / ((j1 + j2 - j3 - k)! k! (j1 - k - m1)! (-j2 + j3 + k + m1)! (-j1 + j3 + k - m2)! (j2 - k + m2)!)]

Possible Issues  (1)

A message is issued and the result 0 returned in the case :

Wolfram Language code: ThreeJSymbol[{2, 1}, {2, 4}, {4, 2}]
Wolfram Research (1991), ThreeJSymbol, Wolfram Language function, https://reference.wolfram.com/language/ref/ThreeJSymbol.html.

Text

Wolfram Research (1991), ThreeJSymbol, Wolfram Language function, https://reference.wolfram.com/language/ref/ThreeJSymbol.html.

CMS

Wolfram Language. 1991. "ThreeJSymbol." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ThreeJSymbol.html.

APA

Wolfram Language. (1991). ThreeJSymbol. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ThreeJSymbol.html

BibTeX

@misc{reference.wolfram_2026_threejsymbol, author="Wolfram Research", title="{ThreeJSymbol}", year="1991", howpublished="\url{https://reference.wolfram.com/language/ref/ThreeJSymbol.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_threejsymbol, organization={Wolfram Research}, title={ThreeJSymbol}, year={1991}, url={https://reference.wolfram.com/language/ref/ThreeJSymbol.html}, note=[Accessed: 13-June-2026]}