Wolfram Language & System Documentation Center

HyperHarmonicNumber

HyperHarmonicNumber[p,n]

gives the hyperharmonic number of level .

HyperHarmonicNumber[p,n,r]

gives the hyperharmonic number of level with order .

HyperHarmonicNumber[p,n,r,s]

gives the hyperharmonic number of level with order and decoration value .

Details

HyperHarmonicNumber extends harmonic numbers by iterated summation and is represented by -fold cumulative sums of harmonic numbers.
HyperHarmonicNumber appears in fields such as combinatorics, number theory and quantum field theory.
HyperHarmonicNumber is a mathematical function, suitable for both symbolic and numerical manipulation.
For positive integer , the hyperharmonic numbers are calculated recursively by $TemplateBox[{p, n}, HyperHarmonicNumber]=sum_(k=1)^nTemplateBox[{{p, -, 1}, n}, HyperHarmonicNumber]$ , where .
For , the hyperharmonic numbers are just the harmonic numbers $TemplateBox[{1, n}, HyperHarmonicNumber]=sum_(k=1)^n1/k$ , and hence, HyperHarmonicNumber[1,n] will return HarmonicNumber[n].
By definition, the hyperharmonic numbers satisfy the recurrence relation .
For arbitrary and , admits analytic continuation given by (PolyGamma[n+p]-PolyGamma[p]).
Hyperharmonic numbers with order are calculated recursively by $TemplateBox[{p, n, r}, HyperHarmonicNumber3] =sum_(k=1)^(n)TemplateBox[{{p, -, 1}, n, r}, HyperHarmonicNumber3]$ , where , the harmonic number of order .
Hyperharmonic numbers with order and decoration value are calculated recursively by $TemplateBox[{p, n, r, s}, HyperHarmonicNumber4]=sum_(k=1)^(n)TemplateBox[{{p, -, 1}, n, r, s}, HyperHarmonicNumber4]$ , where , the harmonic number of order and decoration value .
Sum, RSolve, GeneratingFunction, ExponentialGeneratingFunction, ZTransform and DirichletTransform include methods for handling inputs involving HyperHarmonicNumber.

Examples

open all close all

Basic Examples (6)

First 10 hyperharmonic numbers:

Wolfram Language code: Table[HyperHarmonicNumber[2, n], {n, 10}]

Plot over a subset of the integers:

Wolfram Language code: DiscretePlot[HyperHarmonicNumber[2, t], {t, 0, 100}]

Plot over a subset of the reals:

Wolfram Language code: ReImPlot[HyperHarmonicNumber[2 / 3, n], {n, -∞, ∞}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[HyperHarmonicNumber[p, n] /. p -> 2 / 3, {n, -1 - I, 1 + I}, ...]

Series expansion at the origin:

Wolfram Language code: Series[HyperHarmonicNumber[p, n], {n, 0, 2}]

Series expansion at infinity:

Wolfram Language code: Series[HyperHarmonicNumber[1 / 3, n], {n, ∞, 2}]

Scope (27)

Numerical Evaluation (6)

Evaluate numerically:

Wolfram Language code: HyperHarmonicNumber[2, 4]

Wolfram Language code: HyperHarmonicNumber[3, E]//N

Evaluate to high precision:

Wolfram Language code: N[HyperHarmonicNumber[2, 4], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: HyperHarmonicNumber[2`30, 4]

Wolfram Language code: Precision[%]

Complex number input:

Wolfram Language code: HyperHarmonicNumber[1. + I, 4]

Wolfram Language code: HyperHarmonicNumber[1, 4. + I]

Wolfram Language code: HyperHarmonicNumber[1, 4. + I, 2 - I]

Evaluate efficiently at high precision:

Wolfram Language code: N[HyperHarmonicNumber[2 / 3, 4], 500]//Timing

Wolfram Language code: N[HyperHarmonicNumber[2 / 3, 4], 1500];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: HyperHarmonicNumber[4, Interval[2.1, 2.2]]

Wolfram Language code: HyperHarmonicNumber[4, CenteredInterval[3 / 4, 1 / 1000]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: HyperHarmonicNumber[4, Around[2.1, 0.01]]

Compute the matrix HyperHarmonicNumber function using MatrixFunction:

Wolfram Language code: MatrixFunction[HyperHarmonicNumber[#, 4]&, {{1 / 2, 2}, {2, 1 / 2}}]//FullSimplify

Specific Values (5)

HyperHarmonicNumber[p,n] for symbolic :

Wolfram Language code: HyperHarmonicNumber[p, 2]//FunctionExpand//Simplify

HyperHarmonicNumber[p,n] for symbolic :

Wolfram Language code: HyperHarmonicNumber[4, n]//FunctionExpand

Value at zero:

Wolfram Language code: {HyperHarmonicNumber[2, 0], HyperHarmonicNumber[2, 0, 10], HyperHarmonicNumber[2, 0, 10, 20]}

Find a value of for which HyperHarmonicNumber[11/3,n] is :

Wolfram Language code: nval = n /. FindRoot[HyperHarmonicNumber[11 / 3, n] == 1.5, {n, 5}]

Wolfram Language code: ReImPlot[HyperHarmonicNumber[11 / 3, n], {n, 0, 5}, Rule[...]]

Express hyperharmonic numbers of fractional arguments in terms of elementary functions:

Wolfram Language code: HyperHarmonicNumber[1 / 3, 3 / 4]//FunctionExpand

Wolfram Language code: HyperHarmonicNumber[1, 3 / 4]//FunctionExpand

Function Properties (8)

Real domain of HyperHarmonicNumber:

Wolfram Language code: FunctionDomain[HyperHarmonicNumber[p, n], n]

Complex domain:

Wolfram Language code: FunctionDomain[HyperHarmonicNumber[p, n], n, Complexes]

HyperHarmonicNumber is a meromorphic function:

Wolfram Language code: FunctionMeromorphic[HyperHarmonicNumber[p, n], n]

HyperHarmonicNumber is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[HyperHarmonicNumber[3, n], n]

HyperHarmonicNumber is not surjective:

Wolfram Language code: FunctionSurjective[HyperHarmonicNumber[p, 3], p]

Wolfram Language code: ReImPlot[{HyperHarmonicNumber[p, 3], 2}, {p, -4, 2}, PlotRange -> 10]

HyperHarmonicNumber is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[HyperHarmonicNumber[p, 3], p]

The singularities and discontinuities of the HyperHarmonicNumber:

Wolfram Language code: FunctionSingularities[HyperHarmonicNumber[p, n], p]

Wolfram Language code: FunctionSingularities[HyperHarmonicNumber[p, n], n]

HyperHarmonicNumber is neither convex nor concave:

Wolfram Language code: FunctionConvexity[HyperHarmonicNumber[3, n], n]

TraditionalForm formatting:

Wolfram Language code: HyperHarmonicNumber[p, n] // TraditionalForm

Wolfram Language code: HyperHarmonicNumber[p, n, r] // TraditionalForm

Wolfram Language code: HyperHarmonicNumber[p, n, r, s] // TraditionalForm

Series Expansions (3)

Find the Taylor expansion using Series:

Wolfram Language code: Series[HyperHarmonicNumber[p, n], {n, 0, 1}]

Plots of the first three approximations around for :

Wolfram Language code:

terms = Normal@Table[Series[HyperHarmonicNumber[3 / 2, n], {n, 0, m}], {m, 1, 5, 2}]//Quiet;
ReImPlot[{HyperHarmonicNumber[3 / 2, n], terms}, {n, 0, 10}, PlotRange -> {-30, 30}]

Series expansion at the unity:

Wolfram Language code: Series[HyperHarmonicNumber[p, n], {n, 1, 1}]//FullSimplify

Find the Taylor expansion using Series near infinity:

Wolfram Language code: Series[HyperHarmonicNumber[p, n], {n, ∞, 1}]

Function Identities and Simplifications (5)

First 10 hyperharmonic numbers of level :

Wolfram Language code: Table[HyperHarmonicNumber[1, n], {n, 10}]

These are the harmonic numbers:

Wolfram Language code: Table[HarmonicNumber[n], {n, 10}]

First 10 hyperharmonic numbers of level 0:

Wolfram Language code: Table[HyperHarmonicNumber[0, n], {n, 10}]

These are the numbers :

Wolfram Language code: Table[1 / n, {n, 10}]

Calculating the hyperharmonic numbers recursively using HarmonicNumber:

Wolfram Language code: HyperHarmonicNumber[2, 4]

Wolfram Language code: With[{n = 4, p = 2}, Sum[HyperHarmonicNumber[p - 1, i], {i, 1, n}]]

Calculating the hyperharmonic numbers of order recursively:

Wolfram Language code: HyperHarmonicNumber[3, 4]

Wolfram Language code: With[{n = 4, p = 3}, Sum[HyperHarmonicNumber[p - 1, i], {i, 1, n}]]

Connection with the polygamma functions:

Wolfram Language code: Table[HyperHarmonicNumber[2, n], {n, 1, 10}]

Wolfram Language code: Table[(Gamma[n + r] (-PolyGamma[0, r] + PolyGamma[0, n + r])/Gamma[1 + n] Gamma[r]), {n, 1, 10}] /. r -> 2

Applications (10)

Summation (3)

A finite Euler sum involving a HyperHarmonicNumber:

Wolfram Language code: Sum[n^2HyperHarmonicNumber[3, n], {n, 1, k}]

An infinite Euler sum involving a HyperHarmonicNumber:

Wolfram Language code: Sum[((1/2))^n(HyperHarmonicNumber[3, n]/n^4), {n, 1, ∞}]

A finite Euler sum involving a product of a HarmonicNumber and a HyperHarmonicNumber:

Wolfram Language code: Sum[(HarmonicNumber[n, 2]HyperHarmonicNumber[2, n]/3^nn^2), {n, 1, ∞}]

Recurrence Equations (2)

Solve a recurrent equation containing HyperHarmonicNumber in the forcing term:

Wolfram Language code: RSolveValue[{x[k] - 2x[k - 1] == HyperHarmonicNumber[2, k], x[1] == 1}, x[k], k]

A product of a HarmonicNumber and a HyperHarmonicNumber in the forcing term, along with a pre-factor :

Wolfram Language code: RSolveValue[{x[k] + 6x[k - 1] == k * HarmonicNumber[k] * HyperHarmonicNumber[2, k], x[1] == 1}, x[k], k]

Generating Function (3)

Compute the GeneratingFunction of a HyperHarmonicNumber:

Wolfram Language code: GeneratingFunction[HyperHarmonicNumber[3, n], n, x]

Compute the GeneratingFunction of the product of a HarmonicNumber and a HyperHarmonicNumber:

Wolfram Language code: GeneratingFunction[HarmonicNumber[n]HyperHarmonicNumber[3, n], n, x]

Compute the ExponentialGeneratingFunction of the product of a StirlingS1 and a HyperHarmonicNumber:

Wolfram Language code: ExponentialGeneratingFunction[StirlingS1[n, 3]HyperHarmonicNumber[2, n], n, x]

Discrete Transforms (2)

Compute the ZTransform of the square of a HyperHarmonicNumber:

Wolfram Language code: ZTransform[HyperHarmonicNumber[3, n] ^ 2, n, z]

Compute the DirichletTransform of a HyperHarmonicNumber (with a rational pre-factor):

Wolfram Language code: DirichletTransform[(1 / 2)^nHyperHarmonicNumber[2, n], n, s]

Properties & Relations (9)

HyperHarmonicNumber for and integer index:

Wolfram Language code: {HyperHarmonicNumber[0, 10], HyperHarmonicNumber[0, 10, r], HyperHarmonicNumber[0, 10, r, s]}

HyperHarmonicNumber for is just the HarmonicNumber:

Wolfram Language code: {HyperHarmonicNumber[1, n], HyperHarmonicNumber[1, n, r], HyperHarmonicNumber[1, n, r, s]}

Sum of HarmonicNumber leads to HyperHarmonicNumber of level :

Wolfram Language code: Sum[HarmonicNumber[k], {k, n}]

Wolfram Language code: Sum[HarmonicNumber[k, r], {k, n}]

Wolfram Language code: Sum[HarmonicNumber[k, r, s], {k, n}]

Sum of HyperHarmonicNumber of level results in HyperHarmonicNumber of level :

Wolfram Language code: Sum[HyperHarmonicNumber[p, k], {k, 1, n}]

Wolfram Language code: Sum[HyperHarmonicNumber[p, k, r], {k, 1, n}]

Wolfram Language code: Sum[HyperHarmonicNumber[p, k, r, s], {k, 1, n}]

Verify the Conway–Guy relationship between HyperHarmonicNumber and HarmonicNumber for integers and :

Wolfram Language code:

(HyperHarmonicNumber[p, n] == Binomial[n + p - 1, p - 1](HarmonicNumber[n + p - 1] - HarmonicNumber[p - 1])) /. {p -> 3, n -> 10}

A HyperHarmonicNumber can be written as a linear combination of MultipleHarmonicNumber's:

Wolfram Language code:

HyperHarmonicNumberToMHN[p_, n_, r_, s_] := 
	(1 / Factorial[p - 1]) * Sum[((-1) ^ (l - j)) * Abs[StirlingS1[p, l]] * Binomial[l - 1, j - 1] * (n ^ (j - 1)) * Inactive[MultipleHarmonicNumber][n, {r + j - l}, {s}], {j, 1, p}, {l, j, p}]

Write the identity for a specific set of parameters:

Wolfram Language code:

With[{n = 10, r = 2, s = 1 / 6, p = 3}, 
	Inactive[HyperHarmonicNumber][p, n, r, s] == HyperHarmonicNumberToMHN[p, n, r, s]
	]

Activate to confirm:

Wolfram Language code: Activate[%]

Recurrence relation:

Wolfram Language code: HyperHarmonicNumber[p, n] == HyperHarmonicNumber[p, n - 1] + HyperHarmonicNumber[p - 1, n]//FullSimplify

Express HyperHarmonicNumber using Gamma and PolyGamma:

Wolfram Language code: HyperHarmonicNumber[p, n]//FunctionExpand

Define the utility modZeroQ to test whether a rational expr is 0 mod :

Wolfram Language code:

modZeroQ[expr_, m_Integer] := Module[{t = Together[expr], num, den}, num = Numerator[t];den = Denominator[t];
	If[CoprimeQ[den, m], Mod[num * PowerMod[den, -1, m], m] == 0, False]
	];

Verify the mod-n congruence across many primes (for ):

Wolfram Language code:

With[{p = 6}, primes = Select[Prime[Range[100]], # > p&];
	AllTrue[primes, modZeroQ[HyperHarmonicNumber[p, # - 1] (p - 1) - 1, #]&]
	]

Verify the mod-n² congruence $TemplateBox[{p, {n, -, 1}}, HyperHarmonicNumber] = 1/(p-1) + n * (H_(p-2)/(p-1)-1/(p-1)^2) (mod n^2)$ (for ):

Wolfram Language code:

With[{p = 2}, 
	primes = Select[Prime[Range[100]], # > p&]; 
	AllTrue[primes, modZeroQ[HyperHarmonicNumber[p, # - 1] - (1 / (p - 1) + # * (HarmonicNumber[p - 2] / (p - 1) - 1 / (p - 1) ^ 2)), # ^ 2]&]
	]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

HyperHarmonicNumber

Details

Examples

Basic Examples (6)

Scope (27)

Numerical Evaluation (6)

Specific Values (5)

Function Properties (8)

Series Expansions (3)

Function Identities and Simplifications (5)

Applications (10)

Summation (3)

Recurrence Equations (2)

Generating Function (3)

Discrete Transforms (2)

Properties & Relations (9)

Text

CMS

APA

BibTeX

BibLaTeX

HyperHarmonicNumber

Details

Examples

Basic Examples (6)

Scope (27)

Numerical Evaluation (6)

Specific Values (5)

Function Properties (8)

Series Expansions (3)

Function Identities and Simplifications (5)

Applications (10)

Summation (3)

Recurrence Equations (2)

Generating Function (3)

Discrete Transforms (2)

Properties & Relations (9)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX