WOLFRAM

Wolfram Language & System Documentation Center

DataDistribution[ddist,…]

represents a probability distribution of type ddist, estimated from a set of data.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
See Also
Related Guides
History
Cite this Page

DataDistribution

DataDistribution[ddist,…]

represents a probability distribution of type ddist, estimated from a set of data.

Details

Examples

open all close all

Basic Examples  (4)

Create a univariate DataDistribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10];

Using SmoothKernelDistribution:

Wolfram Language code: SmoothKernelDistribution[data]

Using HistogramDistribution:

Wolfram Language code: HistogramDistribution[data]

Visualize the PDF of a data distribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10];
Wolfram Language code: 𝒟 = SmoothKernelDistribution[data]
Wolfram Language code: Plot[PDF[𝒟, x], {x, -4, 4}, Frame -> True, Filling -> Axis]

Visualize the CDF of a data distribution:

Wolfram Language code: 𝒟 = HistogramDistribution[{-2, -1.5, -0.5, 1.1, 1.5, 2.25}]
Wolfram Language code: Plot[CDF[𝒟, x], {x, -4, 6}, Frame -> True, Filling -> Axis, Exclusions -> None]

Calculate moments of a data distribution:

Wolfram Language code: 𝒟 = SmoothKernelDistribution[{-2, -1.5, -0.5, 1.1, 1.5, 2.25}]

Mean:

Wolfram Language code: Mean[𝒟]

Variance:

Wolfram Language code: Variance[𝒟]

Scope  (4)

DataDistribution objects can be created from five data-based distributions:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 7];
Wolfram Language code: type = {SmoothKernelDistribution, KernelMixtureDistribution, SurvivalDistribution, EmpiricalDistribution, HistogramDistribution};
Wolfram Language code: TableForm[Table[f[data], {f, type}], {1, 5}]

Any property that applies to a parametric distribution applies to data distributions:

Wolfram Language code: data = RandomVariate[BetaDistribution[2, 3], 100];
Wolfram Language code: 𝒟 = KernelMixtureDistribution[data];

Generating functions:

Wolfram Language code: MomentGeneratingFunction[𝒟, t]//Short

Random number generation:

Wolfram Language code: Histogram[RandomVariate[𝒟, 100]]

Distribution functions:

Wolfram Language code: Plot[HazardFunction[𝒟, x], {x, 0, 1}, Filling -> Axis, Frame -> True]

Moments:

Wolfram Language code: Moment[𝒟, 2]

Multivariate data distribution:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.3], 100];
Wolfram Language code: 𝒟 = KernelMixtureDistribution[data];

Mean and standard deviation:

Wolfram Language code: Mean[𝒟]
Wolfram Language code: Variance[𝒟]

Scalar central moment for each marginal:

Wolfram Language code: CentralMoment[𝒟, 2]

Multivariate central joint moment:

Wolfram Language code: CentralMoment[𝒟, {2, 2}]

DataDistribution created from quantity data retains information about units:

Wolfram Language code: qa = QuantityArray[RandomReal[{10, 20}, 100], "Grams"]
Wolfram Language code: 𝒟 = EmpiricalDistribution[qa]

Extract distribution of the data magnitude and the unit of the data:

Wolfram Language code: {QuantityMagnitude[𝒟], QuantityUnit[𝒟]}

Find basic moments:

Wolfram Language code: {Mean[𝒟], StandardDeviation[𝒟], Skewness[𝒟], Kurtosis[𝒟]}
Wolfram Research (2010), DataDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/DataDistribution.html (updated 2016).

Text

Wolfram Research (2010), DataDistribution, Wolfram Language function, https://reference.wolfram.com/language/ref/DataDistribution.html (updated 2016).

CMS

Wolfram Language. 2010. "DataDistribution." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/DataDistribution.html.

APA

Wolfram Language. (2010). DataDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DataDistribution.html

BibTeX

@misc{reference.wolfram_2026_datadistribution, author="Wolfram Research", title="{DataDistribution}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/DataDistribution.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_datadistribution, organization={Wolfram Research}, title={DataDistribution}, year={2016}, url={https://reference.wolfram.com/language/ref/DataDistribution.html}, note=[Accessed: 13-June-2026]}