Wolfram Language & System Documentation Center

FunctionBijective

tests whether has exactly one solution x∈Reals for each y∈Reals.

tests whether has exactly one solution x∈dom for each y∈dom.

FunctionBijective[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether has exactly one solution x₁,x₂,…∈dom for each y₁,y₂,…∈dom.

FunctionBijective[{funs,xcons,ycons},xvars,yvars,dom]

tests whether has exactly one solution with xvars∈dom restricted by the constraints xcons for each yvars∈dom restricted by the constraints ycons.

FunctionBijective

FunctionBijective[f,x]

tests whether has exactly one solution x∈Reals for each y∈Reals.

FunctionBijective[f,x,dom]

tests whether has exactly one solution x∈dom for each y∈dom.

FunctionBijective[{f₁,f₂,…},{x₁,x₂,…},dom]

tests whether has exactly one solution x₁,x₂,…∈dom for each y₁,y₂,…∈dom.

FunctionBijective[{funs,xcons,ycons},xvars,yvars,dom]

tests whether has exactly one solution with xvars∈dom restricted by the constraints xcons for each yvars∈dom restricted by the constraints ycons.

Details and Options

A bijective function is also known as one-to-one and onto.
A function is bijective if for each there is exactly one such that .

FunctionBijective[{funs,xcons,ycons},xvars,yvars,dom] returns True if the mapping is bijective, where is the solution set of xcons and is the solution set of ycons.
If funs contains parameters other than xvars, the result is typically a ConditionalExpression.
Possible values for dom are Reals and Complexes. If dom is Reals, then all variables, parameters, constants and function values are restricted to be real.
The domain of funs is restricted by the condition given by FunctionDomain.
xcons and ycons can contain equations, inequalities or logical combinations of these.
The following options can be given:

Assumptions	$Assumptions	assumptions on parameters
GenerateConditions	True	whether to generate conditions on parameters
PerformanceGoal	$PerformanceGoal	whether to prioritize speed or quality

Possible settings for GenerateConditions include:
Automatic nongeneric conditions only

True all conditions

False no conditions

None return unevaluated if conditions are needed
Possible settings for PerformanceGoal are "Speed" and "Quality".

Examples

open all close all

Basic Examples (4)

Test bijectivity of a univariate function over the reals:

Wolfram Language code: FunctionBijective[Sinh[x], x]

Test bijectivity over the complexes:

Wolfram Language code: FunctionBijective[Sinh[x], x, Complexes]

Test bijectivity of a polynomial mapping over the reals:

Wolfram Language code: FunctionBijective[{x + y ^ 3, y - x ^ 5}, {x, y}]

Test bijectivity of a polynomial with symbolic coefficients:

Wolfram Language code: FunctionBijective[x ^ 3 + a x + b, x]

Scope (10)

Bijectivity over the reals:

Wolfram Language code: FunctionBijective[x ^ 3 - x, x]

Some values are attained more than once:

Wolfram Language code: Plot[{x ^ 3 - x, 1 / 4}, {x, -2, 2}]

Bijectivity between subsets of the reals:

Wolfram Language code: FunctionBijective[{x ^ 3 - x, x > 1, y > 0}, x, y]

For , each positive value is attained exactly once:

Wolfram Language code: Plot[{x ^ 3 - x, 10}, {x, 1, 3}]

Bijectivity over the complexes:

Wolfram Language code: FunctionBijective[Log[x], x, Complexes]

Some values are not attained:

Wolfram Language code: Reduce[Log[x] == y, x]

The logarithm is bijective onto :

Wolfram Language code: FunctionBijective[{Log[x], True, -Pi < Im[y] ≤ Pi}, x, y, Complexes]

Bijectivity over a subset of complexes:

Wolfram Language code: FunctionBijective[{x ^ 4, Re[x] ≥ 0 && Im[x] > 0 || x == 0}, x, Complexes]

is not bijective over the whole complex plane:

Wolfram Language code: FunctionBijective[x ^ 4, x, Complexes]

Some values are attained more than once:

Wolfram Language code: Reduce[x ^ 4 == 1, x]

Bijectivity over the integers:

Wolfram Language code: FunctionBijective[{x + 1, Element[x, Integers], Element[y, Integers]}, x, y]

Bijectivity of linear mappings:

Wolfram Language code: A = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};

Wolfram Language code: FunctionBijective[A.{x, y, z}, {x, y, z}]

Wolfram Language code: B = {{1, 2, 3}, {4, 5, 6}, {7, 8, 0}};

Wolfram Language code: FunctionBijective[B.{x, y, z}, {x, y, z}]

A linear mapping is bijective iff its matrix is square and of the maximal rank:

Wolfram Language code: {MatrixRank[A], MatrixRank[B]}

Bijectivity of polynomial mappings :

Wolfram Language code: FunctionBijective[{x ^ 3 - 3x y ^ 2, 3x ^ 2y - y ^ 3}, {x, y}]

The restricted mapping $TemplateBox[{}, NonNegativeReals]^2->TemplateBox[{}, Reals]^2\(TemplateBox[{}, PositiveReals]xTemplateBox[{}, NegativeReals])$ , equal to the real and imaginary part of , is bijective:

Wolfram Language code: FunctionBijective[{{x ^ 3 - 3x y ^ 2, 3x ^ 2y - y ^ 3}, x ≥ 0 && y ≥ 0, u ≤ 0 || v ≥ 0}, {x, y}, {u, v}]

Bijectivity of polynomial mappings :

Wolfram Language code: FunctionBijective[{x + y ^ 3, y - x ^ 5}, {x, y}, Complexes]

The Jacobian determinant of a bijective complex polynomial mapping must be constant:

Wolfram Language code: Det[D[{x + y ^ 3, y - x ^ 5}, {{x, y}}]]

The Jacobian conjecture states that the reverse implication is true:

Wolfram Language code: Det[D[{x - (x + y / 27) ^ 3, y + (3 x + y / 9) ^ 3}, {{x, y}}]]

Indeed, this polynomial mapping with a constant Jacobian is bijective:

Wolfram Language code: FunctionBijective[{x - (x + y / 27) ^ 3, y + (3 x + y / 9) ^ 3}, {x, y}, Complexes]

Bijectivity of a real polynomial with symbolic parameters:

Wolfram Language code: FunctionBijective[x ^ 3 + a x ^ 2 + b x + c, x]

Bijectivity of a real polynomial mapping with symbolic parameters:

Wolfram Language code: FunctionBijective[{x + a y ^ 3, y + b x ^ 3}, {x, y}]

Options (4)

Assumptions (1)

FunctionBijective gives a conditional answer here:

Wolfram Language code: FunctionBijective[{x + a y ^ 3, y + 2 x ^ 3}, {x, y}]

This checks the bijectivity for the remaining real values of :

Wolfram Language code: FunctionBijective[{x + a y ^ 3, y + 2 x ^ 3}, {x, y}, Assumptions -> a > 0]

GenerateConditions (2)

By default, FunctionBijective may generate conditions on symbolic parameters:

Wolfram Language code: FunctionBijective[x ^ 3 + a x ^ 2 + b x + c, x]

With GenerateConditions->None, FunctionBijective fails instead of giving a conditional result:

Wolfram Language code: FunctionBijective[x ^ 3 + a x ^ 2 + b x + c, x, GenerateConditions -> None]

This returns a conditionally valid result without stating the condition:

Wolfram Language code: FunctionBijective[x ^ 3 + a x ^ 2 + b x + c, x, GenerateConditions -> False]

By default, all conditions are reported:

Wolfram Language code: FunctionBijective[a x, x, Complexes]

With GenerateConditions->Automatic, conditions that are generically true are not reported:

Wolfram Language code: FunctionBijective[a x, x, Complexes, GenerateConditions -> Automatic]

PerformanceGoal (1)

Use PerformanceGoal to avoid potentially expensive computations:

Wolfram Language code: FunctionBijective[x ^ 5 + a x ^ 4 + b x ^ 3 + c x ^ 2 + d x, x, PerformanceGoal -> "Speed"]

The default setting uses all available techniques to try to produce a result:

Wolfram Language code: FunctionBijective[x ^ 5 + a x ^ 4 + b x ^ 3 + c x ^ 2 + d x, x]

Applications (11)

Basic Applications (8)

Check bijectivity of :

Wolfram Language code: FunctionBijective[x ^ 3, x]

Each value is attained exactly once:

Wolfram Language code: Plot[{x ^ 3, -3, 3}, {x, -2, 2}]

is not bijective:

Wolfram Language code: FunctionBijective[x ^ 3 - x, x]

Some values, e.g. , are attained more than once:

Wolfram Language code: Plot[{x ^ 3 - x, 1 / 4}, {x, -2, 2}]

is not bijective:

Wolfram Language code: FunctionBijective[ArcTan[x], x]

Some values, e.g. , are not attained:

Wolfram Language code: Plot[{ArcTan[x], 2}, {x, -5, 5}]

is bijective in its real domain:

Wolfram Language code: FunctionBijective[Log[x], x]

Each value is attained exactly once:

Wolfram Language code: Plot[{Log[x], -1, 1}, {x, 0, 5}]

Show that is bijective:

Wolfram Language code: FunctionBijective[SinhIntegral[x], x]

Wolfram Language code: Plot[SinhIntegral[x], {x, -5, 5}]

Show that is not bijective:

Wolfram Language code: FunctionBijective[Hyperfactorial[x], x]

Wolfram Language code: Plot[Hyperfactorial[x], {x, -1, 2}]

A function is bijective iff it is injective and surjective:

Wolfram Language code: FunctionInjective[x ^ 3 / (x ^ 2 + 1), x]

Wolfram Language code: FunctionSurjective[x ^ 3 / (x ^ 2 + 1), x]

Wolfram Language code: FunctionBijective[x ^ 3 / (x ^ 2 + 1), x]

Wolfram Language code: Plot[x ^ 3 / (x ^ 2 + 1), {x, -1, 1}]

is not bijective because it is not injective:

Wolfram Language code: FunctionInjective[x Sin[x], x]

Wolfram Language code: FunctionBijective[x Sin[x], x]

Wolfram Language code: Plot[x Sin[x], {x, -20, 20}]

is not bijective because it is not surjective:

Wolfram Language code: FunctionSurjective[Erf[x], x]

Wolfram Language code: FunctionBijective[Erf[x], x]

Wolfram Language code: Plot[Erf[x], {x, -5, 5}]

A function is bijective if any horizontal line intersects the graph exactly once:

Wolfram Language code: f = (3x ^ 7 + 3x ^ 2 + x ^ 3) / (x ^ 6 + 2x ^ 2);

Wolfram Language code: FunctionBijective[f, x]

Wolfram Language code: Manipulate[Plot[{f, a}, ...], {{a, 1.5}, -5, 5}]

is not bijective:

Wolfram Language code: FunctionBijective[SinIntegral[x], x]

Some horizontal lines intersect the graph more than once; others do not intersect it at all:

Wolfram Language code: Manipulate[Plot[{SinIntegral[x], a}, ...], {{a, 1.5}, -3, 3}]

Composition of bijective functions is bijective:

Wolfram Language code: FunctionBijective[x ^ 3, x]

Wolfram Language code: FunctionBijective[Sinh[x], x]

Wolfram Language code: FunctionBijective[#, x]& /@ {Sinh[x ^ 3], Sinh[x] ^ 3}

An affine mapping $TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]^n$ given by is bijective if the rank of equals :

Wolfram Language code: Subscript[A, 1] = {{1, 2, 3}, {4, 5, 6}, {7, 8, 0}};

Wolfram Language code: MatrixRank[Subscript[A, 1]]

Wolfram Language code: FunctionBijective[Subscript[A, 1].{x, y, z} + {1, 2, 3}, {x, y, z}]

Wolfram Language code: Subscript[A, 2] = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};

Wolfram Language code: MatrixRank[Subscript[A, 2]]

Wolfram Language code: FunctionBijective[Subscript[A, 2].{x, y, z} + {1, 2, 3}, {x, y, z}]

Probability (1)

CDF of a distribution with a strictly positive PDF is bijective onto :

Wolfram Language code: pdf = PDF[NormalDistribution[], x]

Wolfram Language code: FunctionSign[pdf, x]

Wolfram Language code: Plot[pdf, {x, -5, 5}]

Wolfram Language code: cdf = CDF[NormalDistribution[], x]

Wolfram Language code: FunctionBijective[{cdf, True, 0 < y < 1}, x, y]

Wolfram Language code: Plot[cdf, {x, -3, 3}]

SurvivalFunction is bijective onto as well:

Wolfram Language code: sf = SurvivalFunction[NormalDistribution[], x]

Wolfram Language code: FunctionBijective[{sf, True, 0 < y < 1}, x, y]

Wolfram Language code: Plot[sf, {x, -5, 5}]

Quantile is bijective onto the reals:

Wolfram Language code: qf = Quantile[NormalDistribution[], x]

Wolfram Language code: FunctionBijective[qf, x]

Wolfram Language code: Plot[qf, {x, 0, 1}]

Calculus (2)

Compute by change of variables:

Wolfram Language code: e = Exp[-(x ^ 3 + y ^ 2) ^ 2] / (y ^ 6 + 1)x ^ 2y ^ 2;

If is a bijective mapping , then $int_Uf(g(u)) TemplateBox[{TemplateBox[{{{(, {partial, g}, )}, /, {(, {partial, u}, )}}}, Det]}, Abs]du=int_Vf(v)dv$ :

Wolfram Language code: f[{u_, v_}] := 1 / 9Exp[-u ^ 2] / (v ^ 2 + 1)

Wolfram Language code: g = {x ^ 3 + y ^ 2, y ^ 3};

Wolfram Language code: f[g]Det[D[g, {{x, y}}]] === e

Check that is a bijective mapping $TemplateBox[{}, Reals]^2->TemplateBox[{}, Reals]^2$ :

Wolfram Language code: FunctionBijective[g, {x, y}]

Compute the integral:

Wolfram Language code: Integrate[f[{u, v}], {u, -Infinity, Infinity}, {v, -Infinity, Infinity}]

Compute the original integral directly:

Wolfram Language code: Integrate[e, {x, -Infinity, Infinity}, {y, -Infinity, Infinity}]

Compute the surface area of a ball with radius using a rational parametrization:

Wolfram Language code: f = {(2 r (1 - t^2) u/(1 + t^2) (1 + u^2)), (4 r t u/(1 + t^2) (1 + u^2)), (r (1 - u^2)/1 + u^2)};

Wolfram Language code: ParametricPlot3D[Evaluate[f /. r -> 1], {t, -50, 50}, {u, 0, 50}, ...]

Check that the parametrization is bijective onto the ball less a lower-dimensional set:

Wolfram Language code:

FunctionBijective[{f, u > 0, x ^ 2 + y ^ 2 + z ^ 2 == r ^ 2 && (y ≠ 0 || x > 0)}, {t, u}, {x, y, z}, Assumptions -> r > 0]

The surface area is equal to the integral of square root of Gram determinant of :

Wolfram Language code: df = D[f, {{t, u}}];

Wolfram Language code: Integrate[Sqrt[Det[Transpose[df].df]], {u, 0, ∞}, {t, -∞, ∞}, Assumptions -> r > 0]

Properties & Relations (3)

is bijective iff the equation has exactly one solution for each :

Wolfram Language code: FunctionBijective[x ^ 2 + x + 1, x]

Wolfram Language code: FunctionBijective[x ^ 3 + x + 1, x]

Use Solve to find the solutions:

Wolfram Language code: Solve[x ^ 2 + x + 1 == y, x, Reals]

Wolfram Language code: Solve[x ^ 3 + x + 1 == y, x, Reals]

A real continuous function on an interval is bijective iff it is monotonic and the limits at endpoints are and :

Wolfram Language code: FunctionBijective[{Sec[x], -Pi / 2 < x < Pi / 2}, x]

Wolfram Language code: FunctionBijective[{Tan[x], -Pi / 2 < x < Pi / 2}, x]

Wolfram Language code: Plot[{Sec[x], Tan[x]}, {x, -Pi / 2, Pi / 2}]

Use FunctionMonotonicity to determine the monotonicity of a function:

Wolfram Language code: FunctionMonotonicity[{Sec[x], -Pi / 2 < x < Pi / 2}, x]

Wolfram Language code: FunctionMonotonicity[{Tan[x], -Pi / 2 < x < Pi / 2}, x]

Use Limit to compute the limits:

Wolfram Language code: Limit[{Sec[x], Tan[x]}, x -> -Pi / 2, Direction -> "FromAbove"]

Wolfram Language code: Limit[{Sec[x], Tan[x]}, x -> Pi / 2, Direction -> "FromBelow"]

A complex polynomial mapping is bijective iff it has a polynomial inverse:

Wolfram Language code: F = {x - (x + y / 27) ^ 3, y + (3 x + y / 9) ^ 3};

Wolfram Language code: FunctionBijective[F, {x, y}, Complexes]

Use Solve to find the polynomial inverse:

Wolfram Language code: G = {x, y} /. Solve[{u, v} == {x - (x + y / 27) ^ 3, y + (3 x + y / 9) ^ 3}, {x, y}][[1]]

Verify that is a two-sided inverse of :

Wolfram Language code: Expand[G /. Thread[{u, v} -> F]]

Wolfram Language code: Expand[F /. Thread[{x, y} -> G]]

Possible Issues (2)

FunctionBijective determines the real domain of functions using FunctionDomain:

Wolfram Language code: FunctionBijective[{Cosh[Sqrt[x]], True, y ≥ 1}, x, y]//Quiet

is bijective onto in the real domain reported by FunctionDomain:

Wolfram Language code: FunctionDomain[Cosh[Sqrt[x]], x]

Wolfram Language code: Plot[{Cosh[Sqrt[x]], 7}, {x, 0, 10}]

is real valued and not bijective onto over the whole reals:

Wolfram Language code: Plot[{Cosh[Sqrt[x]], -1 / 2}, {x, -20, 10}]

All subexpressions of need to be real valued for a point to belong to the real domain of :

Wolfram Language code: Refine[Element[Sqrt[x], Reals], x < 0]

FunctionBijective restricts the domain to the inverse image of the solution set of ycons:

Wolfram Language code: FunctionBijective[{x / 2, Element[x, Integers], Element[y, Integers]}, x, y]

Division by two is a bijection between the even integers (the inverse image of integers) and the integers.

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FunctionBijective

Details and Options

Examples

Basic Examples (4)

Scope (10)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (11)

Basic Applications (8)

Probability (1)

Calculus (2)

Properties & Relations (3)

Possible Issues (2)

Text

CMS

APA

BibTeX

BibLaTeX

	Automatic	nongeneric conditions only
	True	all conditions
	False	no conditions
	None	return unevaluated if conditions are needed

FunctionBijective

Details and Options

Examples

Basic Examples (4)

Scope (10)

Options (4)

Assumptions (1)

GenerateConditions (2)

PerformanceGoal (1)

Applications (11)

Basic Applications (8)

Probability (1)

Calculus (2)

Properties & Relations (3)

Possible Issues (2)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX