WOLFRAM

Wolfram Language & System Documentation Center

EllipticThetaPrime[a,u,q]

gives the derivative with respect to u of the theta function TemplateBox[{a, u, q}, EllipticTheta] .

EllipticThetaPrime[a,q]

gives the theta constant TemplateBox[{a, 0, q}, EllipticThetaPrime].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Integration  
Generalizations & Extensions  
Applications  
Possible Issues  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

EllipticThetaPrime

EllipticThetaPrime[a,u,q]

gives the derivative with respect to u of the theta function TemplateBox[{a, u, q}, EllipticTheta] .

EllipticThetaPrime[a,q]

gives the theta constant TemplateBox[{a, 0, q}, EllipticThetaPrime].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For certain special arguments, EllipticThetaPrime automatically evaluates to exact values.
  • EllipticThetaPrime can be evaluated to arbitrary numerical precision.
  • EllipticThetaPrime automatically threads over lists.

Examples

open all close all

Basic Examples  (3)

Evaluate numerically:

Wolfram Language code: EllipticThetaPrime[2, 2.3, 1 / 3]

Plot over a subset of the reals:

Wolfram Language code: Plot[EllipticThetaPrime[2, x, 1 / 3], {x, -6, 6}]

Series expansion at the origin with respect to q:

Wolfram Language code: Series[EllipticThetaPrime[1, x, q], {q, 0, 10}]

Scope  (21)

Numerical Evaluation  (4)

Evaluate numerically:

Wolfram Language code: EllipticThetaPrime[2, 5, .5]
Wolfram Language code: EllipticThetaPrime[1, .4, .5]

Evaluate to high precision:

Wolfram Language code: N[EllipticThetaPrime[3, 15, 1 / 3], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: EllipticThetaPrime[3, 8, .600055555555000055005]

Complex number inputs:

Wolfram Language code: EllipticThetaPrime[2, .4 + I, .5I]

Evaluate efficiently at high precision:

Wolfram Language code: EllipticThetaPrime[2, 5, .5`100]//Timing
Wolfram Language code: EllipticThetaPrime[2, 5, .5`10000];//Timing

Specific Values  (3)

Value at zero:

Wolfram Language code: EllipticThetaPrime[1, 0, 0]

EllipticThetaPrime evaluates symbolically for special arguments:

Wolfram Language code: Table[EllipticThetaPrime[j, z, 0], {j, 4}]

Find a value of for which EllipticThetaPrime[3,x,1/2]=2:

Wolfram Language code: xval = x /. FindRoot[EllipticThetaPrime[3, x, 1 / 2] == 2, {x, 1}]//Quiet
Wolfram Language code: Plot[EllipticThetaPrime[3, x, 1 / 2], {x, -1, 4}, Epilog -> Style[Point[{xval, EllipticThetaPrime[3, xval, 1 / 2]}], PointSize[Large], Red]]

Visualization  (2)

Plot the EllipticThetaPrime function for various parameters:

Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], EllipticThetaPrime[2, x, 1 / 2], EllipticThetaPrime[3, x, 1 / 2], EllipticThetaPrime[4, x, 1 / 2]}, {x, -5, 5}]

Plot the real part of TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime]:

Wolfram Language code: ComplexContourPlot[Re[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{4, z, {1, /, 3}}, EllipticThetaPrime]:

Wolfram Language code: ComplexContourPlot[Im[EllipticThetaPrime[4, z, 1 / 3]], {z, -3 - 3I, 3 + 3 I}, Contours -> 24]

Function Properties  (10)

Real and complex domains of EllipticThetaPrime:

Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, x, q], {x, q}], {a, 4}]
Wolfram Language code: Table[FunctionDomain[EllipticThetaPrime[a, z, q], {z, q}, Complexes], {a, 4}]

EllipticThetaPrime is a periodic function with respect to :

Wolfram Language code: Table[FunctionPeriod[EllipticThetaPrime[a, z, q], z], {a, 4}]

EllipticThetaPrime threads elementwise over lists:

Wolfram Language code: EllipticThetaPrime[{1, 2, 3, 4}, z, q]
Wolfram Language code: EllipticThetaPrime[2, {Pi / 2, Pi}, 1 / 2]

TemplateBox[{1, x, q}, EllipticThetaPrime] is an analytic function of x:

Wolfram Language code: FunctionAnalytic[EllipticThetaPrime[1, x, q], x, Assumptions -> 0 < q < 1]

For example, TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] is not injective:

Wolfram Language code: FunctionInjective[EllipticThetaPrime[1, x, 1 / 2], x]
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], 1}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] is not surjective:

Wolfram Language code: FunctionSurjective[EllipticThetaPrime[1, x, 1 / 2], x]//Quiet
Wolfram Language code: Plot[{EllipticThetaPrime[1, x, 1 / 2], -5}, {x, -6, 6}]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[EllipticThetaPrime[1, x, 1 / 2], x]

TemplateBox[{1, x, {1, /, 2}}, EllipticThetaPrime] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[EllipticThetaPrime[1, x, 1 / 2], x]

TraditionalForm formatting:

Wolfram Language code: EllipticThetaPrime[3, z, q] // TraditionalForm
Wolfram Language code: EllipticThetaPrime[a, q] // TraditionalForm

Integration  (2)

Compute the indefinite integral using Integrate:

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], u]

Verify the anti-derivative:

Wolfram Language code: FullSimplify[D[%, u]]

Definite integral:

Wolfram Language code: Integrate[EllipticThetaPrime[a, u, q], {u, 0, 5}]

Generalizations & Extensions  (1)

EllipticThetaPrime can be applied to power series:

Wolfram Language code: EllipticThetaPrime[2, z, Log[1 + q] + O[q]^4]

Applications  (4)

Verify Jacobi's triple product identity through a series expansion:

Wolfram Language code: Series[EllipticThetaPrime[1, q] - EllipticTheta[2, q]EllipticTheta[3, q]EllipticTheta[4, q], {q, 0, 9}]

Green's function for the 1D heat equation with Dirichlet boundary conditions and initial condition :

Wolfram Language code: T[{x_, t_}, x0_, L_] := (1/2L) (EllipticTheta[3, (π/2L) (x - x0), E^-((π/L))^2t] - EllipticTheta[3, (π/2L)(x + x0), E^-((π/L))^2t])

Calculate the temperature gradient:

Wolfram Language code: gradT[{x_, t_}, x0_, L_] = D[T[{x, t}, x0, L], x]

Plot the temperature gradient:

Wolfram Language code: Plot3D[gradT[{x, t}, 0.6, 1], {x, 0, 1}, {t, 0.01, 0.1}, PlotRange -> All]

Electrostatic force in a NaCl‐like crystal with point‐like ions:

Wolfram Language code: fNaCl[{x_, y_, z_}] := (16/π)NIntegrate[{2 π t EllipticTheta[2, 2 π y, E^-t^2] EllipticTheta[2, 2 π z, E^-t^2]EllipticThetaPrime[2, 2 π x, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2]EllipticTheta[2, 2 π z, E^-t^2] EllipticThetaPrime[2, 2 π y, E^-t^2], 2 π t EllipticTheta[2, 2 π x, E^-t^2] EllipticTheta[2, 2 π y, E^-t^2]EllipticThetaPrime[2, 2 π z, E^-t^2]}, {t, 0, ∞}, PrecisionGoal -> 5]

Plot the magnitude of the force in a plane through the crystal:

Wolfram Language code: ListPlot3D[Table[Norm[fNaCl[{x, y, 0.3}]], {x, 0, 1, 1 / 10}, {y, 0, 1, 1 / 10}]]//Quiet

The canonical rotational distribution function for linear molecules :

Wolfram Language code: Ω[β_] := (1/2) - Subsuperscript[∫, 0, ∞](1/8 Sqrt[π] t^3 / 2)E^-t (-4 t EllipticTheta[3, 0, E^-(β (4 t + β)/4 t)] + β EllipticThetaPrime^(0, 1, 0)[3, 0, E^-(β (4 t + β)/4 t)])ⅆt

Plot a numerical approximation of the partition function:

Wolfram Language code: ListLinePlot[Table[Ω[β] /. Integrate[a_, {t, b_, c_}] :> NIntegrate[a, {t, 10 ^ -3, 10}], {β, 1 / 4, 3, 1 / 4}]]

Possible Issues  (4)

Machine-precision input is insufficient to give a correct answer:

Wolfram Language code: EllipticThetaPrime[1, 10. ^ 30, 1 / Pi]

Use arbitrary-precision arithmetic to obtain the correct result:

Wolfram Language code: N[EllipticThetaPrime[1, 10 ^ 30, 1 / Pi], 20]

The first argument must be an explicit integer between 1 and 4:

Wolfram Language code: EllipticThetaPrime[1 + (E + 1) ^ 2 - E ^ 2 - 2E - 1, 3., 1 / 2]
Wolfram Language code: Simplify[%]

EllipticThetaPrime has the attribute NHoldFirst:

Wolfram Language code: Attributes[EllipticThetaPrime]

Different argument conventions exist for theta functions:

Wolfram Language code: {Plot[EllipticThetaPrime[1, z, 1 / 2], {z, 0, 2π}], Plot[EllipticThetaPrime[1, (z/2π), 1 / 2], {z, 0, 2π}]}
Wolfram Language code: {Plot[EllipticThetaPrime[1, 2, q], {q, 0.1, 0.8}], Plot[EllipticThetaPrime[1, 2, Exp[I π (I τ)]], {τ, 0.1, 0.8}]}

Neat Examples  (1)

Visualize a function with a boundary of analyticity:

Wolfram Language code: Module[{f, R = 0.99}, f[z_ ? NumberQ] := If[Abs[z] > R, 0, Sin[Arg[EllipticThetaPrime[2, 1, z]] / 2]^2]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, R], Frame -> False, PlotPoints -> 90, ColorFunction -> (Hue[2.72 #]&)]]
Wolfram Research (1996), EllipticThetaPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticThetaPrime.html (updated 2017).

Text

Wolfram Research (1996), EllipticThetaPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/EllipticThetaPrime.html (updated 2017).

CMS

Wolfram Language. 1996. "EllipticThetaPrime." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2017. https://reference.wolfram.com/language/ref/EllipticThetaPrime.html.

APA

Wolfram Language. (1996). EllipticThetaPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticThetaPrime.html

BibTeX

@misc{reference.wolfram_2026_ellipticthetaprime, author="Wolfram Research", title="{EllipticThetaPrime}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticthetaprime, organization={Wolfram Research}, title={EllipticThetaPrime}, year={2017}, url={https://reference.wolfram.com/language/ref/EllipticThetaPrime.html}, note=[Accessed: 12-June-2026]}