WOLFRAM

Wolfram Language & System Documentation Center

FactorSquareFreeList[poly]

gives a list of square‐free factors of a polynomial, together with their exponents.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Extension  
Modulus  
Trig  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

FactorSquareFreeList

FactorSquareFreeList[poly]

gives a list of square‐free factors of a polynomial, together with their exponents.

Details and Options

Examples

open all close all

Basic Examples  (2)

List square-free factors of a polynomial:

Wolfram Language code: FactorSquareFreeList[x ^ 5 - x ^ 3 - x ^ 2 + 1]

List irreducible factors of a polynomial:

Wolfram Language code: FactorList[x ^ 5 - x ^ 3 - x ^ 2 + 1]

Scope  (8)

A univariate polynomial:

Wolfram Language code: FactorSquareFreeList[x ^ 4 - 9x ^ 3 + 29x ^ 2 - 39x + 18]

A multivariate polynomial:

Wolfram Language code: FactorSquareFreeList[x ^ 5 - x ^ 3y ^ 2 - x ^ 2y ^ 3 + y ^ 5]

A rational function:

Wolfram Language code: FactorSquareFreeList[(x ^ 3 + x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 1) / (x ^ 2 - 4y ^ 2)]

A polynomial with complex coefficients:

Wolfram Language code: FactorSquareFreeList[x ^ 4 - 2I x ^ 3 - 2x ^ 2 + 2 I x + 1]

Non-polynomial expressions:

Wolfram Language code: FactorSquareFreeList[E ^ (3x) - 3E ^ (2x) + 3E ^ x - 1]
Wolfram Language code: FactorSquareFreeList[x + 2Sqrt[x] + 1]

Square-free factors of a polynomial over the integers modulo 3:

Wolfram Language code: FactorSquareFreeList[x ^ 6 + 1, Modulus -> 3]

Square-free factors of a polynomial over a finite field:

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: FactorSquareFreeList[ℱ[1]x ^ 4 + ℱ[246]x ^ 3 + ℱ[4875]x ^ 2 + ℱ[4608]x + ℱ[304]]

Compute the square-free factorization of a polynomial of degree :

Wolfram Language code: rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n] SeedRandom[1234]; p = rpoly[2000]; q = rpoly[2000]; r = Expand[p ^ 2 q ^ 3];
Wolfram Language code: (facs = FactorSquareFreeList[r]);//AbsoluteTiming
Wolfram Language code: {Exponent[#[[1]], x], #[[2]]}& /@ facs

Options  (5)

Extension  (3)

By default algebraic number coefficients are treated as independent variables:

Wolfram Language code: FactorSquareFreeList[x ^ 2 + 2Sqrt[2]x + 2]

With Extension->Automatic algebraic dependencies between coefficients are recognized:

Wolfram Language code: FactorSquareFreeList[x ^ 2 + 2Sqrt[2]x + 2, Extension -> Automatic]

Square-free factorization over a finite field:

Wolfram Language code: ℱ = FiniteField[2, 3];
Wolfram Language code: FactorSquareFreeList[x ^ 4 + 1, Extension -> ℱ]

Modulus  (1)

Find square-free factors over the integers modulo 2:

Wolfram Language code: FactorSquareFreeList[1 + x ^ 4, Modulus -> 2]

Trig  (1)

List multiple factors in a trigonometric expression:

Wolfram Language code: FactorSquareFreeList[1 - Cos[2x], Trig -> True]

Applications  (1)

Remove root multiplicities:

Wolfram Language code: f = x ^ 9 + 9x ^ 8 + 21x ^ 7 - 27x ^ 6 - 153x ^ 5 - 81x ^ 4 + 239x ^ 3 + 207x ^ 2 - 108x - 108;
Wolfram Language code: rtsf = x /. Solve[f == 0, x]
Wolfram Language code: g = Times@@First /@ FactorSquareFreeList[f]
Wolfram Language code: rtsg = x /. Solve[g == 0, x]
Wolfram Language code: rtsg === Union[rtsf]

Properties & Relations  (3)

FactorSquareFreeList gives a list of square-free factors:

Wolfram Language code: f = x ^ 9 + 9x ^ 8 + 21x ^ 7 - 27x ^ 6 - 153x ^ 5 - 81x ^ 4 + 239x ^ 3 + 207x ^ 2 - 108x - 108;
Wolfram Language code: FactorSquareFreeList[f]

This multiplies the factors together:

Wolfram Language code: Times@@Power@@@%

FactorSquareFree gives a product of factors:

Wolfram Language code: FactorSquareFree[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

Expand combines all the factors back together:

Wolfram Language code: Expand[%]

FactorList gives a list of irreducible factors:

Wolfram Language code: FactorList[f]

A univariate polynomial has multiple factors if and only if its Discriminant is zero:

Wolfram Language code: Discriminant[x ^ 5 - x ^ 3 - x ^ 2 + 1, x]
Wolfram Language code: FactorSquareFreeList[x ^ 5 - x ^ 3 - x ^ 2 + 1]
Wolfram Language code: Discriminant[x ^ 5 - x ^ 3 - x ^ 2 - 1, x]
Wolfram Language code: FactorSquareFreeList[x ^ 5 - x ^ 3 - x ^ 2 - 1]

FactorInteger gives a list of prime factors of an integer:

Wolfram Language code: FactorInteger[1234567]
Wolfram Language code: Times@@Power@@@%
Wolfram Research (1988), FactorSquareFreeList, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorSquareFreeList.html (updated 2023).

Text

Wolfram Research (1988), FactorSquareFreeList, Wolfram Language function, https://reference.wolfram.com/language/ref/FactorSquareFreeList.html (updated 2023).

CMS

Wolfram Language. 1988. "FactorSquareFreeList." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/FactorSquareFreeList.html.

APA

Wolfram Language. (1988). FactorSquareFreeList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorSquareFreeList.html

BibTeX

@misc{reference.wolfram_2026_factorsquarefreelist, author="Wolfram Research", title="{FactorSquareFreeList}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/FactorSquareFreeList.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorsquarefreelist, organization={Wolfram Research}, title={FactorSquareFreeList}, year={2023}, url={https://reference.wolfram.com/language/ref/FactorSquareFreeList.html}, note=[Accessed: 13-June-2026]}