Wolfram Language & System Documentation Center

ElectrostaticPDEComponent

ElectrostaticPDEComponent[vars,pars]

yields an electrostatic PDE term with variables vars and parameters pars.

Details

ElectrostaticPDEComponent is typically used to generate an electrostatic equation with model variables vars and model parameters pars.
ElectrostaticPDEComponent returns a sum of differential operators to be used as a part of partial differential equations:

ElectrostaticPDEComponent models static electric fields produced by stationary charges in insulating, or dielectric materials.

ElectrostaticPDEComponent models electrostatic phenomena with the dependent variable , the electric scalar potential. is in units of volt [], independent variables in units of [].
Stationary variables vars are vars={V[x₁,…,x_n],{x₁,…,x_n}}.
ElectrostaticPDEComponent generally does not produces a time-dependent PDE.
ElectrostaticPDEComponent is based on a diffusion, a source and a derivative PDE term:

is the vacuum permittivity in units of [], the polarization vector in units of [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ] and the volume charge density in units of [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ].
The polarization vector specifies the density of permanent or induced electric dipole moments inside a material.
The volume charge density models charge distributions, negative or positive.
ElectrostaticPDEComponent can produce different equations, depending on the constitutive relationship.
For linear materials, the ElectrostaticPDEComponent equation simplifies to:

is the unitless relative permittivity.
can be isotropic, orthotropic or anisotropic.
For nonlinear non-hysteresis ferroelectric materials, the ElectrostaticPDEComponent equation is given as:

is the remanent polarization vector in units of [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ].
The implicit default boundary condition for the electrostatic model is a 0 ElectricFluxDensityValue.
The units of the electrostatic model terms are in [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ], or equivalently in [ $TemplateBox[{InterpretationBox[, 1], {"s", , "A", , "/", , {"m", ^, 3}}, second amperes per meter cubed, {{(, {"Amperes", , "Seconds"}, )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ].
The following parameters pars can be given:

parameter	default	symbol
"Polarization"	{0,…}	, polarization vector in [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"RegionSymmetry"	None
"RelativePermittivity"	1	, unitless relative permittivity
"RemanentPolarization"	{0,…}	, remanent polarization vector in [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"Thickness"	1	, thickness in []
"CrossSectionalArea"	1	, cross-sectional area in [ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ]
"VacuumPermittivity"		, vacuum permittivity in []
"VolumeChargeDensity"	0	, volume charge density in [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]

All parameters may depend on the spacial variable and dependent variable .
The number of independent variables determines the dimensions of or and the length of vectors and .
A possible choice for the parameter "RegionSymmetry" is "Axisymmetric".
"Axisymmetric" region symmetry represents a truncated cylindrical coordinate system where the cylindrical coordinates are reduced by removing the angle variable as follows:
dimension reduction equation

1D

2D
In 2D, when a "Thickness" is specified, the ElectrostaticPDEComponent equation is given as:

In 1D, when a "CrossSectionalArea" is specified, the ElectrostaticPDEComponent equation is given as:

In a 1D axisymmetric, when a "Thickness" is specified, the ElectrostaticPDEComponent equation is given as:

The input specification for the parameters is exactly the same as for their corresponding operator terms.
If no parameters are specified, the default electrostatic PDE is:

If the ElectrostaticPDEComponent depends on parameters that are specified in the association pars as …,keyp_i…,p_iv_i,…, the parameters are replaced with .

Examples

open all close all

Basic Examples (3)

Define an electrostatic model :

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <||>]

Set up an electrostatic model with particular material parameters:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Subscript[ϵ, 𝓇], "VolumeChargeDensity" -> Subscript[ρ, v]|>]

Specify model variables and electrostatic parameters:

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

Set up and solve an electrostatic PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]}}, V, {x, 0, 0.08}]

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], {x, 0, 0.08}]

Scope (14)

1D (4)

Define a 1D electrostatic model with a cross-sectional area :

Wolfram Language code:

ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[1], "CrossSectionalArea" -> A, "VolumeChargeDensity" -> Subscript[ρ, s]|>]

Model an electric potential field with two electric potential conditions at the sides.

Specify model variables and electrostatic parameters:

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 2|>;

Set up and solve an electrostatic PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

Model an electric potential field with two electric potential conditions at the sides and a discontinuous relative permittivity.

Specify model variables and electrostatic parameters:

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

Set up and solve an electrostatic PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

2D (5)

Define a 2D electrostatic model with a polarization vector:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0] * IdentityMatrix[2], "Polarization" -> {Px[x, y], Py[x, y]}|>]

Define a 2D nonlinear electrostatic model with a remanent polarization vector:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RemanentPolarization" -> {Prx[x, y], Pry[x, y]}|>]

Define a 2D electrostatic model with a thickness :

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "Thickness" -> d|>]

Define an orthotropic relative permittivity:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]

Define a fully anisotropic relative permittivity:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], Subscript[ϵ, r12]}, {Subscript[ϵ, r21], Subscript[ϵ, r12]}}|>]

2D Axisymmetric (2)

Define a 2D axisymmetric electrostatic model:

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RegionSymmetry" -> "Axisymmetric"|>]

Define a 2D axisymmetric orthotropic electrostatic model:

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, 𝓇𝓇], 0}, {0, Subscript[ϵ, zz]}}, "RegionSymmetry" -> "Axisymmetric"|>]

3D (1)

Model an electric potential field in a hollow ball with electric potential conditions at the inner and outer radii.

Specify model variables and electrostatic parameters:

Wolfram Language code:

vars = {V[x, y, z], {x, y, z}};
pars = <|"RelativePermittivity" -> 3.9|>;

Set up and solve an electrostatic PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 <= (3 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 32|>], ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 >= (9 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 0|> ]}}, V, {x, y, z} ∈ RegionDifference[Ball[{0, 0, 0}, 10 / 1000], Ball[{0, 0, 0}, 3 / 1000]]];

Visualize the solution:

Wolfram Language code:

SliceContourPlot3D[Vfun[x, y, z], "CenterPlanes", {x, -10 / 1000, 10 / 1000}, {y, -10 / 1000, 10 / 1000}, {z, -10 / 1000, 10 / 1000}, ColorFunction -> "Rainbow"]

Multi-material (2)

Set up an electrostatic model for several material regions:

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Piecewise[{{7, y <= 1}, {2, y > 1}}]|>]

Model an electric potential field with two electric potential conditions at the sides and a discontinuous relative permittivity.

Specify model variables and electrostatic parameters:

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

Set up and solve an electrostatic PDE:

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

Applications (4)

1D (2)

Compute the electric potential distribution between two parallel plates separated by a distance [] and positioned normal to the axis. The left plate is maintained at a constant potential [], whereas the right plate is grounded, []. The region between the plates is characterized by a relative permittivity and a uniform electron charge density [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]. The equation to model is given by:

Set up the electrostatic model variables :

Wolfram Language code: vars = {V[x], {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

Specify electrostatic model parameters:

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

Specify the electric potential conditions:

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

Set up the equation:

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], x∈Ω]

Compute the electrical potential distribution between two parallel plates with the same distance and boundary conditions as in the previous example, but now with a nonuniform charge distribution given by:

Set up the electrostatic model variables :

Wolfram Language code: vars = {V[x], {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

Specify electrostatic model parameters:

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8 * (1 - (x/0.08))^2|>;

Specify the electric potential conditions:

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

Set up the equation:

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], x∈Ω]

2D (1)

Model an infinitely long rectangular box with metallic walls. The box has a width of [], and a height of []. The side and bottom walls are maintained at zero electric potential, whereas the top wall has a fixed electric potential of . The region inside the box is free of charge . The equation to model is given by:

Define the model variables and parameters:

Wolfram Language code:

vars = {V[x, y], {x, y}};
pars = <|"RelativePermittivity" -> 1|>;

Set up the model region:

Wolfram Language code:

w = 1;
h  = 2;
Ω = Rectangle[{0, 0}, {w, h}];

Set up a 2D electrostatic model:

Wolfram Language code: op = ElectrostaticPDEComponent[vars, pars];

The bottom and parts of the side walls at are maintained at a zero electric potential:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[y <= 1, vars, pars];

The top wall at is fixed with an electric potential of []:

Wolfram Language code:

V0 = 1;
Subscript[Γ, potential] = ElectricPotentialCondition[y == h, vars, pars, <|"ElectricPotential" -> V0|>];

Set up the equation:

Wolfram Language code: eqn = {op == 0, Subscript[Γ, ground], Subscript[Γ, potential]};

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[eqn, V, {x, y}∈Ω];

Visualize the solution:

Wolfram Language code: Legended[ContourPlot[Vfun[x, y], {x, y}∈Ω, ...], BarLegend[...]]

3D (1)

Model a dielectric material of a cylindrical capacitor with two electric potential conditions at the upper and lower boundaries, which represent the capacitor electrodes. The equation to model is given by:

Set up the electrostatic model variables :

Wolfram Language code: vars = {V[x, y, z], {x, y, z}};

Set up a region :

Wolfram Language code:

r0 = 0.01;
h = 0.001;
Ω = Cylinder[{{0, 0, 0}, {0, 0, h}}, r0];

Specify a relative permittivity :

Wolfram Language code: pars = <|"RelativePermittivity" -> 2|>;

Specify ground potential at the lower boundary:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0, vars, pars];

Specify an electric potential of [] at the upper boundary:

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[z == h, vars, pars, <|"ElectricPotential" -> 1|>];

Set up the equation:

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y, z}∈Ω]

Visualize the solution:

Wolfram Language code: SliceDensityPlot3D[Vfun[x, y, z], "CenterPlanes", {x, y, z}∈Ω, ...]

Possible Issues (1)

For symbolic computation, the "VacuumPermittivity" or "RelativePermittivity" parameter should be given as a matrix:

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]//Activate

For numeric values, the "VacuumPermittivity" or "RelativePermittivity" parameter is automatically converted to a matrix of proper dimensions:

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> 1|>]

This automatic conversion is not possible for symbolic input:

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0]|>]

Not providing the properly dimensioned matrix will result in an error:

Wolfram Language code: %//Activate

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

ElectrostaticPDEComponent

Details

Examples

Basic Examples (3)

Scope (14)

1D (4)

2D (5)

2D Axisymmetric (2)

3D (1)

Multi-material (2)

Applications (4)

1D (2)

2D (1)

3D (1)

Possible Issues (1)

Text

CMS

APA

BibTeX

BibLaTeX

dimension	reduction	equation
1D
2D

ElectrostaticPDEComponent

Details

Examples

Basic Examples (3)

Scope (14)

1D (4)

2D (5)

2D Axisymmetric (2)

3D (1)

Multi-material (2)

Applications (4)

1D (2)

2D (1)

3D (1)

Possible Issues (1)

See Also

Tech Notes

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX