WOLFRAM

Wolfram Language & System Documentation Center

ElectricPotentialCondition[pred,vars,pars]

represents an electric potential surface boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

ElectricPotentialCondition[pred,vars,pars,lkey]

represents an electric potential surface boundary condition with local parameters specified in pars[lkey].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
1D  
2D  
3D  
See Also
Tech Notes
Related Guides
History
Cite this Page

ElectricPotentialCondition

ElectricPotentialCondition[pred,vars,pars]

represents an electric potential surface boundary condition for PDEs with predicate pred indicating where it applies, with model variables vars and global parameters pars.

ElectricPotentialCondition[pred,vars,pars,lkey]

represents an electric potential surface boundary condition with local parameters specified in pars[lkey].

Details

Examples

open all close all

Basic Examples  (3)

Set up an electric potential surface boundary condition:

Wolfram Language code: ElectricPotentialCondition[x ≥ 0, {V[x, y], {x, y}}, <|"ElectricPotential" -> Subscript[V, s][x, y]|>]

Set up a default electric potential surface boundary condition:

Wolfram Language code: ElectricPotentialCondition[x ≥ 0, {V[x, y], {x, y}}, <||>]

Compute the electric potential distribution with model variables vars and parameters pars with an electric potential of [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]] at the left boundary and a ground potential at the right boundary.

Specify model variables and electrostatic parameters:

Wolfram Language code: vars = {V[x], {x}}; pars = <|"RelativePermittivity" -> 2|>;

Set up and solve an electrostatic PDE:

Wolfram Language code: Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

Scope  (4)

Define model variables vars for an electrostatic analysis with model parameters pars and multiple specific parameter boundary conditions:

Wolfram Language code: vars = {V[x, y], {x, y}}; pars = <|"RelativePermittivity" -> 1, "BoundaryCondition1" -> <|<|"ElectricPotential" -> V1|>|>, "BoundaryCondition2" -> <|<|"ElectricPotential" -> V2|>|>|>;
Wolfram Language code: ElectricPotentialCondition[x == 0, vars, pars, "BoundaryCondition1"]
Wolfram Language code: ElectricPotentialCondition[x == 1, vars, pars, "BoundaryCondition2"]

1D  (1)

Compute the electric potential distribution between two parallel plates separated by a distance [TemplateBox[{InterpretationBox[, 1], "cm", centimeters, "Centimeters"}, QuantityTF]] and positioned normal to the axis. The left plate is maintained at a constant potential [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]], whereas the right plate is grounded, . The region between the plates is characterized by a relative permittivity and a uniform electron charge density [TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]]. The equation to use in the model is given by:

del .(-epsilon_0epsilon_r del V(x))^(︷^( electrostatic model)) =rho_v

Set up the electrostatic model variables vars:

Wolfram Language code: vars = {V[x], {x}};

Set up a region :

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

Specify electrostatic model parameters:

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

Specify the electric potential conditions:

Wolfram Language code: Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]}

Set up the equation:

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

Visualize the solution:

Wolfram Language code: Plot[Vfun[x], x∈Ω]

2D  (1)

Solve for the electric scalar potential in a three-bar electric switch with an electrical conductivity of . The equation to use in the model is given by:

del .(-sigma del V(x,y))^(︷^( stationary current model)) =0

Set up the electrostatic model variables vars:

Wolfram Language code: vars = {V[x, y], {x, y}};

Set up a region :

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 2.5}, {10, 7.5}], Rectangle[{9, -2.5}, {10 + 9, 2.5}], Rectangle[{0, -7.5}, {10, -2.5}]];

Specify an electrical conductivity :

Wolfram Language code: pars = <|"ElectricalConductivity" -> 6*^7|>;

Specify ground potential at the lower boundary:

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[y == -7.5, vars, pars, <|"ElectricPotential" -> 0|>];

Specify an electric potential of [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]] at the upper boundary:

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[y == 7.5, vars, pars, <|"ElectricPotential" -> 5|>];

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{ElectricCurrentPDEComponent[vars, pars] == 0, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y}∈Ω];

Compute the current density vector:

Wolfram Language code: Jfield = -6*^7 * Grad[Vfun[x, y], {x, y}];

Visualize the current density vector:

Wolfram Language code: VectorPlot[Jfield, {x, y}∈Ω, AspectRatio -> Automatic]

3D  (1)

Model a simplified bushing insulator of a transformer with an electric potential condition at the inner walls, which are in contact with the high-voltage conductor, and a ground potential boundary at one of the surface plates (). The equation to use in the model is given by:

del .(-epsilon_0epsilon_r del V(x,y,z))^(︷^( electrostatic model)) =0

Set up the electrostatic model variables vars:

Wolfram Language code: vars = {V[x, y, z], {x, y, z}};

Set up the geometry:

Wolfram Language code: insulator = \!\(\*Graphics3DBox[«7»]\);

Specify a relative permittivity :

Wolfram Language code: pars = <|"RelativePermittivity" -> 5|>;

Specify a ground potential at the surface :

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0.2, vars, pars, <|"ElectricPotential" -> 0|>];

Specify an electric potential of [TemplateBox[{InterpretationBox[, 1], "V", volts, "Volts"}, QuantityTF]] at the inner walls:

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[x ^ 2 + y ^ 2 <= 0.2 ^ 2, vars, pars, <|"ElectricPotential" -> 10 ^ 3|>];

Set up the equation:

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0;

Solve the PDE:

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y, z}∈insulator]

Visualize the solution:

Wolfram Language code: Legended[RegionPlot3D[insulator, ColorFunction -> Function[{x, y, z}, ColorData[{"Rainbow", MinMax[Vfun["ValuesOnGrid"]]}][Vfun[x, y, z]]], ...], BarLegend[...]]
Wolfram Research (2024), ElectricPotentialCondition, Wolfram Language function, https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html (updated 2024).

Text

Wolfram Research (2024), ElectricPotentialCondition, Wolfram Language function, https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html (updated 2024).

CMS

Wolfram Language. 2024. "ElectricPotentialCondition." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html.

APA

Wolfram Language. (2024). ElectricPotentialCondition. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html

BibTeX

@misc{reference.wolfram_2026_electricpotentialcondition, author="Wolfram Research", title="{ElectricPotentialCondition}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_electricpotentialcondition, organization={Wolfram Research}, title={ElectricPotentialCondition}, year={2024}, url={https://reference.wolfram.com/language/ref/ElectricPotentialCondition.html}, note=[Accessed: 13-June-2026]}