Wolfram Language & System Documentation Center

FormPage   

FormPage[formspec,func]

represents an active page that takes input from a form and generates results on the same page by applying func to the values obtained from the form whose structure is defined by formspec.

FormPage[{"name₁"type₁,…},func]

represents an active form page with fields named name_i interpreted as types type_i.

FormPage[{{"name₁",label₁}type₁,…},func]

uses label_i as the label for the field named name_i.

FormPage[{namespec₁type₁default₁,…},func]

uses default_i as the default for the field specified by namespec_i.

FormPage[formspec,func,form]

lays out the page according to the layout specification form.

FormPage[formspec,func,initformresform]

uses initform as the initial layout specification and resform as the layout specification for result pages.

FormPage   

Listing of Field Types »

FormPage[formspec,func]

represents an active page that takes input from a form and generates results on the same page by applying func to the values obtained from the form whose structure is defined by formspec.

FormPage[{"name₁"type₁,…},func]

represents an active form page with fields named name_i interpreted as types type_i.

FormPage[{{"name₁",label₁}type₁,…},func]

uses label_i as the label for the field named name_i.

FormPage[{namespec₁type₁default₁,…},func]

uses default_i as the default for the field specified by namespec_i.

FormPage[formspec,func,form]

lays out the page according to the layout specification form.

FormPage[formspec,func,initformresform]

uses initform as the initial layout specification and resform as the layout specification for result pages.

Details and Options

CloudDeploy[FormPage[…]] yields a cloud object containing an active form page.
FormPage[formspec,func][<|"name_k"->input_k,…|>] inserts the inputs given into the initial form specified by the FormPage object.
Setting[FormPage[formspec,func]] evaluates to func applied to the current values of the form.
In FormPage[formspec,func,layout], possible specifications for layout include:

	"ResultBelow"	display results below the form
	"ResultAbove"	display results above the form
	{elem₁,elem₂,…}	display layout elements in the specified order

In FormPage[formspec,func,{elem₁,elem₂,…}], possible elem_i include:
"Form" the form as specified by formspec

"Result" results generated by applying func

"Button" button for submitting the form
Overall options for FormPage include:

AppearanceRules	Automatic	association giving overall appearance rules
FormLayoutFunction	Automatic	function to generate layout for the form
FormProtectionMethod	Automatic	method for spam protection
PageTheme	Automatic	overall theme to use for the form
ImageFormattingWidth	$ImageFormattingWidth	wrapping width for output formatting
ImageSize	Automatic	overall image size for output

Examples

open all close all

Basic Examples (1)

Use FormPage to continuously interact with a webpage:

Wolfram Language code: CloudDeploy[FormPage["country" -> "Country", GeoGraphics[#country]&]]

Scope (31)

Interpreter Specifications (6)

Use rich Interpreter specifications:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> Restricted["Integer", {1, 10}]}, func]]

The Interpreter head is optional, but useful to specify options or other arguments to Interpreter:

Wolfram Language code:

CloudDeploy[FormPage[{"x" -> Interpreter["StructuredDate", TimeZone -> 2], "y" -> Interpreter[ToExpression, Positive]}, func]]

A list can be used to create a menu:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> {1, 2, 3}}, func]]

Wolfram Language code: CloudDeploy[FormPage[{"question" -> {"Yes" -> True, "No" -> False}}, func]]

An entity list can be used as a menu:

Wolfram Language code: CloudDeploy[FormPage[{"Country" -> EntityList["Country"]}, func]]

Choices can be any expression:

Wolfram Language code:

CloudDeploy[FormPage[{"Image"  :> Map[ImageResize[ExampleData[#], {100, 100}] &, ExampleData["TestImage"][[1 ;; 6]]]}, Composition[EdgeDetect, First]]]

A list of rules allows for label specification:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> {"A" -> 1, "B" -> 2, "C" -> 3}}, func]]

Defaults (3)

Specify a default for a field; fields that have a default are not required:

Wolfram Language code: Setting @ FormPage[{"first" -> "String", "second" -> "Number" -> 3}, f]["first" -> "str"]

Fields can be optional without having a default:

Wolfram Language code:

Setting@FormPage[{"first" -> "String", "second" -> <|"Interpreter" -> "Number", "Required" -> False|>}, f]["first" -> "str"]

Use RuleDelayed to evaluate a new default every time:

Wolfram Language code:

Setting@FormPage[{"name" -> "String", "date" -> <|"Interpreter" -> "DateTime", "Default" :> DateObject[]|>}, f][<|"name" -> "Bob", "date" -> None|>]

Input (2)

Create a form with input inside:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> <|"Input" -> "Apple"|>}, Identity]]

Input can be delayed:

Wolfram Language code: CloudDeploy[FormPage[{"DateTime" -> <|"Interpreter" -> "DateTime", "Input" :> DateString[]|>}, Identity]]

Label (1)

Change the label for a field:

Wolfram Language code: CloudDeploy[FormPage[{"x", "First Name"} -> "String", Identity]]

You can use RuleDelayed and return any expression:

Wolfram Language code: CloudDeploy[FormPage["pc" -> <|"Label" :> "PC: " <> $MachineID|>, Identity]]

Wolfram Language code:

CloudDeploy[FormPage[
	"pc" -> <|"Label" :> GeoGraphics[
	$GeoLocation, 
	GeoRange -> Quantity[2, "Miles"]
	]|>, 
	Identity
	]]

Use None to remove the label:

Wolfram Language code: CloudDeploy[FormPage["Query" -> <|"Label" -> None, "Hint" -> "Search"|>, Identity]]

Wolfram Language code:

CloudDeploy[FormPage[{
	"First" -> <|"Label" -> None, "Hint" -> "First Name"|>, 
	"Last"  -> <|"Label" -> None, "Hint" -> "Last Name"|>
	}, Identity]]

Appearance (4)

Change the default label to be something different from the key:

Wolfram Language code: CloudDeploy[FormPage[{"key", "Label"} -> "Integer", g]]

Labels can be any expression:

Wolfram Language code: CloudDeploy[FormPage[{"Number", [image]} -> "Number", g]]

Change the appearance of single fields:

Wolfram Language code:

CloudDeploy[FormPage[{"x"  -> <|"Interpreter" -> Restricted["Integer", {1, 10}], "Control" -> InputField, "Help" -> "help text", "Hint" -> "write something"|>}, func]]

Use RuleDelayed to evaluate an expression in the cloud:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> <|"Label" -> "Where are you?", "Help" :> GeoGraphics[$GeoLocation]|>}, func]]

Use non-rule elements to change the default appearance:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> "String", "text", Graphics3D[Sphere[]], "y" -> "Integer"}, func]]

Controls (7)

Different types have different controllers. Color pickers for "Color":

Wolfram Language code: CloudDeploy[FormPage[{"x" -> "Color"}, func]]

Or file pickers for file formats:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> "Image"}, func]]

Checkboxes for "Boolean":

Wolfram Language code: CloudDeploy[FormPage[{"x" -> "Boolean"}, func]]

Change the default controller:

Wolfram Language code: CloudDeploy[FormPage[{"x" -> <|"Interpreter" -> Restricted["Integer", {1, 10}], "Control" -> Slider|>}, func]]

Multiple choices support various types of controllers:

Wolfram Language code:

CloudDeploy[FormPage[FormObject[<|"x" -> <|"Interpreter" -> {"A" -> 1, "B" -> 2, "C" -> 3}, "Control" -> RadioButtonBar|>|>], func]]

Labels for radio buttons can be anything you want:

Wolfram Language code:

CloudDeploy[FormPage[FormObject[<|"x" -> <|"Interpreter" -> {Plot[Sin[x], {x, 0, 10}] -> 1, Graphics3D[Sphere[]] -> 2, EntityValue[Entity["Species", "Species:FelisCatus"], EntityProperty["Species", "Image"]] -> 3}, "Control" -> RadioButtonBar|>|>], func]]

The control specification also accepts pure functions:

Wolfram Language code:

CloudDeploy[FormPage[{"x" -> <|"Interpreter" -> "String", "Control" -> Function[Tooltip[InputField[##], EntityValue[Entity["Species", "Species:FelisCatus"], EntityProperty["Species", "Image"]]]]|>}, func]]

Disambiguation (3)

For strings that are interpreted from natural language in the Wolfram Cloud, sometimes results might be ambiguous:

Wolfram Language code: CloudDeploy[FormPage["where" -> "City", func]["where" -> "springfield"]]

Disambiguation is off for most types by default, but it can be easily activated:

Wolfram Language code:

CloudDeploy[FormPage["amount"  -> <|"Interpreter" -> "Quantity", "Disambiguation" -> All|>, func]["amount" -> "2 ounces"]]

Sometimes several parts of the expression are ambiguous:

Wolfram Language code:

CloudDeploy[FormPage["expr"  -> <|"Interpreter" -> "SemanticExpression", "Disambiguation" -> All|>, func]["expr" -> "log log 3"]]

Dynamic Forms (1)

Parts of forms that contain TemplateSlot are not evaluated until the keys mentioned in TemplateSlot[key] are bound to a proper value:

Wolfram Language code:

FormPage[{{"name", "what's your name?"} -> "GivenName", "gender"  -> <|"Interpreter" -> {"Male", "Female"}, "Input"  -> TemplateIf[TemplateSlot["name"][[-1, -1]] == "male", "Male", "Female"]|>}]

Layout (4)

Put the result below the form:

Wolfram Language code: CloudDeploy[FormPage["x" -> "Integer", #x!&, "ResultBelow"]]

Put the result above the form:

Wolfram Language code: CloudDeploy[FormPage["x" -> "Integer", #x!&, "ResultAbove"]]

Specify a custom order:

Wolfram Language code: CloudDeploy[FormPage["x" -> "Integer", #x!&, {"Button", "Form", "Result"}]]

Wolfram Language code: [image]

Specify a different order for the initial form and the results:

Wolfram Language code: CloudDeploy[FormPage["x" -> "Integer", #x!&, {"Form", "Button"} -> {"Button", "Form", "Result"}]]

Options (6)

AppearanceRules (1)

Write a custom title and description:

Wolfram Language code:

CloudDeploy[FormPage["Start" -> "Country", func, AppearanceRules -> <|"Title" -> "Where do you want to go?", "Description" -> "Enter a country and we will find you an accomodation"|>]]

Use an image for branding:

Wolfram Language code:

CloudDeploy[FormPage["Product" -> {"Flyers", "Business cards", "Leflets"}, func, AppearanceRules -> <|"Title"  -> [image], "Description" -> "What do you want to print today?"|>]]

Use an "ItemLayout" to change form fields' appearance:

Wolfram Language code:

CloudDeploy[FormPage[{"First" -> "String", "Second" -> "String"}, func, AppearanceRules -> <|"ItemLayout" -> "Vertical"|>]]

Wolfram Language code:

CloudDeploy[FormPage[{"First" -> <|"Help"  ->   "Insert a value"|>, "Second" -> <|"Help"  ->   "Insert a value"|>}, func, AppearanceRules -> <|"ItemLayout" -> "Inline"|>]]

Change the submit label:

Wolfram Language code:

CloudDeploy[FormPage["Product" -> {"Flyers", "Business cards", "Leflets"}, func, AppearanceRules -> <|"SubmitLabel" -> "Buy now!"|>]]

FormLayoutFunction (1)

A pure function can be specified to give a specific layout to a form:

Wolfram Language code: CloudDeploy[FormPage["x" -> "Integer", func, FormLayoutFunction -> Function[Column[{#["x"], Graphics3D[Sphere[]]}]]]]

PageTheme (4)

Deploy a form with a white theme:

Wolfram Language code: CloudDeploy[FormPage[{"age" -> "Number"}, First, PageTheme -> "White"]]

Deploy a form with a blue theme:

Wolfram Language code: CloudDeploy[FormPage[{"age" -> "Number"}, First, PageTheme -> "Blue"]]

Deploy a form with a black theme:

Wolfram Language code: CloudDeploy[FormPage[{"age" -> "Number"}, First, PageTheme -> "Black"]]

Deploy a form with a red theme:

Wolfram Language code: CloudDeploy[FormPage[{"age" -> "Number"}, First, PageTheme -> "Red"]]

Applications (2)

Draw the flight path between two airports:

Wolfram Language code:

CloudDeploy[FormPage[{"from" -> "Airport", "to" -> "Airport"}, GeoGraphics[GeoPath[{GeoPosition[#from], GeoPosition[#to]}]]&]]

Get demographic data for a city:

Wolfram Language code:

CloudDeploy @ FormPage[{
	"city" -> <|"Interpreter" -> "City", "Input" -> "NYC"|>, 
	"years" -> <|
	"Input" -> "2000 - 2010", 
	"Interpreter" -> Restricted[
	DelimitedSequence[
	Restricted["Integer", {1900, 2014}], 
	"-"
	], 
	{1, 2}
	]|>
	}, 
	Module[{data, range}, 
	range = Range @@ PadRight[Sort[#years], 2, First[#years]];
	data  =   EntityValue[
	#city, 
	Table[
	EntityProperty[
	"City", 
	"Population", 
	{"Date" -> DateObject[{year}]}
	], 
	{year, range}
	]
	];
	Grid @ Transpose[{range, data}]
	]
	&, 
	AppearanceRules -> <|
	"Title" -> "Demographic data", 
	"Description" -> "Enter any city and a date range."
	|>
	]

Properties & Relations (9)

FormPage is designed to be interchangeable with FormFunction:

Wolfram Language code: CloudDeploy[FormPage @@ FormFunction["x" -> "String", Identity]]

FormPage is designed to be interchangeable with APIFunction:

Wolfram Language code: CloudDeploy[FormPage @@ APIFunction["x" -> "String", Identity]]

And vice versa:

Wolfram Language code: CloudDeploy[APIFunction @@ FormPage["x" -> "String", Identity]]

The first argument of FormPage can be given as a full FormObject:

Wolfram Language code: FormPage[FormObject["x" -> "Integer"], Identity]

FormPage evaluates so that the first argument becomes a full FormObject:

Wolfram Language code: FormPage["x" -> "String", Identity]//InputForm

The single fields of a FormPage use Interpreter to transform the input in Wolfram Language expressions:

Wolfram Language code: f1 = FormPage["x" -> "Country", #x&]

This is effectively the same as:

Wolfram Language code: f2 = FormPage["x" -> Interpreter["Country"], #x&]

AnySubset can be used to generate a controller where more than one choice can be picked:

Wolfram Language code:

CloudDeploy[FormPage[
	{"choose one or more" -> AnySubset[{1, 2, 3}]}]]

RepeatingElement can be used to create a group of fields that can be added and deleted:

Wolfram Language code: CloudDeploy[FormPage["field" -> RepeatingElement["String", {2, {1, 5}}]]]

CompoundElement can be used to create an extensible table of fields:

Wolfram Language code: CloudDeploy[FormPage["names" -> RepeatingElement[CompoundElement[<|"first" -> "String", "last" -> "String"|>]]]]

Possible Issues (2)

Interpreter["String"] accepts an empty string. This is not true for FormPage, where the empty string and an empty field are considered equivalent:

Wolfram Language code: Interpreter["String"][""]

Wolfram Language code: FormPage[{"a string" -> "String"}, f][{"a string" -> ""}]

Cloud evaluations have restrictions on memory usage and evaluation time. The limitations for FormPage are determined by your cloud plan, and the specific amounts can be found in CloudAccountData as the "DeployedMemoryLimit" and "DeployedEvaluationTimeLimit":

Wolfram Language code: CloudAccountData /@ {"DeployedMemoryLimit", "DeployedEvaluationTimeLimit"}

Neat Examples (1)

Make a simple web application to apply a filter to an image:

Wolfram Language code:

CloudDeploy[FormPage[{"image"  -> "Image", "filter" -> ImageEffect[]}, ImageEffect[#image, #filter]&, AppearanceRules -> {"Title" -> "Wolf(g)ram"}]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FormPage

Details and Options

Examples

Basic Examples (1)

Scope (31)

Interpreter Specifications (6)

Defaults (3)

Input (2)

Label (1)

Appearance (4)

Controls (7)

Disambiguation (3)

Dynamic Forms (1)

Layout (4)

Options (6)

AppearanceRules (1)

FormLayoutFunction (1)

PageTheme (4)

Applications (2)

Properties & Relations (9)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

FormPage

Details and Options

Examples

Basic Examples (1)

Scope (31)

Interpreter Specifications (6)

Defaults (3)

Input (2)

Label (1)

Appearance (4)

Controls (7)

Disambiguation (3)

Dynamic Forms (1)

Layout (4)

Options (6)

AppearanceRules (1)

FormLayoutFunction (1)

PageTheme (4)

Applications (2)

Properties & Relations (9)

Possible Issues (2)

Neat Examples (1)

See Also

Related Guides

Related Workflows

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX

FormPage   