WOLFRAM

Wolfram Language & System Documentation Center

FourierSequenceTransform[expr,n,ω]

gives the Fourier sequence transform of expr.

FourierSequenceTransform[expr,{n1,n2,…},{ω1,ω2,…}]

gives the multidimensional Fourier sequence transform.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
FourierParameters  
GenerateConditions  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

FourierSequenceTransform

FourierSequenceTransform[expr,n,ω]

gives the Fourier sequence transform of expr.

FourierSequenceTransform[expr,{n1,n2,…},{ω1,ω2,…}]

gives the multidimensional Fourier sequence transform.

Details and Options

  • FourierSequenceTransform is also known as discrete-time Fourier transform (DTFT).
  • FourierSequenceTransform[expr,n,ω] takes a sequence whose n^(th) term is given by expr, and yields a function of the continuous parameter ω.
  • The Fourier sequence transform of is by default defined to be .
  • The Fourier sequence transform of is by default periodic with a period of .
  • The multidimensional transform of is defined to be .
  • The following options can be given:
  • Assumptions$Assumptionsassumptions on parameters
    FourierParameters {1,1}parameters to define the discrete-time Fourier transform
    GenerateConditions Falsewhether to generate results that involve conditions on parameters
  • Common settings for FourierParameters include:
  • {1,1}default settings
    {1,2Pi}period 1
    {a,b}general setting

Examples

open all close all

Basic Examples  (2)

Find the discrete-time Fourier transform of a simple signal:

Wolfram Language code: FourierSequenceTransform[(1 / 2) ^ n UnitStep[n], n, ω]
Wolfram Language code: LogPlot[Abs[%], {ω, 0, 4Pi}]

Find a bivariate discrete-time Fourier transform:

Wolfram Language code: FourierSequenceTransform[(1 / 2) ^ n1(1 / 3) ^ n2 UnitStep[n1, n2], {n1, n2}, {ω1, ω2}]
Wolfram Language code: Plot3D[Abs[%], {ω1, 0, 4Pi}, {ω2, 0, 4Pi}]

Scope  (4)

Compute the transform for each frequency ω:

Wolfram Language code: F = FourierSequenceTransform[Sin[n 2Pi / 3](2 / 3) ^ n UnitStep[n], n, ω]

Plot the power spectrum:

Wolfram Language code: LogPlot[Abs[F] ^ 2, {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}]

The phase:

Wolfram Language code: Plot[Arg[F], {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}]

Plot both spectrum and phase using color:

Wolfram Language code: LogPlot[Abs[F] ^ 2, {ω, 0, 2π}, Ticks -> {{0, π, 2π}, Automatic}, ColorFunction -> Function[ω, Evaluate@Hue[Arg[F] / (2Pi) + 1 / 2]], ColorFunctionScaling -> False, Filling -> Axis]

Constant:

Wolfram Language code: FourierSequenceTransform[1, n, ω]

Periodic:

Wolfram Language code: FourierSequenceTransform[Exp[I n ], n, ω]
Wolfram Language code: FourierSequenceTransform[Cos[5n], n, ω]
Wolfram Language code: FourierSequenceTransform[Sin[n ω0], n, ω, Assumptions -> ω0∈Reals]
Wolfram Language code: FourierSequenceTransform[Mod[n, 3], n, ω]

Impulse:

Wolfram Language code: FourierSequenceTransform[DiscreteDelta[n], n, ω]
Wolfram Language code: FourierSequenceTransform[DiscreteDelta[n - n0], n, ω]

Exponential:

Wolfram Language code: FourierSequenceTransform[a ^ n UnitStep[n], n, ω]
Wolfram Language code: FourierSequenceTransform[a ^ n UnitStep[-1 - n], n, ω]

Exponential polynomial:

Wolfram Language code: FourierSequenceTransform[(n + 1)a ^ n UnitStep[n], n, ω]
Wolfram Language code: FourierSequenceTransform[(n + 2)(n + 1) a ^ n UnitStep[n], n, ω]

Rational sequence:

Wolfram Language code: FourierSequenceTransform[1 / (2n + 1) ^ 2, n, ω]

Rational-trigonometric:

Wolfram Language code: FourierSequenceTransform[Sin[n] / (3n + 1), n, ω]

Hypergeometric terms:

Wolfram Language code: FourierSequenceTransform[1 / n! UnitStep[n], n, ω]
Wolfram Language code: FourierSequenceTransform[2 ^ n / (CatalanNumber[n]n!) UnitStep[n], n, ω]

Multivariate sequences:

Wolfram Language code: FourierSequenceTransform[E ^ (-n1)(1 / 5) ^ n2 UnitStep[n1, n2], {n1, n2}, {ω1, ω2}]
Wolfram Language code: FourierSequenceTransform[Mod[n1 + n2, 2], {n1, n2}, {ω1, ω2}]

Options  (2)

FourierParameters  (1)

Use a non-default setting for FourierParameters:

Wolfram Language code: FourierSequenceTransform[a ^ n UnitStep[n], n, ω, FourierParameters -> {1, -2π}]

GenerateConditions  (1)

Obtain conditions on parameters:

Wolfram Language code: FourierSequenceTransform[Piecewise[{{a^n, n ≥ 0}, {b^n, n < 0}}], n, ω, GenerateConditions -> True, Assumptions -> ω∈Reals]

Properties & Relations  (5)

FourierSequenceTransform is defined by a doubly infinite sum:

Wolfram Language code: f = Piecewise[{{a^n, n ≥ 0}, {b^n, n < 0}}]
Wolfram Language code: {FourierSequenceTransform[f, n, ω], Sum[f Exp[-I n ω], {n, -∞, ∞}]}

FourierSequenceTransform and InverseFourierSequenceTransform are inverses:

Wolfram Language code: InverseFourierSequenceTransform[FourierSequenceTransform[f[n], n, ω], ω, n]
Wolfram Language code: FourierSequenceTransform[InverseFourierSequenceTransform[g[ω], ω, n], n, ω]
Wolfram Language code: FourierSequenceTransform[a ^ n UnitStep[n], n, ω]
Wolfram Language code: InverseFourierSequenceTransform[%, ω, n]
Wolfram Language code: Simplify[% - a ^ n UnitStep[n], n∈Integers]

FourierSequenceTransform is closely related to ZTransform:

Wolfram Language code: {FourierSequenceTransform[a ^ n UnitStep[n], n, ω], ZTransform[a ^ n, n, Exp[I ω]]}

A discrete analog of FourierTransform being closely related to LaplaceTransform:

Wolfram Language code: {Sqrt[2π]FourierTransform[Exp[-a t] UnitStep[t], t, ω], LaplaceTransform[Exp[-a t] UnitStep[t], t, -I ω]}

FourierSequenceTransform provides a -analog generating function:

Wolfram Language code: FourierSequenceTransform[a ^ n UnitStep[n], n, ω] /. Exp[I ω] -> q
Wolfram Language code: GeneratingFunction[a ^ n UnitStep[n], n, 1 / q]
Wolfram Language code: Simplify[%% - %]

FourierSequenceTransform is closely related to BilateralZTransform:

Wolfram Language code: {BilateralZTransform[UnitStep[n + 1]3^-n, n, Exp[I ω], Assumptions -> ω∈Reals], FourierSequenceTransform[UnitStep[n + 1]3^-n, n, ω]}
Wolfram Language code: {BilateralZTransform[5^-Abs[n + 1], n, Exp[I ω], Assumptions -> ω∈Reals], FourierSequenceTransform[5^-Abs[n + 1], n, ω]}
Wolfram Research (2008), FourierSequenceTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/FourierSequenceTransform.html.

Text

Wolfram Research (2008), FourierSequenceTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/FourierSequenceTransform.html.

CMS

Wolfram Language. 2008. "FourierSequenceTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FourierSequenceTransform.html.

APA

Wolfram Language. (2008). FourierSequenceTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FourierSequenceTransform.html

BibTeX

@misc{reference.wolfram_2026_fouriersequencetransform, author="Wolfram Research", title="{FourierSequenceTransform}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/FourierSequenceTransform.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_fouriersequencetransform, organization={Wolfram Research}, title={FourierSequenceTransform}, year={2008}, url={https://reference.wolfram.com/language/ref/FourierSequenceTransform.html}, note=[Accessed: 12-June-2026]}