CreateDataSystemModel will create an interpolated curve that is typically used as flexible input to other models.
CreateDataSystemModel returns a SystemModel[…] object that can be connected to other models.
CreateDataSystemModel["NewModel",…] gives the created model the name "NewModel".
CreateDataSystemModel["PackageA.NewModel",…] inserts "NewModel" into "PackageA".
The following options can be given:

InterpolationOrder	Automatic	interpolation order
SamplingPeriod	Automatic	time between samples
GeneratedAssetLocation	None	location of data file

Default values of InterpolationOrder according to input:
{v₁,v₂,…},{{t₁,v₁},…} 1

TimeSeries, InterpolatingFunction preserved

fun 3
For a list of values v_i, SamplingPeriod defaults to 1.
Sample points in TimeSeries and InterpolatingFunction are preserved.
Possible "dspec" values include:
"Time" time column and value columns

"1D" argument column and value columns

"2D" arguments row and column and value matrix
The corresponding data arrays have the layouts given here:

The default "dspec" is "Time".

Examples

open all close all

Basic Examples (3)

Create a model from a list of time-value pairs:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data]

Simulate and plot the output of the data model:

Wolfram Language code: sim = SystemModelSimulate[model, 10]

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Create a model from a TimeSeries:

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]

Wolfram Language code: model = CreateDataSystemModel[ts];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Create a data model of a sampled function between 0 and 10 seconds:

Wolfram Language code: model = CreateDataSystemModel[Sin, 0, 10];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Scope (18)

Value Lists (4)

Create a data model from a list of values:

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data];

The sample interval is assumed to be 1 second:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Specify a custom sampling period:

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 0.1];

Simulate for 1 second and plot:

Wolfram Language code: sim = SystemModelSimulate[model, 1];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Use a custom InterpolationOrder:

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SparseArray is interpreted as the corresponding Normal array:

Wolfram Language code: s = SparseArray[{{1} -> 1, {2} -> 3, {5} -> 2, {7} -> 1}];

Wolfram Language code: model = CreateDataSystemModel[s];

The sample interval is assumed to be 1 second:

Wolfram Language code: sim = SystemModelSimulate[model, 7];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Time-Value Pairs (3)

Create a model from a list of time-value pairs:

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Use a custom InterpolationOrder:

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Create data with multiple values for each time point:

Wolfram Language code:

data = {{0, 8, 4}, {1, 5, 2}, {2, 9, 6}, {3, 10, 2}, {4, 4, 1}, {5, 0, 4}, {6, 6, 8}, {7, 3, 6}, {8, 1, 3}, {9, 0, 1}, {10, 6, 1}};

Wolfram Language code: model = CreateDataSystemModel[data];

Simulate and plot the two output curves:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

TimeSeries (3)

Create a data model from a TimeSeries:

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]

Wolfram Language code: model = CreateDataSystemModel[ts];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

The InterpolationOrder from the TimeSeries is preserved:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]

Wolfram Language code: model = CreateDataSystemModel[ts];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Override the InterpolationOrder when creating a data model:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]

Wolfram Language code: model = CreateDataSystemModel[ts, InterpolationOrder -> 3];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolatingFunction (2)

Create a model from an InterpolatingFunction:

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: if = Interpolation[data];

Wolfram Language code: model = CreateDataSystemModel[if];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Resample an InterpolatingFunction before creating the model:

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: if = Interpolation[data];

Wolfram Language code: model = CreateDataSystemModel[if, SamplingPeriod -> 2];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Functions (3)

Create a data model of a function sampled for 10 seconds:

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10];

The sample points are automatically determined:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Choose the InterpolationOrder:

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 0];

Simulate and plot 2 seconds of the data output to show the interpolation order:

Wolfram Language code: sim = SystemModelSimulate[model, 2];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Set the sampling period when creating the model:

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 1, SamplingPeriod -> 1];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

Data Specification (3)

Create a data model that takes time and interpolates it over two value columns:

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

Show the first rows of the data:

Wolfram Language code: Take[data, 5]//MatrixForm

Create a model that uses time to interpolate over the data:

Wolfram Language code: model = CreateDataSystemModel[data, "Time"];

Simulate the model:

Wolfram Language code: sim = SystemModelSimulate[model, π];

Plot the interpolated variables:

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

Create a data model that takes an input and interpolates it over two value columns:

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

Show the first rows of the data:

Wolfram Language code: Take[data, 5]//MatrixForm

Create a model with the data:

Wolfram Language code: model = CreateDataSystemModel[data, "1D"];

Simulate with an input that samples the data at twice the speed of time:

Wolfram Language code: sim = SystemModelSimulate[model, π, <|"Inputs" -> {"u" -> Function[t, 2t]}|>];

Plot the interpolated variables:

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

Create a data model that takes two scalar inputs and runs them through a bivariate interpolation:

Wolfram Language code:

data = (⁠|     |     |     |     |     |
| --- | --- | --- | --- | --- |
| 0.0 | 0.1 | 0.2 | 0.3 | 0.4 |
| 0.1 | 0.3 | 0.5 | 0.7 | 0.9 |
| 0.2 | 0.4 | 0.6 | 0.8 | 1.0 |
| 0.3 | 0.5 | 0.7 | 0.9 | 1.1 |
| 0.4 | 0.6 | 0.8 | 1.0 | 1.2 |⁠);

Split coordinates and values to show the data in a 3D plot:

Wolfram Language code: xcoords = data[[2 ;; , 1]];

Wolfram Language code: ycoords = data[[1, 2 ;; ]];

Wolfram Language code: values = data[[2 ;; , 2 ;; ]];

Show the data points:

Wolfram Language code: points = Join@@Table[{xcoords[[x]], ycoords[[y]], values[[x, y]]}, {x, Length[xcoords]}, {y, Length[ycoords]}];

Wolfram Language code: p1 = ListPointPlot3D[points]

Create a model with the data:

Wolfram Language code: model = CreateDataSystemModel[data, "2D"];

Simulate with inputs:

Wolfram Language code: inputx = Function[t, 0.2 + 0.4t Cos[50 t]];

Wolfram Language code: inputy = Function[t, 0.2 + 0.4t Sin[50 t]];

Wolfram Language code: sim = SystemModelSimulate[model, 0.3, <|"Inputs" -> {"u1" -> inputx, "u2" -> inputy}|>];

Plot the interpolation results together with the original data:

Wolfram Language code: p2 = ParametricPlot3D[{inputx[t], inputy[t], sim["y", t]}, {t, 0, 0.3}];

Wolfram Language code: Show[p1, p2]

Options (7)

InterpolationOrder (3)

An InterpolationOrder of 0 gives constant segments between samples:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

An InterpolationOrder of 1 gives straight lines between samples:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 1];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

An InterpolationOrder of 3 gives a smooth line with a continuous derivative:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 3];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SamplingPeriod (3)

For a list of data, SamplingPeriod determines the period between data points:

Wolfram Language code: data = {6, 9, 1, 9, 7, 6};

Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 2];

The output has 2-second-long linear sections between samples:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

For a function, SamplingPeriod determines how often a function is sampled:

Wolfram Language code: model1 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 0.5, InterpolationOrder -> 0];

Wolfram Language code: model2 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 2, InterpolationOrder -> 0];

Simulate with sampling periods of 0.5 and 2 seconds:

Wolfram Language code: sim1 = SystemModelSimulate[model1, 10];

Wolfram Language code: sim2 = SystemModelSimulate[model2, 10];

Compare the output for each simulation:

Wolfram Language code: SystemModelPlot[{sim1, sim2}, "y[1]"]

For a TimeSeries, SamplingPeriod resamples uniformly:

Wolfram Language code: data = {{0, 5}, {1, 4}, {2, 2}, {3, 9}, {4, 1}, {5, 9}, {6, 4}, {7, 3}, {8, 9}, {9, 2}, {10, 0}};

Wolfram Language code: ts = TimeSeries[data]

Wolfram Language code: ListLinePlot[ts]

Downsample the time series when creating the data model:

Wolfram Language code: model = CreateDataSystemModel[ts, SamplingPeriod -> 3];

Simulate and plot the output:

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

GeneratedAssetLocation (1)

Data is stored in the model by default:

Wolfram Language code: model = CreateDataSystemModel[Range[3]];

Wolfram Language code: model["ModelicaDisplay"]

Use GeneratedAssetLocation to export a data file to a specified location referenced by the model:

Wolfram Language code: model = CreateDataSystemModel[Range[3], GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];

Wolfram Language code: model["ModelicaDisplay"]

Applications (1)

Create a data model with noisy output for 5 seconds:

Wolfram Language code: noise = CreateDataSystemModel[RandomFunction[WienerProcess[], {0., 5, 5 / 400}]];

Connect it to a lowpass filter:

Wolfram Language code:

filteredModel = ConnectSystemModelComponents[{"noise"∈noise, "filter"∈"Modelica.Blocks.Continuous.LowpassButterworth"}, {"noise.y[1]" -> "filter.u"}]

Simulate the filtering model:

Wolfram Language code: sim = SystemModelSimulate[filteredModel, 5]

Show the signal before and after filtering:

Wolfram Language code: SystemModelPlot[sim, {"filter.u", "filter.y"}]

Properties & Relations (2)

Insert created model in a package:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: CreateDataSystemModel["MyPackage.DataModel", data];

Wolfram Language code: CreateDataSystemModel["MyPackage.TimeSeriesModel", TimeSeries[data]];

The package contains both created models:

Wolfram Language code: SystemModels["MyPackage.*"]

Export as a file for use in a "CombiTimeTable" Modelica component:

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "data.txt"}], {"var1", data}, "MCTT"]

Possible Issues (1)

Larger datasets in the model may lead to slower simulations:

Wolfram Language code: data = Table[{t, RandomReal[10]}, {t, 0, 1000}];

Wolfram Language code: dataModel = CreateDataSystemModel[data];

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[dataModel, 1000]]

Simulating with data exported using MCTT Export is faster:

Wolfram Language code: fileModel = "DocumentationExamples.Simulation.FileInput";

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[fileModel, 1000]]

Use GeneratedAssetLocation to export a data file to a specified location referenced by the model:

Wolfram Language code: assetModel = CreateDataSystemModel[data, GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[assetModel, 1000]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

CreateDataSystemModel

Details and Options

Examples

Basic Examples (3)

Scope (18)

Value Lists (4)

Time-Value Pairs (3)

TimeSeries (3)

InterpolatingFunction (2)

Functions (3)

Data Specification (3)

Options (7)

InterpolationOrder (3)

SamplingPeriod (3)

GeneratedAssetLocation (1)

Applications (1)

Properties & Relations (2)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

	"Time"	time column and value columns
	"1D"	argument column and value columns
	"2D"	arguments row and column and value matrix

CreateDataSystemModel

Details and Options

Examples

Basic Examples (3)

Scope (18)

Value Lists (4)

Time-Value Pairs (3)

TimeSeries (3)

InterpolatingFunction (2)

Functions (3)

Data Specification (3)

Options (7)

InterpolationOrder (3)

SamplingPeriod (3)

GeneratedAssetLocation (1)

Applications (1)

Properties & Relations (2)

Possible Issues (1)

See Also

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX