ContinuousWaveletTransform gives a ContinuousWaveletData object.
Properties of the ContinuousWaveletData cwd can be found using cwd["prop"]. A list of available properties can found using cwd["Properties"].
The resulting wavelet coefficients are arrays of the same dimensions as the input data.
The possible wavelets wave include:

	MorletWavelet[…]	Morlet cosine times Gaussian
	GaborWavelet[…]	complex Morlet wavelet
	DGaussianWavelet[…]	derivative of Gaussian
	MexicanHatWavelet[…]	second derivative of Gaussian
	PaulWavelet[…]	Paul wavelet

The default wave is MexicanHatWavelet[].
The default value for noct is given by $TemplateBox[{{InterpretationBox[{log, _, DocumentationBuild`Utils`Private`Parenth[2]}, Log2, AutoDelete -> True], (, {n, /, 2}, )}}, Floor]$ , where is the length of the input. »
The default value for nvoc is 4.
The continuous wavelet transform of a function is given by $w(u,s)=1/(sqrt(s))int_(-infty)^inftyx(t) TemplateBox[{psi}, Conjugate]((t-u)/s)dt$ .
The continuous wavelet transform of a uniformly sampled sequence is given by $w(u,s)=1/(sqrt(s))sum_(k=1)^nx_k TemplateBox[{psi}, Conjugate]((Delta (k-u))/s)$ .
The scaling parameter is given by equal-tempered scale where is the octave number, the voice number, and the smallest wavelet scale.
For each scale , the ContinuousWaveletTransform computes the wavelet coefficients .
The following options can be given:

Padding	None	how to extend data beyond boundaries
SampleRate	Automatic	samples per unit
WaveletScale	Automatic	smallest resolvable scale
WorkingPrecision	MachinePrecision	precision to use in internal computations

Padding pads the input data to the next higher power of 2 to reduce boundary effects. The settings for Padding are the same as for the padding argument used in ArrayPad.
InverseContinuousWaveletTransform gives the inverse transform.

Examples

open all close all

Basic Examples (2)

Compute a continuous wavelet transform using MexicanHatWavelet:

Wolfram Language code: cwd = ContinuousWaveletTransform[{56, 40, 8, 24, 48, 48, 40, 16}]

Plot the coefficients:

Wolfram Language code: ListLinePlot[cwd[All, "Values"]]

Perform an inverse continuous wavelet transform:

Wolfram Language code: InverseContinuousWaveletTransform[cwd]

Transform a sampled Sound object:

Wolfram Language code: Play[Underoverscript[∑, n, 5]Sin[2000 2^t n t], {t, 2, 3}]

Wolfram Language code: cwd = ContinuousWaveletTransform[%]

Plot a scalogram:

Wolfram Language code: WaveletScalogram[cwd]

Scope (18)

Basic Uses (6)

Compute a continuous wavelet transform:

Wolfram Language code: data = Table[HeavisideLambda[x], {x, -2, 2, (4/1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data]

Show all the voices for the 8octave:

Wolfram Language code: ListLinePlot[Abs[cwt[{8, _}][[All, 2]]], PlotRange -> All]

Use Normal to get all wavelet coefficients explicitly:

Wolfram Language code: cwt = ContinuousWaveletTransform[{0, 0, 1, 0, 0}, MexicanHatWavelet[1]]

Wolfram Language code: Normal[cwt]

Also use All as an argument to get all coefficients:

Wolfram Language code: cwt[All]

Use "IndexMap" to find out what wavelet coefficients are available:

Wolfram Language code: cwt = ContinuousWaveletTransform[{0, 0, 1, 0, 0}, MexicanHatWavelet[1]];

Wolfram Language code: cwt["IndexMap"]

Extract specific coefficient arrays:

Wolfram Language code: cwt[{1, 1}]

Wolfram Language code: cwt[{1, 4}]

Extract several wavelet coefficients corresponding to the list of wavelet index specifications:

Wolfram Language code: cwt[{{1, 1}, {1, 3}}]

Extract all coefficients whose wavelet indexes match a pattern:

Wolfram Language code: cwt[{1, _}]

Wolfram Language code: cwt[{{_, 1}, {_, 4}}]

Wolfram Language code: cwt[{_, 1 | 4}]

WaveletScalogram gives a time scale representation of wavelet coefficients:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data];

Wolfram Language code: WaveletScalogram[cwt, AxesLabel -> {"time", "scale"}]

More voices per octave increases the scale resolution:

Wolfram Language code: data = Table[Sin[x^2], {x, 0, 10, 0.02}];

Wolfram Language code: {cwt1, cwt2} = Table[ContinuousWaveletTransform[data, DGaussianWavelet[5], {Automatic, voc}], {voc, {4, 16}}];

Wolfram Language code: {WaveletScalogram[cwt1, PlotLabel -> "4 voices/octave"], WaveletScalogram[cwt2, PlotLabel -> "16 voices/octave"]}

Higher number of octaves gives a wider spectrum of scale range:

Wolfram Language code: data = Function[x, x Sin[Exp[x] x]][Range[2, 5, 0.001]];

Wolfram Language code: {cwt1, cwt2} = Table[ContinuousWaveletTransform[data, Automatic, {oct, Automatic}], {oct, {5, 8}}];

Wolfram Language code: {WaveletScalogram[cwt1, PlotLabel -> "5 octaves"], WaveletScalogram[cwt2, PlotLabel -> "8 octaves"]}

Time and Scale Features (4)

A single frequency shows up as a horizontal band at the equivalent scale:

Wolfram Language code: data1 = Table[Cos[20 π x], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data1]

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data1, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt1, ColorFunction -> "SolarColors"]

Multiple frequencies show up as multiple bands at the equivalent scales:

Wolfram Language code: data2 = Table[Cos[20 π x] + Cos[Sqrt[2] 50 π x], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data2]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data2, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt2, ColorFunction -> "SolarColors"]

Sinusoid with linearly increasing frequency:

Wolfram Language code: data3 = Block[{fr = 0}, Table[Sin[(fr += 0.5)x], {x, 0, 1, (1/1023)}]];

Wolfram Language code: ListLinePlot[data3]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data3, GaborWavelet[6]];

Wolfram Language code: WaveletScalogram[cwt2, ColorFunction -> "SolarColors"]

Wavelet transform gives a good time localization of features:

Wolfram Language code: data = Table[Sin[4 π t] + 2 Exp[-10^5 ((1/3) - t)^2], {t, 0, 1, (1/511)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, PaulWavelet[5], {7, 12}, SampleRate -> 511];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "AvocadoColors"]

Higher frequencies are resolved at lower octaves and lower frequencies at higher octaves:

Wolfram Language code:

data = Table[Piecewise[{{Sin[2 π 10 t], 0 ≤ t < (1/4)}, {Sin[2 π 25 t], (1/4) ≤ t < (1/2)}, {Sin[2 π 50 t], (1/2) ≤ t < (3/4)}, {Sin[2 π 100 t], (3/4) ≤ t ≤ 1}}], {t, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data, AspectRatio -> 0.2]

Wolfram Language code: cwd = ContinuousWaveletTransform[data, DGaussianWavelet[5], {Automatic, 12}];

Wolfram Language code: WaveletScalogram[cwd, ColorFunction -> "RustTones"]

Resolve time and frequency features of a signal:

Wolfram Language code: data = Table[Cos[40 π x] Exp[-100 π (x - 0.7)^2] + Cos[140 π x] Exp[-50 π (x - 0.2)^2], {x, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data, PlotRange -> All]

Use GaborWavelet to perform a continuous wavelet transform:

Wolfram Language code: cwd = ContinuousWaveletTransform[data, GaborWavelet[8], SampleRate -> 1023];

There is an inverse relationship between scale values and frequency values:

Wolfram Language code: freq = (#1[[1]] -> (1023/#1[[2]])&) /@ cwd["Scales"]

Find pairs of {oct,voc} that resolve frequencies 20 Hz and 70 Hz:

Wolfram Language code: Cases[freq, u_ /; 19 ≤ Last[u] ≤ 21]

Wolfram Language code: Cases[freq, u_ /; 69 ≤ Last[u] ≤ 71]

Verify using a WaveletScalogram:

Wolfram Language code: WaveletScalogram[cwd, ColorFunction -> "BrassTones"]

Wavelet Families (6)

Compute the wavelet transform using different wavelet families:

Wolfram Language code: data = Table[Sin[x^2] + Cos[x^3], {x, 0, 3 π, 0.01}];

Wolfram Language code: ListLinePlot[data]

A narrow wavelet function will have good time and scale resolution:

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data, MexicanHatWavelet[1]];

Wolfram Language code: WaveletScalogram[cwt1]

A broad wavelet function will have poor time and scale resolution:

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data, GaborWavelet[3]]

Wolfram Language code: WaveletScalogram[cwt2]

Use different families of wavelets to capture different features:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: ListLinePlot[data]

MexicanHatWavelet (default):

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MexicanHatWavelet[]];

Wolfram Language code:

ListPlot3D[Re@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

DGaussianWavelet:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, DGaussianWavelet[]];

Wolfram Language code:

ListPlot3D[Re@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

GaborWavelet:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[3]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

MorletWavelet:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MorletWavelet[]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

PaulWavelet:

Wolfram Language code: data = Table[Sign[Cos[x^2]], {x, -6, 6, (12./1023)}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, PaulWavelet[]];

Wolfram Language code:

ListPlot3D[Abs@cwt[All, "Values"], ColorFunction -> "DarkRainbow", AxesLabel -> {"time", "scale"}, Mesh -> None, PlotRange -> All]

Sound (2)

ContinuousWaveletTransform works on Sound as input:

Wolfram Language code: sdata = Play[Sin[5000 t] + Sin[1000 t] + Cos[500 t] + Cos[200 t], {t, 0, 1}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata, DGaussianWavelet[5]];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "StarryNightColors"]

Speech analysis using ContinuousWaveletTransform:

Wolfram Language code: snd = ExampleData[{"Sound", "Apollo11ReturnSafely"}]

Wolfram Language code: cwd = ContinuousWaveletTransform[snd, GaborWavelet[6], {Automatic, 12}];

The orange patches correspond to the words "You will return safely to Earth":

Wolfram Language code: WaveletScalogram[cwd, {4 | 5 | 6 | 7, _}]

Extract octaves 5 and 6:

Wolfram Language code: cwd2 = WaveletMapIndexed[#1 0.0&, cwd, Except[{5 | 6, _}]]

Wolfram Language code: Sound[InverseContinuousWaveletTransform[cwd2], SoundVolume -> 2]

Options (9)

Padding (3)

The settings for Padding are the same as the methods for ArrayPad, including "Periodic":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Periodic"]

"Reversed":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reversed"]

"ReversedNegation":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedNegation"]

"Reflected":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "Reflected"]

"ReflectedDifferences":

Wolfram Language code: ArrayPad[{a, b, c}, 3, "ReflectedDifferences"]

"ReversedDifferences":

Wolfram Language code: ArrayPad[{a, b, c}, 4, "ReversedDifferences"]

"Extrapolated":

Wolfram Language code: ArrayPad[{a, b, c}, 3, "Extrapolated"]

Padding has no effect on the length of wavelet coefficients:

Wolfram Language code: cwd = ContinuousWaveletTransform[Range[16]];

Wolfram Language code: (Length[#1]&) /@ cwd[All][[All, 2]]

Padding pads the input data to the next higher power of 2 to reduce boundary effects:

Wolfram Language code: data = Table[Sin[20 x], {x, 0, 1, (1/1023)}];

Wolfram Language code:

cwt1 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> None, WaveletScale -> Automatic];
rdata1 = InverseContinuousWaveletTransform[cwt1];

Wolfram Language code:

cwt2 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> "Reflected", WaveletScale -> Automatic];
rdata2 = InverseContinuousWaveletTransform[cwt2];

Wolfram Language code:

cwt3 = ContinuousWaveletTransform[data, MexicanHatWavelet[4], Padding -> "Extrapolated", WaveletScale -> Automatic];
rdata3 = InverseContinuousWaveletTransform[cwt3];

Boundary effects at the start:

Wolfram Language code:

ListLinePlot[{data[[1 ;; 50]], rdata1[[1 ;; 50]], rdata2[[1 ;; 50]], rdata3[[1 ;; 50]]}, PlotStyle -> {Red, Green, Blue, Orange}, BaseStyle -> Thick]

Boundary effects at the end:

Wolfram Language code:

ListLinePlot[{data[[-50 ;; -1]], rdata1[[-50 ;; -1]], rdata2[[-50 ;; -1]], rdata3[[-50 ;; -1]]}, PlotStyle -> {Red, Green, Blue, Orange}, BaseStyle -> Thick]

SampleRate (3)

For lists, the Automatic value of SampleRate is set to 1:

Wolfram Language code: cwt1 = ContinuousWaveletTransform[Table[Sin[x^2], {x, 0, 1, 0.001}]];

Wolfram Language code: cwt1["SampleRate"]

Explicitly set the sample rate:

Wolfram Language code: cwt2 = ContinuousWaveletTransform[Table[Sin[x^2], {x, 0, 1, 0.001}], SampleRate -> 1000];

Wolfram Language code: cwt2["SampleRate"]

For Sound data, the Automatic value of SampleRate is extracted from the Sound data object:

Wolfram Language code: sdata = Sound[{Play[Sin[1000 t (1 + t^2)], {t, 0, .2}], Play[Sin[500 t (1 + t^3)], {t, 0, .5}]}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata];

Wolfram Language code: cwt["SampleRate"]

SampleRate is used for normalizing wavelet transform coefficients:

Wolfram Language code: sdata = Sound[{Play[Sin[1000 t (1 + t^2)], {t, 0, .2}], Play[Sin[500 t (1 + t^3)], {t, 0, .5}]}]

Wolfram Language code: cwt = ContinuousWaveletTransform[sdata, Automatic, {Automatic, 16}]

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "BlueGreenYellow"]

WaveletScale (1)

WaveletScale indicates the smallest resolvable scale used for the transform:

Wolfram Language code: data = Table[Sin[x^2], {x, 0, 3 π, (3 π/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[6], WaveletScale -> 1];

The scales used are given as with wavelet scale, octave, and voice:

Wolfram Language code: {ws, oct, voc} = cwt[{"WaveletScale", "Octaves", "Voices"}];

Wolfram Language code: Table[ws 2^j / voc, {j, 1, oct voc}] == cwt["Scales"][[All, 2]]

WorkingPrecision (2)

By default, WorkingPrecision->MachinePrecision is used:

Wolfram Language code: data = RandomInteger[1, {10}];

Wolfram Language code: cwt1 = ContinuousWaveletTransform[data]

Wolfram Language code: cwt2 = ContinuousWaveletTransform[data, WorkingPrecision -> MachinePrecision]

Wolfram Language code: cwt1 == cwt2

Use higher-precision computation:

Wolfram Language code: data = RandomInteger[1, {8}];

Wolfram Language code: cwt = ContinuousWaveletTransform[data, MexicanHatWavelet[], WorkingPrecision -> 35]

Wolfram Language code: cwt[{1, 1}]

Wolfram Language code: {Precision[cwt], Accuracy[cwt]}

Applications (4)

Identify Features (2)

Real wavelet functions can be used to isolate peaks or discontinuities:

Wolfram Language code: data = Table[HeavisideTheta[x], {x, -2, 2, (4/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, DGaussianWavelet[4], {Automatic, 12}, Padding -> "Fixed"]

Wolfram Language code: WaveletScalogram[cwt]

Complex wavelets can be used to capture oscillatory behavior:

Wolfram Language code: f[t_, ϵ_] := Sqrt[t (1 - t)] Sin[(2 π (1 + ϵ)/t + ϵ)]

Wolfram Language code: data = Table[f[t, 0.05], {t, 0, 1, (1/1023)}];

Wolfram Language code: ListLinePlot[data]

Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[6], {Automatic, 16}]

Amplitude of wavelet coefficients:

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "BlueGreenYellow"]

Phase of wavelet coefficients:

Wolfram Language code: WaveletScalogram[cwt, Automatic, Arg, ColorFunction -> "BlueGreenYellow"]

Filter Frequencies (2)

ContinuousWaveletTransform can be used to filter frequencies:

Wolfram Language code:

f[x_] := Sin[50 π x] Exp[-100 π (x - 0.5)^2] + (Sin[50 π x] + 2 Cos[140 π x]) Exp[-50 π (x - 0.2)^2] + 2 Sin[150 π x] Exp[-80 π (x - 0.8)^2]

Wolfram Language code: data = Table[f[x], {x, 0., 1, (1/2047)}];

Wolfram Language code: ListLinePlot[data, PlotRange -> All]

Wolfram Language code:

cwt = ContinuousWaveletTransform[data, GaborWavelet[6], {10, 16}, Padding -> 0.0, SampleRate -> 2047, WaveletScale -> Automatic];

Wolfram Language code: WaveletScalogram[cwt, ColorFunction -> "SolarColors"]

Filter the cosine with frequency :

Wolfram Language code:

vec = ConstantArray[1, Length[data]];
vec[[1 ;; 1000]] := 0.0

Wolfram Language code: cwtThresh = WaveletMapIndexed[#1 vec&, cwt, {{4 | 5, _}, {6, u_ /; u < 8}}];

Wolfram Language code: WaveletScalogram[cwtThresh, ColorFunction -> "SolarColors"]

Perform InverseContinuousWaveletTransform on a thresholded data object:

Wolfram Language code: rdata = InverseContinuousWaveletTransform[cwtThresh];

Wolfram Language code: ListLinePlot[{data[[1 ;; 800]], rdata[[1 ;; 800]]}, PlotRange -> All, PlotStyle -> {Blue, {Red, Thick}}]

The final filtered signal:

Wolfram Language code: ListLinePlot[rdata, PlotRange -> All]

Identify musical notes using a scalogram:

Wolfram Language code: Needs["Music`"]

Generate a sequence of pitches corresponding to an equal-tempered scale at 300 Hz:

Wolfram Language code: m300 = MusicScale[TemperedChromatic, 300, 1]

Wolfram Language code: cwd = ContinuousWaveletTransform[m300, GaborWavelet[6], {7, 8}, SampleRate -> 8192];

Compute frequencies resolved corresponding to octaves and voices:

Wolfram Language code: freq = (#1[[1]] -> (8192/#1[[2]])&) /@ cwd["Scales"];

Find pairs of {oct,voc} that resolve frequencies 300 Hz:

Wolfram Language code: Cases[freq, u_ /; 280 ≤ Last[u] ≤ 320]

Wolfram Language code: WaveletScalogram[cwd, {3 | 4 | 5 | 6 | 7, _}]

Properties & Relations (1)

The default value for octave is given by $TemplateBox[{{InterpretationBox[{log, _, DocumentationBuild`Utils`Private`Parenth[2]}, Log2, AutoDelete -> True], (, {n, /, 2}, )}}, Floor]$ :

Wolfram Language code: data = RandomReal[1, {100}];

Wolfram Language code: oct = Floor[Log2[(Length[data]/2)]]

Wolfram Language code: ContinuousWaveletTransform[data] == ContinuousWaveletTransform[data, Automatic, {oct, Automatic}]

Default value of voices is 4:

Wolfram Language code: ContinuousWaveletTransform[data] == ContinuousWaveletTransform[data, Automatic, {Automatic, 4}]

Possible Issues (1)

Low-frequency data is resolved at higher octaves:

Wolfram Language code: data = Cos[(Range[1000]/1000)];

Based on the length of input data, the Automatic setting for octaves resolved 8 octaves:

Wolfram Language code: cwd1 = ContinuousWaveletTransform[data, MorletWavelet[], Automatic]

Wolfram Language code: ListLinePlot[{InverseContinuousWaveletTransform[cwd1], data}]

Increase the number of octaves to resolve the low-frequency component:

Wolfram Language code: cwd2 = ContinuousWaveletTransform[data, MorletWavelet[], {12, Automatic}]

Wolfram Language code: ListLinePlot[{InverseContinuousWaveletTransform[cwd2], data}]

Neat Examples (1)

Scalogram of a Zeta function:

Wolfram Language code: d = Re[Zeta[(1/2) + I Range[0, 100, 0.01]]];

Wolfram Language code: ListLinePlot[d]

Wolfram Language code: cwd = ContinuousWaveletTransform[d, GaborWavelet[6], {4, 12}, WaveletScale -> 100];

Wolfram Language code:

{WaveletScalogram[cwd, All, Re, ColorFunction -> "CherryTones"], WaveletScalogram[cwd, All, Abs, ColorFunction -> "CherryTones"]}

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ContinuousWaveletTransform

Details and Options

Examples

Basic Examples (2)

Scope (18)

Basic Uses (6)

Time and Scale Features (4)

Wavelet Families (6)

Sound (2)

Options (9)

Padding (3)

SampleRate (3)

WaveletScale (1)

WorkingPrecision (2)

Applications (4)

Identify Features (2)

Filter Frequencies (2)

Properties & Relations (1)

Possible Issues (1)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

ContinuousWaveletTransform

Details and Options

Examples

Basic Examples (2)

Scope (18)

Basic Uses (6)

Time and Scale Features (4)

Wavelet Families (6)

Sound (2)

Options (9)

Padding (3)

SampleRate (3)

WaveletScale (1)

WorkingPrecision (2)

Applications (4)

Identify Features (2)

Filter Frequencies (2)

Properties & Relations (1)

Possible Issues (1)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX