Wolfram Language & System Documentation Center

RegionMember

RegionMember[reg,{x,y,…}]

gives True if the numeric point {x,y,…} is a member of the constant region reg and False otherwise.

RegionMember[reg,{x,y,…}]

gives conditions for the point {x,y,…} to be a member of reg.

RegionMember[reg]

returns a RegionMemberFunction[…] that can be applied repeatedly to different points.

Details

RegionMember is also known as point in region test, membership test, and membership conditions.

A constant region is a region where ConstantRegionQ[reg] gives True.

Examples

open all close all

Basic Examples (3)

Test whether a particular point is in a region:

Wolfram Language code: RegionMember[Polygon[{{0, 0}, {1, 0}, {0, 1}}], {1 / 3, 1 / 3}]

Get conditions for point membership:

Wolfram Language code: RegionMember[Disk[], {x, y}]

Create RegionMemberFunction to apply to different points:

Wolfram Language code: mf = RegionMember[Disk[{0, 0}, 3]]

Wolfram Language code: mf[RandomReal[4, {7, 2}]]

Scope (23)

Basic Uses (4)

Directly test whether a point is in a region:

Wolfram Language code: ℛ = Rectangle[{0, 0}, {2, 2}];

Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {3, 3}]}

Directly test whether a list of points is in a region:

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 2];

Wolfram Language code: RegionMember[ℛ, RandomReal[2, {7, 3}]]

Get conditions for point membership by using variables {x,y}:

Wolfram Language code: ℛ = Rectangle[{0, 0}, {2, 2}];

Wolfram Language code: RegionMember[ℛ, {x, y}]

Create RegionMemberFunction to apply to different points:

Wolfram Language code: ℛ = Disk[{0, 0}, 2];

Wolfram Language code: mf = RegionMember[ℛ]

Wolfram Language code: mf[RandomReal[3, {7, 2}]]

Special Regions (6)

Regions in :

Wolfram Language code: RegionMember[Point[{1}], {x}]

Wolfram Language code: RegionMember[Interval[{1, 5}], {x}]

Wolfram Language code: RegionMember[Interval[{1, 5}], {6}]

Regions in :

Wolfram Language code: RegionMember[Point[{1, 2}], {x, y}]

Wolfram Language code: RegionMember[Circle[{0, 0}, 2], {x, y}]

Wolfram Language code: RegionMember[Disk[{1, 2}, {3, 4}], {x, y}]

Wolfram Language code: RegionMember[Circle[{0, 0}, 2], {3, 3}]

Visualize region membership in :

Wolfram Language code: ℛ = Triangle[{{0, 0}, {1, 2}, {2, 1}}];

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounding box for the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Wolfram Language code:

col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}}]

Regions in :

Wolfram Language code: RegionMember[Point[{1, 2, 3}], {x, y, z}]

Wolfram Language code: RegionMember[Line[{{1, 2, 3}, {4, 5, 6}}], {x, y, z}]

Wolfram Language code: RegionMember[Polygon[{{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}], {x, y, z}]

Wolfram Language code: RegionMember[Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2], {x, y, z}]

Wolfram Language code: RegionMember[Ball[{0, 0, 0}, 2], {3, 3, 3}]

Visualize region membership in :

Wolfram Language code:

ℛ = Cuboid[{-1, -1, -1}, {1, 1, 1}];
in = RegionCentroid[ℛ];
out = {2, 0, 0};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Graphics3D[{{Opacity[0.2], ℛ}, PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}, Boxed -> False]

Regions in :

Wolfram Language code: RegionMember[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}], {x, y, z, t}]

Wolfram Language code: RegionMember[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}], {x, y, z, t, u}]

Wolfram Language code: RegionMember[Ball[{0, 0, 0, 0, 0, 0, 0}, 8], {1, 2, 3, 4, 5, 6, 7}]

Formula Regions (3)

Implicit regions:

Wolfram Language code: RegionMember[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}], {x, y}]

Wolfram Language code: RegionMember[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}], {x, y, z}]

Visualize region membership in :

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounding box for the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Wolfram Language code:

col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}}]

Parametric regions:

Wolfram Language code: RegionMember[ParametricRegion[{(1 - t ^ 2) / (1 + t ^ 2), 2t / (1 + t ^ 2)}, {t}], {x, y}]

Wolfram Language code:

RegionMember[ParametricRegion[{{u + v + w, u + v - w, u - v - w, -u - v - w}, -1 ≤ u ≤ 1 && -1 ≤ v ≤ 1 && -1 ≤ w ≤ 1}, {u, v, w}], {x, y, z, t}]

Mesh Regions (4)

MeshRegion in 2D:

Wolfram Language code:

ℛ = DelaunayMesh[RandomReal[8, {100, 2}]];
in = RegionCentroid[ℛ];
out = {9, 9};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Show[ℛ, Graphics[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

In 3D:

Wolfram Language code:

ℛ = DelaunayMesh[RandomReal[8, {100, 3}]];
in = RegionCentroid[ℛ];
out = {9, 9, 9};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code:

Show[HighlightMesh[RegionBoundary[ℛ], Style[2, Opacity[0.1]]], Graphics3D[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

BoundaryMeshRegion in 2D:

Wolfram Language code:

ℛ = ConvexHullMesh[RandomReal[8, {100, 2}]];
in = RegionCentroid[ℛ];
out = {9, 9};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Show[ℛ, Graphics[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

BoundaryMeshRegion in 3D:

Wolfram Language code:

ℛ = ConvexHullMesh[RandomReal[8, {1000, 3}]];
in = RegionCentroid[ℛ];
out = {9, 9, 9};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Show[HighlightMesh[ℛ, Style[2, Opacity[0.2]]], Graphics3D[{PointSize[Large], {Green, Point[in]}, {Red, Point[out]}}]]

Derived Regions (4)

RegionIntersection of two regions:

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];

Wolfram Language code: RegionMember[ℛ, {x, y}]

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounding box for the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Wolfram Language code:

col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}}]

RegionUnion of mixed-dimensional regions:

Wolfram Language code:

ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Region[ℛ]

Wolfram Language code: RegionMember[ℛ, {x, y}]

TransformedRegion:

Wolfram Language code: ℛ = TransformedRegion[Disk[{0, 0}, 1], ShearingTransform[θ, {1, 0}, {0, 1}]];

Wolfram Language code: RegionMember[ℛ, {x, y}]

RegionBoundary:

Wolfram Language code:

ℛ = RegionBoundary[Disk[{0, 0}, 1]];
Region[ℛ]

Wolfram Language code: RegionMember[ℛ, {x, y}]

CSG Regions (1)

CSGRegion in 2D:

Wolfram Language code:

ℛ = CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}];
in = {-1 / 2, -1 / 2};
out = {0, 0};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Show[ℛ, Graphics[{PointSize[Large], {StandardGreen, Point[in]}, {StandardRed, Point[out]}}]]

3D:

Wolfram Language code:

ℛ = CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}];
in = {0, 0, 0};
out = {1, 1, 1};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code:

Show[Region[BoundaryDiscretizeRegion[ℛ], BaseStyle -> Opacity[0.2]], Graphics3D[{Opacity[1], PointSize[Large], {StandardGreen, Point[in]}, {StandardRed, Point[out]}}]]

Subdivision Regions (1)

SubdivisionRegion in 2D:

Wolfram Language code:

ℛ = SubdivisionRegion[Rectangle[]];
in = {1 / 2, 1 / 2};
out = {1, 1};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code: Show[ℛ, Graphics[{PointSize[Large], {StandardGreen, Point[in]}, {StandardRed, Point[out]}}]]

3D:

Wolfram Language code:

ℛ = SubdivisionRegion[Tetrahedron[]];
in = {0, 0, 0};
out = {1 / 10, 1 / 10, 1 / 10};

Wolfram Language code: {RegionMember[ℛ, in], RegionMember[ℛ, out]}

Wolfram Language code:

Show[Region[BoundaryDiscretizeRegion[ℛ], BaseStyle -> Opacity[0.2]], Graphics3D[{Opacity[1], PointSize[Large], {StandardGreen, Point[in]}, {StandardRed, Point[out]}}]]

Applications (6)

Basic (2)

Convert polygon data for the given country to a MeshRegion:

Wolfram Language code: ℛ = DiscretizeGraphics[CountryData["Austria", {"FullPolygon", "Mercator"}]]

Determine membership of a city:

Wolfram Language code: city = GeoGridPosition[GeoPosition[Entity["City", {"Vienna", "Vienna", "Austria"}]], "Mercator"]["Data"]

Wolfram Language code: RegionMember[ℛ, city]

Wolfram Language code: Show[ℛ, Epilog -> {Red, Point@city}]

For a parameterized region, RegionMember can give conditions on the parameters to determine when a given point is a member:

Wolfram Language code:

ℛ = Disk[{0, 0}, {Subscript[r, x], Subscript[r, y]}];
RegionMember[ℛ, {3, 4}]

Find an instance where the region includes the point:

Wolfram Language code: FindInstance[%, {Subscript[r, x], Subscript[r, y]}]

Visualize it:

Wolfram Language code: Graphics[{LightGray, ℛ /. %, Red, Point[{3, 4}]}]

Random Points in a Region (2)

Generate points on a region by filtering a uniform set of points:

Wolfram Language code: ℛ = ImplicitRegion[1 < x ^ 2 + y ^ 2 < 3, {x, y}];

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ];

Uniformly sample over the bounding box of the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Select member points:

Wolfram Language code: mpts = Select[pts, RegionMember[ℛ]];

Visualize member points:

Wolfram Language code: Graphics[{AbsolutePointSize[1], Point[mpts]}]

Convert polygon data for the given country to a MeshRegion:

Wolfram Language code: ℛ = [image];

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounding box of the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Wolfram Language code:

col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{AbsolutePointSize[1], {col, Point /@ pts}}]

Monte Carlo Integration (2)

Perform Monte Carlo integration to estimate the area of a unit disk:

Wolfram Language code:

ℛ = Disk[{0, 0}, 1];
Region[ℛ]

Get the region bounds:

Wolfram Language code: bounds = RegionBounds[ℛ]

Uniformly sample over the bounding box of the region:

Wolfram Language code: pts = RandomVariate[UniformDistribution[bounds], 10 ^ 4];

Wolfram Language code:

col = RegionMember[ℛ, pts] /. {False -> Gray, True -> Red};
Graphics[{ℛ, AbsolutePointSize[1], {col, Point /@ pts}}]

Count the number of samples inside the region:

Wolfram Language code: inside = Count[RegionMember[ℛ, pts], True]

Get the ratio of samples inside the region to the total number of sample points:

Wolfram Language code: ratio = N[(inside/Length[pts])]

Get the bounding area:

Wolfram Language code: area = Area[Cuboid@@(bounds)]

Get the approximate area of the region:

Wolfram Language code: area * ratio

Use random points in a region to perform Monte Carlo integration:

Wolfram Language code:

ℛ = ImplicitRegion[2 ≤ x^2 + y^2 ≤ 4, {x, y}];
pts = Select[RandomVariate[UniformDistribution[RegionBounds[ℛ]], 10 ^ 5], RegionMember[ℛ, #]&];

Evaluate a function at each sample point and take their average:

Wolfram Language code:

f[x_, y_] := x^3 + y^4;
intVal = Mean[f@@@pts]RegionMeasure[ℛ]

Compare with the exact value:

Wolfram Language code: Integrate[f[x, y], {x, y}∈ℛ]

Wolfram Language code: %//N

Properties & Relations (5)

Element can be used to test region membership for constant regions:

Wolfram Language code: ℛ = Disk[{0, 0}, 2];

Wolfram Language code: {RegionMember[ℛ, {0, 0}], {0, 0}∈ℛ}

RegionDistance is 0 for a member:

Wolfram Language code: ℛ = Disk[{0, 0}, 2];

Wolfram Language code: {RegionMember[ℛ, {0, 0}], RegionDistance[ℛ, {0, 0}]}

SignedRegionDistance is non-positive for a member:

Wolfram Language code: ℛ = Disk[{0, 0}, 1];

Wolfram Language code: {RegionMember[ℛ, {0, 0}], SignedRegionDistance[ℛ, {0, 0}]}

SignedRegionDistance is positive for a non-member:

Wolfram Language code: {RegionMember[ℛ, {-2, 0}], SignedRegionDistance[ℛ, {-2, 0}]}

Use RegionNearest to find the nearest member:

Wolfram Language code: ℛ = Disk[{0, 0}, 2];

Wolfram Language code: {RegionMember[ℛ, RegionNearest[ℛ, {3, 3}]], RegionMember[ℛ, {3, 3}]}

Visualize it:

Wolfram Language code: Graphics[{{LightBlue, ℛ}, {Green, Point[RegionNearest[ℛ, {3, 3}]]}, {Red, Point[{3, 3}]}}]

Use FindInstance to find multiple instances for special and formula regions:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 - 2y ^ 2 <= 1, {{x, -3, 3}, {y, -4, 4}}];

Wolfram Language code: Region[ℛ]

Find points that are in both regions:

Wolfram Language code: pts = FindInstance[{x, y}∈ℛ, {x, y}, 100];

Wolfram Language code: RegionPlot[ℛ, Epilog -> {Red, Point[{x, y} /. pts]}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

RegionMember

Details

Examples

Basic Examples (3)

Scope (23)

Basic Uses (4)

Special Regions (6)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

CSG Regions (1)

Subdivision Regions (1)

Applications (6)

Basic (2)

Random Points in a Region (2)

Monte Carlo Integration (2)

Properties & Relations (5)

Text

CMS

APA

BibTeX

BibLaTeX

RegionMember

Details

Examples

Basic Examples (3)

Scope (23)

Basic Uses (4)

Special Regions (6)

Formula Regions (3)

Mesh Regions (4)

Derived Regions (4)

CSG Regions (1)

Subdivision Regions (1)

Applications (6)

Basic (2)

Random Points in a Region (2)

Monte Carlo Integration (2)

Properties & Relations (5)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX