WOLFRAM

Wolfram Language & System Documentation Center

Ellipsoid[p,{r1,…}]

represents an axis-aligned ellipsoid centered at the point p and with semiaxes lengths ri.

Ellipsoid[p,Σ]

represents an ellipsoid centered at p and weight matrix Σ.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Ellipsoid

Ellipsoid[p,{r1,…}]

represents an axis-aligned ellipsoid centered at the point p and with semiaxes lengths ri.

Ellipsoid[p,Σ]

represents an ellipsoid centered at p and weight matrix Σ.

Details and Options

  • Ellipsoid is also known as center interval, ellipse, and hyperellipsoid.
  • Ellipsoid can be used as a geometric region and a graphics primitive.
  • Ellipsoid represents the axis-aligned filled ellipsoid or general ellipsoid .
  • Ellipsoid allows p to be any point in , ri any positive real numbers, and Σ any real symmetric positive definite matrix.
  • Ellipsoid can be used in Graphics and Graphics3D.
  • In graphics, the points p, pi, and radii ri can be Scaled and Dynamic expressions.
  • Graphics rendering is affected by directives such as FaceForm, Specularity, Opacity, and color.

Examples

open all close all

Basic Examples  (2)

An axis-aligned ellipsoid in 3D:

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

In 2D:

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

Measure and centroid:

Wolfram Language code: RegionMeasure[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]
Wolfram Language code: RegionCentroid[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

Scope  (20)

Graphics  (10)

Specification  (4)

An axis-aligned ellipsoid in 3D:

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

In 2D:

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

A general ellipsoid in 3D:

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {{5, 2, 3}, {2, 3, 2}, {3, 2, 5}}]]

In 2D:

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {{5, 2}, {2, 5}}]]

Styling  (4)

Balls with different specular exponents:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

Black ball that glows red:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacity specifies the face opacity:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

2D styling:

Wolfram Language code: ℛ = Ellipsoid[{0, 0}, {3, 2}];
Wolfram Language code: Graphics[{EdgeForm[{Thick, Dashed, Blue}], Brown, ℛ}]

Coordinates  (2)

Specify coordinates by fractions of the plot range:

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[Scaled[{0.5, 0.75}], {3, 2}];
Wolfram Language code: Graphics[Subscript[ℛ, 1], PlotRange -> {{0, 8}, {0, 8}}, Frame -> True]

Specify scaled offsets from the ordinary coordinates:

Wolfram Language code: Graphics[Ellipsoid[ Scaled[{0.5, 0.25}, {0, 0}], {4, 2}], Frame -> True]

Regions  (10)

Embedding dimension is the dimension of the space in which the ball lives:

Wolfram Language code: RegionEmbeddingDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

Membership testing:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {5, 5, 5}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Volume:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionDistance[ℛ, {0, 0, 0}], RegionDistance[ℛ, {0, 2, 2}]}

The distance to the nearest point for an ellipse:

Wolfram Language code: Plot3D[RegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> {x^2 + (y^2/4) == 1}]

Signed distance from a point:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {SignedRegionDistance[ℛ, {0, 2, 2}], SignedRegionDistance[ℛ, {0, 1 / 2, 0}]}

Signed distance to an ellipse:

Wolfram Language code: Plot3D[SignedRegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point in the region:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionNearest[ℛ, {3., 3, 3}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

Nearest points to an enclosing sphere:

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 4]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

An ellipsoid is bounded:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: BoundedRegionQ[ℛ]

Find its range:

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

Integrate over an ellipsoid region:

Wolfram Language code: ℛ = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

Optimize over an ellipsoid region:

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {4, 5, 6}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]//RootReduce

Solve equations in an ellipsoid region:

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {2, 3, 4}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

Applications  (4)

A spheroid is an ellipsoid with two equal axes:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {a, a, c}]

Compute its volume:

Wolfram Language code: Volume[ℛ]

Total mass for an ellipsoid region with density given by :

Wolfram Language code: ℛ = Ellipsoid[{a, b, c}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> Subscript[r, 1] > 0 && Subscript[r, 2] > 0 && Subscript[r, 3] > 0 && (a | b | c)∈Reals]

Find the mass of methanol in an Ellipsoid:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, Quantity[{4, 3, 2}, "Centimeters"]];

Density of methanol:

Wolfram Language code: d = ChemicalData["Methanol", "Density"]

Volume of ellipsoid:

Wolfram Language code: v = Volume[ℛ]

Mass of methanol in the ellipsoid:

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]

Find a bounding Ellipsoid to a region's bounding box:

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];
Wolfram Language code: bounds = RegionBounds[ℛ];

Compute the bounding box:

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

Compute a bounding ellipsoid to the bounding box:

Wolfram Language code: r = (Sqrt[3]/2) EuclideanDistance@@@bounds;
Wolfram Language code: boundingEllipsoid = Ellipsoid[RegionCentroid[boundingBox], r];

Compute the difference in Volume of the bounding solids:

Wolfram Language code: Volume[boundingEllipsoid] - Volume[boundingBox]

Visualize bounding surfaces:

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox, boundingEllipsoid}], Boxed -> False]

Properties & Relations  (4)

Disk is a special case of Ellipsoid:

Wolfram Language code: RegionMember[Disk[{0, 0}, {1, 2}], {x, y}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0}, {1, 2}], {x, y}]

Ball is a special case of Ellipsoid:

Wolfram Language code: RegionMember[Ball[{0, 0, 0}, 1], {x, y, z}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0, 0}, {1, 1, 1}], {x, y, z}]

Ellipsoid is a generalization of Ball:

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any Ellipsoid:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(Subscript[t, 1] - Subscript[c, 1])^2 + (1/4) (Subscript[t, 2] - Subscript[c, 2])^2 + (1/9) (Subscript[t, 3] - Subscript[c, 3])^2 + (1/16) (Subscript[t, 4] - Subscript[c, 4])^2 ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}]; Subscript[ℛ, 2] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 2, 3, 4}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Neat Examples  (2)

Random ellipsoid collections:

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Ellipsoid[RandomReal[50, {3}], RandomReal[{1, 5}, 3]]}, {100}]]

Sweep an ellipsoid around an axis:

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {1, -2, 3}, {5, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 16}]}]
Wolfram Research (2014), Ellipsoid, Wolfram Language function, https://reference.wolfram.com/language/ref/Ellipsoid.html.

Text

Wolfram Research (2014), Ellipsoid, Wolfram Language function, https://reference.wolfram.com/language/ref/Ellipsoid.html.

CMS

Wolfram Language. 2014. "Ellipsoid." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Ellipsoid.html.

APA

Wolfram Language. (2014). Ellipsoid. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ellipsoid.html

BibTeX

@misc{reference.wolfram_2026_ellipsoid, author="Wolfram Research", title="{Ellipsoid}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Ellipsoid.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipsoid, organization={Wolfram Research}, title={Ellipsoid}, year={2014}, url={https://reference.wolfram.com/language/ref/Ellipsoid.html}, note=[Accessed: 12-June-2026]}