WOLFRAM

Wolfram Language & System Documentation Center

GaborWavelet[]

represents a Gabor wavelet of frequency 6.

GaborWavelet[w]

represents a Gabor wavelet of frequency w.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

GaborWavelet

GaborWavelet[]

represents a Gabor wavelet of frequency 6.

GaborWavelet[w]

represents a Gabor wavelet of frequency w.

Details

Examples

open all close all

Basic Examples  (1)

Wavelet function:

Wolfram Language code: ψ = WaveletPsi[GaborWavelet[1], x];
Wolfram Language code: Plot[{Re[ψ], Im[ψ]}, {x, -5, 5}, PlotRange -> All]
Wolfram Language code: ψ = WaveletPsi[GaborWavelet[6], x];
Wolfram Language code: Plot[{Re[ψ], Im[ψ]}, {x, -5, 5}, PlotRange -> All]

Scope  (3)

Create a Gabor wavelet function of frequency 6:

Wolfram Language code: ψ = WaveletPsi[GaborWavelet[], x]
Wolfram Language code: Plot[{Re[ψ], Im[ψ]}, {x, -5, 5}, PlotRange -> All]

GaborWavelet is used to perform ContinuousWaveletTransform:

Wolfram Language code: f[t_, ϵ_] := ((t(1 - t))^(1/2)Sin[2π((1 + ϵ)/(t + ϵ))])
Wolfram Language code: data = Table[f[t, 0.05], {t, 0, 1, (1/1023)}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: cwt = ContinuousWaveletTransform[data, GaborWavelet[4], {Automatic, 16}, Padding -> 0.0, SampleRate -> 1023]

Use WaveletScalogram to get a time scale representation of wavelet coefficients:

Wolfram Language code: WaveletScalogram[cwt]

Use InverseWaveletTransform to reconstruct the signal:

Wolfram Language code: ListLinePlot[{data, InverseContinuousWaveletTransform[cwt]}]

Wavelet function as a function of frequency w:

Wolfram Language code: FormulaGrid[list_] := Grid[list, Alignment -> Center, Background -> {None, {{StandardBlue, StandardGray}}}, Dividers -> {None, {Darker[Gray, .6], {False}, Darker[Gray, .6]}}, ItemSize -> {{Scaled[.1], Scaled[.9]}}, ItemStyle -> {{14}, 16}]
Wolfram Language code: FormulaGrid[Table[{k, Simplify@WaveletPsi[GaborWavelet[k], x]}, {k, 1, 5}]]

Applications  (1)

Resolve a cosine wave with frequency 10 Hz:

Wolfram Language code: Data = Table[Cos[20 π x], {x, 0, 1, (1/1023)}];

Perform a continuous wavelet transform on the data:

Wolfram Language code: cwt = ContinuousWaveletTransform[Data, GaborWavelet[6], Automatic];

Frequencies resolved by the transform are the inverse of the scales:

Wolfram Language code: (First[#] -> (1023/Last[#] )&) /@ cwt["Scales"]

Plot WaveletScalogram to verify that the 10 Hz frequency is resolved by the seventh octave:

Wolfram Language code: WaveletScalogram[cwt]

Properties & Relations  (4)

GaborWavelet with a certain frequency is similar to MorletWavelet:

Wolfram Language code: ω0 = N[πSqrt[(2/Log[2])]];
Wolfram Language code: Plot[{WaveletPsi[MorletWavelet[], x], Re@WaveletPsi[GaborWavelet[ω0], x]}, {x, -5, 5}, PlotStyle -> {Blue, {Red, Dashed}}, PlotRange -> All]

Wavelet function and its Fourier transform:

Wolfram Language code: ψ = WaveletPsi[GaborWavelet[6], x]
Wolfram Language code: Plot[{Re[ψ], Im[ψ]}, {x, -5, 5}, PlotRange -> All, PlotStyle -> {Automatic, Dashed}, Frame -> True, GridLines -> Automatic]
Wolfram Language code: Overscript[ψ, ^ ] = FourierTransform[ψ, x, ω, FourierParameters -> {0, -2Pi}]
Wolfram Language code: Plot[Overscript[ψ, ^ ], {ω, -2, 2}, PlotRange -> All]

GaborWavelet does not have a scaling function:

Wolfram Language code: WaveletPhi[GaborWavelet[6], x]

The central frequency of the GaborWavelet[w] is approximately w:

Wolfram Language code: cf[w_] := (2π( w + Sqrt[2 + w ^ 2])/4Pi)
Wolfram Language code: wc = N[cf[6]]

Compute the wavelet function with frequency parameter :

Wolfram Language code: ψ = ExpToTrig[WaveletPsi[GaborWavelet[6], x]]

Plot the real part of a wavelet function overlaid by a sinusoid at the central frequency:

Wolfram Language code: Plot[{Re[ψ], (Cos[wc x]/π^(1/4))}, {x, -5, 5}]

Imaginary part:

Wolfram Language code: Plot[{Im[ψ], (Sin[wc x]/π^(1/4))}, {x, -5, 5}]
Wolfram Research (2010), GaborWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/GaborWavelet.html.

Text

Wolfram Research (2010), GaborWavelet, Wolfram Language function, https://reference.wolfram.com/language/ref/GaborWavelet.html.

CMS

Wolfram Language. 2010. "GaborWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GaborWavelet.html.

APA

Wolfram Language. (2010). GaborWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GaborWavelet.html

BibTeX

@misc{reference.wolfram_2026_gaborwavelet, author="Wolfram Research", title="{GaborWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/GaborWavelet.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_gaborwavelet, organization={Wolfram Research}, title={GaborWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/GaborWavelet.html}, note=[Accessed: 13-June-2026]}