FunctionPoles
FunctionPoles[f,x]
finds the poles of the meromorphic function f with the variable x.
FunctionPoles[{f,cons},x]
gives the poles of f when x is restricted by the constraints cons.
Details and Options
- Function poles are also known as pole singularities.
- Function poles are often used to compute the residue of a function in complex analysis or to compute the radius of convergence for a power series.
- A function
has a pole singularity at 
with multiplicity 
if it has a series representation of the form 
. A function is meromorphic if it only has pole singularities. - FunctionPoles returns a list of pairs {pole,multiplicity}.
- The function f should be meromorphic for x satisfying the constraints cons.
- cons can contain equations, inequalities or logical combinations of these.
- The following options can be given:
-
Assumptions $Assumptions assumptions on parameters GeneratedParameters C how to name parameters that are generated PerformanceGoal $PerformanceGoal whether to prioritize speed or quality - Some of the returned poles may have Indeterminate multiplicity if FunctionPoles fails to determine their multiplicity.
Examples
open all close allBasic Examples (2)
Scope (6)
FunctionPoles[(x ^ 2 - 3) / (x ^ 3 - 2) + x / (x - 1) ^ 3, x]A function with infinitely many poles:
FunctionPoles[Gamma[x ^ 2 + 1], x]![TemplateBox[{x}, Abs]<=2](Files/FunctionPoles.en/6.png "TemplateBox[{x}, Abs]<=2"){kind=small}
FunctionPoles[{Gamma[x ^ 2 + 1], Abs[x] <= 2}, x]Analytic functions have no poles:
FunctionPoles[Sin[x ^ 2 + Cosh[x]] + E ^ x, x]
has a removable singularity at 
:
FunctionPoles[(1 - Cos[x]) / x ^ 2, x]FunctionPoles requires the input function to be meromorphic:
FunctionPoles[Log[x] + 1 / (x - 1), x]
The function is meromorphic for 
:
FunctionPoles[{Log[x] + 1 / (x - 1), Re[x] > 0}, x]Some of the returned poles may have Indeterminate multiplicity if determining the multiplicity fails:
FunctionPoles[Gamma[a x] Gamma[Sqrt[a ^ 2] x], x, Assumptions -> Element[a, Reals]][[1]]Options (3)
Assumptions (1)
GeneratedParameters (1)
FunctionPoles may introduce new parameters to represent the solution:
FunctionPoles[Tan[x ^ 2], x]Use GeneratedParameters to control how the parameters are named:
FunctionPoles[Tan[x ^ 2], x, GeneratedParameters -> (Subscript[k, #]&)]PerformanceGoal (1)
Computing multiplicities of poles may take a long time:
(p1 = FunctionPoles[Gamma[a x ^ 2 + x + 1], x, Assumptions -> Element[a, Reals]]);//AbsoluteTimingPerformanceGoal"Speed" limits the time allowed for computation of multiplicity:
(p2 = FunctionPoles[Gamma[a x ^ 2 + x + 1], x, Assumptions -> Element[a, Reals], PerformanceGoal -> "Speed"]);//AbsoluteTimingThe poles returned in both cases are the same:
(First /@ p1) === (First /@ p2)In the first case, all multiplicities are computed successfully:
#[[2]]& /@ p1In the second case, some multiplicities are not computed:
#[[2]]& /@ p2Applications (3)
Classify singularities of a meromorphic function:
f = (E ^ x - 1 - x) / x ^ 2 + Sin[x - 1] / (x ^ 2 - 1) ^ 2;FunctionSingularities gives locations of poles and removable singularities:
FunctionSingularities[f, x]
has a double pole at 
, a single pole at 
and a removable singularity at 
:
FunctionPoles[f, x]Integrate ![TemplateBox[{{{x, ^, 3}, -, {x, /, 3}}}, Gamma]](Files/FunctionPoles.en/15.png "TemplateBox[{{{x, ^, 3}, -, {x, /, 3}}}, Gamma]"){kind=small}
along the unit circle:
f = Gamma[x ^ 3 - x / 3];Compute the poles of 
in the unit disk:
pp = FunctionPoles[{f, Abs[x] <= 1}, x]Compute the integral using the residue theorem:
2Pi I Total[Residue[f, {x, #[[1]]}]& /@ pp]//RootReduceCompare with the result of numeric integration:
NIntegrate[(f /. x -> Exp[I t])D[Exp[I t], t], {t, 0, 2Pi}] - %//ChopFind the radius of convergence of the Taylor series of 
at 
:
f = Tanh[x];The radius of convergence equals the distance to the nearest pole:
FunctionPoles[{f, Abs[x] < 3}, x]r = Min[Abs[First[#] - 0]& /@ %]Even though the poles are complex, the convergence over the reals is affected:
s = Series[f, {x, 0, 15}]//NormalPlot[{f, s}, {x, -3, 3}, Rule[...]]Since 
is farther from the poles than 
, the convergence radius at 
is greater:
FunctionPoles[{f, Abs[x - 3] < 5}, x]r = Min[Abs[First[#] - 3]& /@ %]s = Series[f, {x, 3, 15}]//Normal;Plot[{f, s}, {x, -3, 9}, Rule[...]]Properties & Relations (4)
The limit of the absolute value of a function at a pole is 
:
FunctionPoles[{1 / (E ^ x - 2), Abs[x] < 2}, x]Use Limit to compute the limit:
Limit[Abs[1 / (E ^ x - 2)], x -> Log[2]]The first term of the power series of a function at a pole of multiplicity 
has exponent 
:
FunctionPoles[{Tan[x] ^ 3 + x, Abs[x] < 2}, x]Use Series to compute the series:
Series[Tan[x] ^ 3 + x, {x, Pi / 2, 1}]Use Residue to find the coefficient at the series term with exponent 
:
Residue[Tan[x] ^ 3 + x, {x, Pi / 2}]The only singularities a meromorphic function can have are poles and removable singularities:
FunctionMeromorphic[Sin[x] / (x ^ 3 - x), x]Use FunctionSingularities to find a condition satisfied by all singularities:
FunctionSingularities[Sin[x] / (x ^ 3 - x), x]Use SolveValues to find the singularities:
SolveValues[%, x]The function has poles at 
and 
and a removable singularity at 
:
FunctionPoles[Sin[x] / (x ^ 3 - x), x]Use FunctionPoles to find the poles of a function:
FunctionPoles[x ^ 3 / (x ^ 4 - 2), x]Use Residue to find the residues at the poles:
Residue[x ^ 3 / (x ^ 4 - 2), {x, #[[1]]}]& /@ %ResidueSum gives the sum of the residues at all poles:
ResidueSum[x ^ 3 / (x ^ 4 - 2), x]Possible Issues (2)
Some of the returned poles may have Indeterminate multiplicity if determining the multiplicity fails:
FunctionPoles[Gamma[a x] Gamma[Sqrt[a ^ 2] x], x, Assumptions -> Element[a, Reals]][[1]]FunctionPoles rationalizes inexact inputs and then approximates the result to the input precision:
FunctionPoles[1 / (x - 1) ^ (2. + 10 ^ -13), x]The result may depend on which rational numbers are chosen:
FunctionPoles[1 / (x - 1) ^ (2. + 10 ^ -12), x]
In the first example, the rationalized exponent is an integer; in the second example, it is not:
Rationalize[Rationalize[#], 0]& /@ {2. + 10 ^ -13, 2. + 10 ^ -12}Text
Wolfram Research (2021), FunctionPoles, Wolfram Language function, https://reference.wolfram.com/language/ref/FunctionPoles.html.
CMS
Wolfram Language. 2021. "FunctionPoles." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionPoles.html.
APA
Wolfram Language. (2021). FunctionPoles. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FunctionPoles.html