WOLFRAM

Wolfram Language & System Documentation Center

DiagonalMatrixQ[m]

gives True if m is diagonal, and False otherwise.

DiagonalMatrixQ[m,k]

gives True if m has nonzero elements only on the k^(th) diagonal, and False otherwise.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Special Matrices  
Options  
Tolerance  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

DiagonalMatrixQ

DiagonalMatrixQ[m]

gives True if m is diagonal, and False otherwise.

DiagonalMatrixQ[m,k]

gives True if m has nonzero elements only on the k^(th) diagonal, and False otherwise.

Details and Options

  • DiagonalMatrixQ[m,k] works even if m is not a square matrix.
  • In DiagonalMatrixQ[m,k], positive k refers to superdiagonals above the main diagonal and negative k refers to subdiagonals below the main diagonal.
  • DiagonalMatrixQ works with SparseArray and structured array objects.
  • The following option can be given:
  • Tolerance Automaticnumerical tolerance to use
  • For approximate matrices, the option Tolerance->t can be used to indicate that all entries Abs[mij]≤t are taken to be zero. »

Examples

open all close all

Basic Examples  (3)

Test if a matrix is diagonal:

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | a | 0 | 0 | | 0 | b | 0 | | 0 | 0 | c |⁠)]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 1 | 0 | 0 | | 0 | 0 | 2 | | 3 | 0 | 0 |⁠)]

Test a superdiagonal matrix:

Wolfram Language code: MatrixForm[{{0, a, 0}, {0, 0, b}, {0, 0, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, 1]

Test a subdiagonal matrix:

Wolfram Language code: MatrixForm[{{0, 0, 0}, {a, 0, 0}, {0, b, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, -1]

Scope  (12)

Basic Uses  (8)

Test rectangular diagonal matrices:

Wolfram Language code: (mat23 = {{1, 0, 0}, {0, 2, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat23]
Wolfram Language code: (mat32 = {{1, 0}, {0, 2}, {0, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat32]

Use DiagonalMatrixQ with a symbolic matrix:

Wolfram Language code: DiagonalMatrixQ[{{a, b}, {c, d}}]

The matrix becomes diagonal when :

Wolfram Language code: Block[{b = c = 0}, DiagonalMatrixQ[{{a, b}, {c, d}}]]

Test if a real machine-precision matrix is diagonal:

Wolfram Language code: m = {{1.2, 0, 0}, {0, 2.4, 0}, {0, 0, 3.5}};
Wolfram Language code: DiagonalMatrixQ[m]

Test if a complex matrix is diagonal:

Wolfram Language code: m = {{1, -3I}, {0, 4}};
Wolfram Language code: DiagonalMatrixQ[m]

The real part of the matrix is diagonal and the imaginary part is superdiagonal:

Wolfram Language code: {DiagonalMatrixQ[Re[m]], DiagonalMatrixQ[Im[m], 1]}

Test if an exact matrix is diagonal:

Wolfram Language code: m = (⁠| | | | | - | - | ------- | | 0 | 5 | 4 | | 3 | 1 | Sqrt[2] | | 3 | 5 | Pi |⁠);
Wolfram Language code: DiagonalMatrixQ[m]

Use DiagonalMatrixQ with an arbitrary-precision matrix:

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

A random matrix is typically non-diagonal:

Wolfram Language code: DiagonalMatrixQ[m]

Test if matrices have nonzero entries only on a particular superdiagonal:

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 2]

Note that the matrix is not diagonal:

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠)]

Test if matrices have nonzero entries only on a particular subdiagonal:

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -2]

Note that the matrix is not diagonal:

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠)]

Special Matrices  (4)

Use DiagonalMatrixQ with sparse matrices:

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]
Wolfram Language code: DiagonalMatrixQ[%]
Wolfram Language code: SparseArray[{{x_, y_} /; x == y -> 3}, {5, 5}]
Wolfram Language code: DiagonalMatrixQ[%]

Use DiagonalMatrixQ with structured matrices:

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 4, {2, 2} -> 5, {3, 3} -> 6}, {3, 3}, Symmetric[All]]
Wolfram Language code: DiagonalMatrixQ[%]

Use with a QuantityArray structured matrix:

Wolfram Language code: QuantityArray[{{1, 0}, {0, 5}}, "Meters"]
Wolfram Language code: DiagonalMatrixQ[%]

The identity matrix is diagonal:

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

HilbertMatrix is not diagonal:

Wolfram Language code: DiagonalMatrixQ[HilbertMatrix[5]]

Options  (1)

Tolerance  (1)

This matrix is not diagonal:

Wolfram Language code: m = {{1., 10 ^ -12, 0}, {0, 2., 10 ^ -13}, {0, 0, 3.}}; DiagonalMatrixQ[m]

Add the Tolerance option to consider numbers smaller than 10-12 to be zero:

Wolfram Language code: DiagonalMatrixQ[m, Tolerance -> 10 ^ -12]

Applications  (2)

A real-valued matrix is orthogonally similar to a diagonal matrix iff it is normal and has real eigenvalues:

Wolfram Language code: m = N[HilbertMatrix[3]]; NormalMatrixQ[m]

Compute the eigenvalues and eigenvectors of m:

Wolfram Language code: {vals, vecs} = Eigensystem[m];

The eigenvalues are real:

Wolfram Language code: vals∈Reals

Verify that m is equivalent to a diagonal matrix via its eigenvectors:

Wolfram Language code: DiagonalMatrixQ[vecs.m.Transpose[vecs]]

Verify that the eigenvector matrix is orthogonal:

Wolfram Language code: OrthogonalMatrixQ[vecs]

A matrix is diagonalizable if and only if its canonical Jordan matrix is diagonal:

Wolfram Language code: mat1 = {{1, 2}, {3, 4}}; (j1 = Last[JordanDecomposition[mat1]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat1], DiagonalMatrixQ[j1]}
Wolfram Language code: mat2 = {{27, 48, 81}, {-6, 0, 0}, {1, 0, 3}}; (j2 = Last[JordanDecomposition[mat2]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat2], DiagonalMatrixQ[j2]}

Properties & Relations  (10)

DiagonalMatrixQ returns False for inputs that are not matrices:

Wolfram Language code: DiagonalMatrixQ[1]
Wolfram Language code: DiagonalMatrixQ[{}]

Matrices of dimensions {n,0} are diagonal:

Wolfram Language code: DiagonalMatrixQ[{{}, {}}]

DiagonalMatrix creates a diagonal matrix:

Wolfram Language code: (m = DiagonalMatrix[{a, b, c, d}])//MatrixForm
Wolfram Language code: DiagonalMatrixQ[m]

Any identity matrix is diagonal:

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

Inverses of diagonal matrices are diagonal:

Wolfram Language code: mat = DiagonalMatrix[Range[5]];
Wolfram Language code: DiagonalMatrixQ[Inverse[mat]]

This extends to arbitrary powers and functions:

Wolfram Language code: DiagonalMatrixQ[MatrixPower[mat, n]]
Wolfram Language code: DiagonalMatrixQ[MatrixFunction[f, mat]]

The product of two (or more) diagonal matrices is diagonal:

Wolfram Language code: m1 = DiagonalMatrix[RandomReal[1., {5}]]; m2 = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: DiagonalMatrixQ[m1.m2]

A diagonal matrix is both upper and lower triangular:

Wolfram Language code: mat = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: {DiagonalMatrixQ[m1], UpperTriangularMatrixQ[m1], LowerTriangularMatrixQ[m1]}

DiagonalMatrixQ[m,0] is equivalent to DiagonalMatrixQ[m]:

Wolfram Language code: {DiagonalMatrixQ[{{1, 0}, {0, 2}}], DiagonalMatrixQ[{{1, 0}, {0, 2}}, 0]}
Wolfram Language code: {DiagonalMatrixQ[{{1, 3}, {4, 2}}], DiagonalMatrixQ[{{1, 3}, {4, 2}}, 0]}

A matrix with only subdiagonals or superdiagonals is nilpotent, meaning for some :

Wolfram Language code: m1 = DiagonalMatrix[Range[4], -1]; DiagonalMatrixQ[m1, -1]
Wolfram Language code: MatrixPower[m1, 5]
Wolfram Language code: m2 = DiagonalMatrix[Range[4], 1]; DiagonalMatrixQ[m2, 1]
Wolfram Language code: MatrixPower[m2, 5]

Band can be used to construct a k-diagonal sparse matrix:

Wolfram Language code: k = RandomInteger[5]
Wolfram Language code: m = SparseArray[Band[{1, 1 + k}] -> Range[5], (5 + k){1, 1}]
Wolfram Language code: DiagonalMatrixQ[m, k]
Wolfram Research (2019), DiagonalMatrixQ, Wolfram Language function, https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

Text

Wolfram Research (2019), DiagonalMatrixQ, Wolfram Language function, https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

CMS

Wolfram Language. 2019. "DiagonalMatrixQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

APA

Wolfram Language. (2019). DiagonalMatrixQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html

BibTeX

@misc{reference.wolfram_2026_diagonalmatrixq, author="Wolfram Research", title="{DiagonalMatrixQ}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_diagonalmatrixq, organization={Wolfram Research}, title={DiagonalMatrixQ}, year={2019}, url={https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}, note=[Accessed: 12-June-2026]}