WOLFRAM

Wolfram Language & System Documentation Center

ImplicitRegion[cond,{x1,…,xn}]

represents a region in that satisfies the conditions cond.

ImplicitRegion[cond,{{x1,a1,b1},…}]

represents a region in that satisfies the conditions cond as well as etc.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Regions in 1D  
Regions in 2D  
Regions in 3D  
Regions in D  
Properties  
Applications  
See Also
Related Guides
History
Cite this Page

ImplicitRegion

ImplicitRegion[cond,{x1,…,xn}]

represents a region in that satisfies the conditions cond.

ImplicitRegion[cond,{{x1,a1,b1},…}]

represents a region in that satisfies the conditions cond as well as etc.

Details

Examples

open all close all

Basic Examples  (1)

Specify a disk as an ImplicitRegion:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];
Wolfram Language code: Region[ℛ]

A circle:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 == 1, {x, y}];
Wolfram Language code: Region[ℛ]

Scope  (27)

Regions in 1D  (3)

A 0D region is a set of discrete points:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 3 - x == 0, {x}]

Find the points:

Wolfram Language code: Reduce[Element[{x}, ℛ], x]

A purely 1D region is a union of (possibly unbounded) segments:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 3 - x ≥ 0, {x}]

Find the segments:

Wolfram Language code: Reduce[Element[{x}, ℛ], x]

A region with 1D and 0D components:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2(x ^ 2 - 1)(x ^ 2 - 2) ≤ 0, {x}]

Find the components:

Wolfram Language code: Reduce[Element[{x}, ℛ], x]

Compute the length:

Wolfram Language code: ArcLength[ℛ]

Regions in 2D  (5)

A 0D region is a set of discrete points:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 + y ^ 2 == 1 && x ^ 2 == y ^ 2, {x, y}]

Find the points:

Wolfram Language code: Reduce[Element[{x, y}, ℛ], {x, y}]//LogicalExpand

A purely 1D region is a curve:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 + y ^ 2 == 1, {x, y}]

Plot it:

Wolfram Language code: RegionPlot[ℛ]

A higher-degree algebraic curve:

Wolfram Language code: ℛ = ImplicitRegion[x^6 - 5 x^4 y + 3 x^4 y^2 + 10 x^2 y^3 + 3 x^2 y^4 - y^5 + y^6 == 0, {x, y}];

Plot it:

Wolfram Language code: RegionPlot[ℛ]

A 2D region with two connected components:

Wolfram Language code: ℛ = ImplicitRegion[y^2 < x (-1 + x^4), {x, y}];

Plot it:

Wolfram Language code: RegionPlot[ℛ, PlotRange -> {{-2, 2}, {-2, 2}}]

A 2D region with lower-dimensional components:

Wolfram Language code: ℛ = ImplicitRegion[(((x^2 - 2 y == 0 && -3 ≤ x ≤ 3) || (x^2 + y^2 ≤ 16 && (16 x^2/49) + (1/4) (1 + y)^2 > 1) || x^2 + ((1/2) + y)^2 ≤ 4) && ((3/2) + x)^2 + (-1 + y)^2 > (9/16) && (-(3/2) + x)^2 + (-1 + y)^2 > (9/16)) || ((7/5) + x)^2 + (-(11/10) + y)^2 ≤ (1/16) || (-(8/5) + x)^2 + (-(11/10) + y)^2 ≤ (1/16) || ((46/15) + x)^2 + (-(1058/225) + y)^2 == (9181/202500) || (-(46/15) + x)^2 + (-(1058/225) + y)^2 == (9181/202500), {x, y}];

Plot it:

Wolfram Language code: DiscretizeRegion[ℛ, {{-5, 5}, {-5, 5}}]

Regions in 3D  (7)

A 0D region is a set of discrete points:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 == 1 && x ^ 2 == y z && x + y + z == 1, {x, y, z}]

Find the points:

Wolfram Language code: Reduce[Element[{x, y, z}, ℛ], {x, y, z}]

A purely 1D region is a curve; conic curves are intersections of a cone and a plane:

Wolfram Language code: cone = ContourPlot3D[x^2 + y^2 == z^2, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, Mesh -> None, ContourStyle -> Opacity[0.3]];

An ellipse:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 == z^2 && x + y == 2 z - 1, {x, y, z}];
Wolfram Language code: Show[{cone, DiscretizeRegion[ℛ, {{-3, 3}, {-3, 3}, {-3, 3}}]}]

A parabola:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 == z^2 && x + y == Sqrt[2] z - 1, {x, y, z}];
Wolfram Language code: Show[{cone, DiscretizeRegion[ℛ, {{-3, 3}, {-3, 3}, {-3, 3}}]}]

A hyperbola:

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 == z^2 && x + y == (z/2) - 1, {x, y, z}];
Wolfram Language code: Show[{cone, DiscretizeRegion[ℛ, {{-3, 3}, {-3, 3}, {-3, 3}}]}]

A higher-degree algebraic curve:

Wolfram Language code: ℛ = ImplicitRegion[5 y - 20 y^3 + 16 y^5 - z == 0 && x^2 + y^2 == 1, {x, y, z}];

Plot it:

Wolfram Language code: DiscretizeRegion[ℛ]

The curve is an intersection of two surfaces:

Wolfram Language code: Show[{ContourPlot3D[5 y - 20 y^3 + 16 y^5 - z == 0, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Mesh -> None], Graphics3D[{Green, Opacity[0.5], Cylinder[{{0, 0, -1}, {0, 0, 1}}]}], %}]

A purely 2D region is a surface:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, y, z}];

Plot it:

Wolfram Language code: DiscretizeRegion[ℛ]

A higher-degree algebraic surface:

Wolfram Language code: ℛ = ImplicitRegion[-4 y^2 - 4 x y^2 + y^4 + 4 x z^2 + 4 x^2 z^2 + 2 y^2 z^2 + z^4 == 0, {x, y, z}];

Plot it:

Wolfram Language code: DiscretizeRegion[ℛ]

A purely 3D region is a solid:

Wolfram Language code: ℛ = ImplicitRegion[4 ≤ x^2 + y^2 + z^2 ≤ 9, {x, y, z}];

Plot it:

Wolfram Language code: RegionPlot3D[ℛ, PlotStyle -> Opacity[0.5], PlotPoints -> 50]

A higher-degree algebraic solid:

Wolfram Language code: ℛ = ImplicitRegion[x^6 - 5 x^4 y + 3 x^4 y^2 + 10 x^2 y^3 + 3 x^2 y^4 - y^5 + y^6 + z^2 ≤ 1, {x, y, z}];

Plot it:

Wolfram Language code: RegionPlot3D[ℛ, PlotRange -> {{-1.2, 1.2}, {-1.2, 1.2}, {-1.2, 1.2}}, PlotPoints -> 50]

Regions in D  (2)

A ball in :

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];

Intersect with a 3D affine space and project on :

Wolfram Language code: 𝒮 = ImplicitRegion[x + y + z + u + v == 1 && x - y == u - v, {x, y, z, u, v}];
Wolfram Language code: Resolve[Subscript[∃, {u, v}]{x, y, z, u, v}∈RegionIntersection[ℛ, 𝒮], Reals]

Plot it:

Wolfram Language code: RegionPlot3D[Evaluate[%], {x, -1, 1}, {y, -1, 1}, {z, -1, 1}]

A torus embedded in :

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 == 1 && z^2 + t^2 == 1, {x, y, z, t}];

Compute the area of the torus:

Wolfram Language code: Area[ℛ]

Embed the torus in using the mapping :

Wolfram Language code: Resolve[Subscript[∃, {x, y, z, t}, {x, y, z, t}∈ℛ](u == x + (x z/2) && v == y + (y z/2) && w == (t/2)), Reals]

Plot it:

Wolfram Language code: ContourPlot3D[Evaluate[%], {u, -1.5, 1.5}, {v, -1.5, 1.5}, {w, -1.5, 1.5}]

Properties  (10)

Implicitly described region:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 4 + y ^ 4 ≤ 1, {x, y}]

Plot it:

Wolfram Language code: RegionPlot[ℛ]

Embedding dimension:

Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension:

Wolfram Language code: RegionDimension[ℛ]

Point membership test:

Wolfram Language code: ℛ = ImplicitRegion[x y ≤ 1, {x, y}];
Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {2, 2}]}

Plot it:

Wolfram Language code: Show[{RegionPlot[ℛ, PlotRange -> {{-2.5, 2.5}, {-2.5, 2.5}}], Graphics[{{Green, Point[{1, 1}]}, {Red, Point[{2, 2}]}}]}]

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area and centroid:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 2 + x y + y ^ 2 ≤ 1, {x, y}];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Plot it:

Wolfram Language code: Show[{RegionPlot[ℛ], Graphics[{Red, Point[%]}]}]

Distance from a point:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 4 + y ^ 4 ≤ 1, {x, y}]; p1 = {1, 1};p2 = {1 / 2, 1 / 2};
Wolfram Language code: d1 = RegionDistance[ℛ, p1]//Simplify
Wolfram Language code: d2 = RegionDistance[ℛ, p2]

Plot it:

Wolfram Language code: Show[{RegionPlot[ℛ], Graphics[{{Blue, Point[p1]}, {Green, Circle[p1, d1]}, {Red, Point[p2]}}]}, PlotRange -> All]

Signed distance from a point:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 4 + y ^ 4 ≤ 1, {x, y}]; p1 = {1, 1};p2 = {1 / 2, 1 / 2};
Wolfram Language code: d1 = SignedRegionDistance[ℛ, p1]//RootReduce
Wolfram Language code: d2 = SignedRegionDistance[ℛ, p2]//RootReduce

Plot it:

Wolfram Language code: Show[{RegionPlot[ℛ], Graphics[{{Blue, Point[p1]}, {Red, Point[p2]}, {Green, Circle[p1, d1], Circle[p2, -d2]}}]}, PlotRange -> All]

Nearest point in the region:

Wolfram Language code: ℛ = ImplicitRegion[(x ^ 3 - 3 x y ^ 2) + (x ^ 2 + y ^ 2) ^ 2 ≤ 0, {x, y}]; p1 = {0, 1};p2 = {-1, 0};
Wolfram Language code: q1 = RegionNearest[ℛ, p1]//RootReduce
Wolfram Language code: N[q1]
Wolfram Language code: q2 = RegionNearest[ℛ, p2]

Plot it:

Wolfram Language code: Show[{RegionPlot[ℛ], Graphics[{{Green, Point[{p1, q1}]}, {Dashed, Line[{p1, q1}]}, {Red, Point[p2]}}]}, PlotRange -> All]

Nearest points:

Wolfram Language code: pts = Table[2{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Show[{RegionPlot[ℛ], Graphics[{{Dashed, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}]}, PlotRange -> All]

A trifolium is bounded:

Wolfram Language code: ℛ = ImplicitRegion[(x ^ 3 - 3 x y ^ 2) + (x ^ 2 + y ^ 2) ^ 2 ≤ 0, {x, y}];
Wolfram Language code: BoundedRegionQ[ℛ]
Wolfram Language code: RegionBounds[ℛ]

Plot it:

Wolfram Language code: Show[{Graphics[{LightGreen, Rectangle@@Transpose[%]}], RegionPlot[ℛ]}]

Integrate over an implicitly defined region:

Wolfram Language code: ℛ = ImplicitRegion[0 ≤ x ≤ 2 && 0 ≤ y ≤ 2 && x y ≤ 1, {x, y}];
Wolfram Language code: Integrate[x + y, {x, y}∈ℛ]

Optimize over an implicitly defined region:

Wolfram Language code: ℛ = ImplicitRegion[0 ≤ x ≤ 2 && 0 ≤ y ≤ 2 && x y ≤ 1, {x, y}];
Wolfram Language code: MinValue[{x y - x, {x, y}∈ℛ}, {x, y}]

Solve equations in an implicitly defined region:

Wolfram Language code: ℛ = ImplicitRegion[x ^ 3 + y ^ 3 == 1, {x, y}];
Wolfram Language code: Reduce[x^2 - y^2 == 1 / 2 && {x, y}∈ℛ, {x, y}]

Applications  (1)

Find the projection of an implicit region on the plane in :

Wolfram Language code: ℛ = ImplicitRegion[x^6 - 5 x^4 y z + 3 x^4 y^2 + 10 x^2 y^3 z + 3 x^2 y^4 - y^5 z + y^6 + z^6 ≤ 1, {x, y, z}];

Visualize the region:

Wolfram Language code: RegionPlot3D[ℛ, PlotRange -> {{-1.5, 1.5}, {-1.5, 1.5}, {-1.6, 1.6}}, PlotPoints -> 50]
Wolfram Language code: prj = Resolve[Subscript[∃, z]{x, y, z}∈ℛ, Reals];

Visualize the projection:

Wolfram Language code: RegionPlot[prj, {x, -1.5, 1.5}, {y, -1.5, 1.5}]
Wolfram Research (2014), ImplicitRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/ImplicitRegion.html.

Text

Wolfram Research (2014), ImplicitRegion, Wolfram Language function, https://reference.wolfram.com/language/ref/ImplicitRegion.html.

CMS

Wolfram Language. 2014. "ImplicitRegion." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ImplicitRegion.html.

APA

Wolfram Language. (2014). ImplicitRegion. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImplicitRegion.html

BibTeX

@misc{reference.wolfram_2026_implicitregion, author="Wolfram Research", title="{ImplicitRegion}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ImplicitRegion.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_implicitregion, organization={Wolfram Research}, title={ImplicitRegion}, year={2014}, url={https://reference.wolfram.com/language/ref/ImplicitRegion.html}, note=[Accessed: 13-June-2026]}