WOLFRAM

Wolfram Language & System Documentation Center

QPochhammer[a,q,n]

gives the -Pochhammer symbol TemplateBox[{a, q, n}, QPochhammer].

QPochhammer[a,q]

gives the -Pochhammer symbol TemplateBox[{a, q}, QPochhammer2].

QPochhammer[q]

gives the -Pochhammer symbol TemplateBox[{q}, QPochhammer1].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Series Expansions  
Applications  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

QPochhammer

QPochhammer[a,q,n]

gives the -Pochhammer symbol TemplateBox[{a, q, n}, QPochhammer].

QPochhammer[a,q]

gives the -Pochhammer symbol TemplateBox[{a, q}, QPochhammer2].

QPochhammer[q]

gives the -Pochhammer symbol TemplateBox[{q}, QPochhammer1].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{a, q}, QPochhammer2]=product_(k=0)^infty(1-a q^k).
  • TemplateBox[{a, q, n}, QPochhammer]=TemplateBox[{a, q}, QPochhammer2]/TemplateBox[{{a, , {q, ^, n}}, q}, QPochhammer2].
  • QPochhammer automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: QPochhammer[-1.2, .2, 5]

Plot over a subset of the reals:

Wolfram Language code: Plot[QPochhammer[q], {q, -1, 1}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[QPochhammer[z ^ 2, 1 / 2], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[QPochhammer[x], {x, 0, 7}]

Scope  (22)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: QPochhammer[3, 5, 9]
Wolfram Language code: QPochhammer[.4, .2]

Evaluate to high precision:

Wolfram Language code: N[QPochhammer[2 / 7, 1 / 9, 1 / 3], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: QPochhammer[1 / 3, 1 / 9, 1.1111111111111]

Complex number inputs:

Wolfram Language code: QPochhammer[.3 + I, .5 - I, 9]

Evaluate efficiently at high precision:

Wolfram Language code: QPochhammer[1 / 4, 1 / 5`100]//Timing
Wolfram Language code: QPochhammer[1 / 3, 1 / 5`30000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: QPochhammer[ 2, Around[.2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: QPochhammer[3, {{-1, 0}, {0, 5}}, 5]

Or compute the matrix QPochhammer function using MatrixFunction:

Wolfram Language code: MatrixFunction[QPochhammer[3, #, 5]&, {{-1, 0}, {0, 5}}]

Specific Values  (4)

Values of QPochhammer at fixed points:

Wolfram Language code: Table[QPochhammer[x], {x, {0, 1}}]

QPochhammer for symbolic parameters:

Wolfram Language code: QPochhammer[a, 2, 1]//FunctionExpand
Wolfram Language code: QPochhammer[2, q, 5]//FunctionExpand

Finite products evaluate for all Gaussian rational numbers:

Wolfram Language code: QPochhammer[(1 + I/2), (1 - I/2), 10]

Find the maximum of QPochhammer[x]:

Wolfram Language code: xmax = x /. FindRoot[D[QPochhammer[x], x] == 0, {x, -0.2}]//Chop
Wolfram Language code: Plot[QPochhammer[x], {x, -1, 1}, Epilog -> Style[Point[{xmax, QPochhammer[xmax]}], PointSize[Large], Red]]

Visualization  (2)

Plot the QPochhammer function:

Wolfram Language code: Plot[QPochhammer[x], {x, -1, 1}]
Wolfram Language code: Plot[QPochhammer[x, 1 / 2], {x, -2, 2}]

Plot the real part of TemplateBox[{z, {1, /, 2}}, QPochhammer2]:

Wolfram Language code: ComplexContourPlot[Re[QPochhammer[z, 1 / 2]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{z, {1, /, 2}}, QPochhammer2]:

Wolfram Language code: ComplexContourPlot[Im[QPochhammer[z, 1 / 2]], {z, -4 - 4I, 4 + 4I}, Contours -> 20]

Function Properties  (9)

The real domain of TemplateBox[{x}, QPochhammer1]:

Wolfram Language code: FunctionDomain[QPochhammer[x], x]

Approximate function range of TemplateBox[{x}, QPochhammer1]:

Wolfram Language code: FunctionRange[QPochhammer[x], x, y]//Quiet

TemplateBox[{x}, QPochhammer1] is not an analytic function:

Wolfram Language code: FunctionAnalytic[QPochhammer[x], x]

Has both singularities and discontinuities for x≤-1 or for x≥1:

Wolfram Language code: FunctionSingularities[QPochhammer[x], x]
Wolfram Language code: FunctionDiscontinuities[QPochhammer[x], x]

TemplateBox[{x}, QPochhammer1] is neither nonincreasing nor nondecreasing:

Wolfram Language code: FunctionMonotonicity[QPochhammer[x], x]

QPochhammer is not injective:

Wolfram Language code: FunctionInjective[QPochhammer[x], x]
Wolfram Language code: Plot[{QPochhammer[x], .5}, {x, -1, 1}]

QPochhammer is not surjective:

Wolfram Language code: FunctionSurjective[QPochhammer[x], x]
Wolfram Language code: Plot[{QPochhammer[x], -1}, {x, -1, 1}]

QPochhammer is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[QPochhammer[x], x]

QPochhammer is neither convex nor concave:

Wolfram Language code: FunctionConvexity[QPochhammer[x], x]

TraditionalForm formatting:

Wolfram Language code: QPochhammer[a, q]//TraditionalForm
Wolfram Language code: QPochhammer[a, q, n]//TraditionalForm

Series Expansions  (1)

Find the Taylor expansion using Series:

Wolfram Language code: Series[QPochhammer[n, q, x], {q, 0, 3}]//Normal

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[QPochhammer[2, q, 1 / 3], {q, 0, m}], {m, 1, 3}]; Plot[{QPochhammer[2, q, 1 / 3], terms}, {q, 0, 1 / 20}]

Applications  (11)

-series are building blocks of other -factorial functions:

Wolfram Language code: FunctionExpand[QGamma[n, q]]
Wolfram Language code: QHypergeometricPFQ[{}, {}, q, z]

The -binomial theorem:

Wolfram Language code: QHypergeometricPFQ[{a}, {}, q, z]

Rogers–Ramanujan identities:

Wolfram Language code: QHypergeometricPFQ[{}, {0}, q, q]
Wolfram Language code: QHypergeometricPFQ[{}, {0}, q, q^2]

Build -analogs of sine and cosine:

Wolfram Language code: cosq[u_, q_] := (QPochhammer[-I u, q] + QPochhammer[I u, q]) / 2
Wolfram Language code: sinq[u_, q_] := -I(QPochhammer[-I u, q] - QPochhammer[I u, q]) / 2
Wolfram Language code: Cosq[u_, q_] := (1 / QPochhammer[-I u, q] + 1 / QPochhammer[I u, q]) / 2
Wolfram Language code: Sinq[u_, q_] := I(1 / QPochhammer[-I u, q] - 1 / QPochhammer[I u, q]) / 2

Verify some analogs of the usual trigonometric identities:

Wolfram Language code: sinq[u, q]Sinq[u, q] + cosq[u, q]Cosq[u, q]//FullSimplify
Wolfram Language code: sinq[u, q]Cosq[u, q] - cosq[u, q]Sinq[u, q]//FullSimplify

Plot the functions:

Wolfram Language code: Plot[{sinq[u, 1 / 2], cosq[u, 1 / 2]}, {u, 0, π}, PlotRange -> All]
Wolfram Language code: Plot[{Sinq[u, 1 / 2], Cosq[u, 1 / 2]}, {u, 0, 2π}, PlotRange -> All]

-analog of :

Wolfram Language code: qPower[x_, a_, n_, q_] := x^n QPochhammer[(a/x), q, n]
Wolfram Language code: qPower[x, a, 3, q]//FunctionExpand//Factor

-analog of :

Wolfram Language code: Dq[f_, x_] := (f /. x -> x q) - f
Wolfram Language code: (Dq[qPower[x, a, n, q], x]/Dq[x, x]) == (1 - q^n/1 - q)qPower[x, a, n - 1, q] /. n -> 5//FullSimplify

Demonstrate the pentagonal number theorem:

Wolfram Language code: Series[QPochhammer[q], {q, 0, 27}]
Wolfram Language code: Sum[(-1)^kq^PolygonalNumber[5, k], {k, -4, 4}]

An alternative formulation in terms of a Dirichlet character modulo 12:

Wolfram Language code: Sum[DirichletCharacter[12, 4, k]q^(k^2 - 1/24), {k, 1, 25}]

Generate partition numbers:

Wolfram Language code: Series[(1/QPochhammer[q]), {q, 0, 10}]
Wolfram Language code: Sum[PartitionsP[n]q^n, {n, 0, 10}]
Wolfram Language code: Series[(1/QPochhammer[q, q^2]), {q, 0, 10}]
Wolfram Language code: Sum[PartitionsQ[n]q^n, {n, 0, 10}]

Verify Jacobi's triple product identity through series expansion:

Wolfram Language code: QPochhammer[q^2]QPochhammer[-q z, q^2]QPochhammer[-q / z, q^2]
Wolfram Language code: Series[% - Sum[z^nq^n^2, {n, -10, 10}], {q, 0, 100}]

Find RamanujanTau from its generating function, the modular discriminant:

Wolfram Language code: q QPochhammer[q] ^ 24 + O[q] ^ 20
Wolfram Language code: Sum[RamanujanTau[n]q ^ n, {n, 20}] + O[q] ^ 21

Define a function for computing the conjugate of an integer partition:

Wolfram Language code: conjugatePartition[p_] := Total[UnitStep[Outer[Plus, p, -Range[First[p]]]]]

Count the number of integer partitions of that are self-conjugate:

Wolfram Language code: n = 23; Count[IntegerPartitions[n], p_ /; p === conjugatePartition[p]]

Compute the same result from the generating function:

Wolfram Language code: SeriesCoefficient[QPochhammer[-q, q^2], {q, 0, n}]

The probability that the determinant of a random uniform matrix in a finite field of characteristic is zero:

Wolfram Language code: ZeroDetProbability[n_, p_] = 1 - Product[1 - p^k - n, {k, 0, n - 1}]

Compute the probability for a matrix in a field of characteristic 2:

Wolfram Language code: ZeroDetProbability[5, 2]//N

Compare with a simulation:

Wolfram Language code: randomdet[n_, p_] := Mod[Det[RandomInteger[{0, p - 1}, {n, n}]], p]
Wolfram Language code: With[{n = 1*^5}, Length[Table[If[randomdet[5, 2] == 0, 1, Nothing], {n}]] / n]//N

Neat Examples  (4)

Hirschhorn's modular identity (TemplateBox[{q, q}, QPochhammer2])^5=TemplateBox[{{q, ^, 5}, {q, ^, 5}}, QPochhammer2] mod 5:

Wolfram Language code: Series[QPochhammer[q] ^ 5 - QPochhammer[q ^ 5], {q, 0, 20}]
Wolfram Language code: Collect[%, q, Mod[#, 5]&]

The boundary of the unit disk contains a dense subset of essential singularities of TemplateBox[{q}, QPochhammer1]:

Wolfram Language code: With[{b = 0.99}, ContourPlot[Abs[QPochhammer[x + I y]], {x, y}∈Disk[{0, 0}, b]]]

Expand the Rogers–Ramanujan continued fraction into a series:

Wolfram Language code: Series[q^1 / 5ContinuedFractionK[q^k, 1, {k, 0, 4}], {q, 0, 12}]

Compare with the closed form in terms of QPochhammer:

Wolfram Language code: Series[q^1 / 5 (QPochhammer[q, q^5] QPochhammer[q^4, q^5]/QPochhammer[q^2, q^5] QPochhammer[q^3, q^5]), {q, 0, 12}]

Visualize the Rogers–Ramanujan continued fraction over the unit disk:

Wolfram Language code: Module[{f, r = 0.995}, f[q_ ? NumberQ] := If[Abs[q] > r, 0, Arg[q^1 / 5 (QPochhammer[q, q^5] QPochhammer[q^4, q^5]/QPochhammer[q^2, q^5] QPochhammer[q^3, q^5])]]; DensityPlot[f[qx + I qy], {qx, qy}∈Disk[{0, 0}, r], IconizedObject[«plot options»]]]

Visualize a partial sum of the "strange function" of Kontsevich and Zagier in the complex plane:

Wolfram Language code: ComplexPlot[Underoverscript[∑, k = 0, 19]QPochhammer[q, q, k], {q, -2 - 2I, 2 + 2I}]
Wolfram Research (2008), QPochhammer, Wolfram Language function, https://reference.wolfram.com/language/ref/QPochhammer.html.

Text

Wolfram Research (2008), QPochhammer, Wolfram Language function, https://reference.wolfram.com/language/ref/QPochhammer.html.

CMS

Wolfram Language. 2008. "QPochhammer." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/QPochhammer.html.

APA

Wolfram Language. (2008). QPochhammer. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QPochhammer.html

BibTeX

@misc{reference.wolfram_2026_qpochhammer, author="Wolfram Research", title="{QPochhammer}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/QPochhammer.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_qpochhammer, organization={Wolfram Research}, title={QPochhammer}, year={2008}, url={https://reference.wolfram.com/language/ref/QPochhammer.html}, note=[Accessed: 13-June-2026]}