Wolfram Language & System Documentation Center

Gamma

Gamma[z]

is the Euler gamma function .

Gamma[a,z]

is the incomplete gamma function .

Gamma[a,z₀,z₁]

is the generalized incomplete gamma function $TemplateBox[{a, {z, _, 0}}, Gamma2]-TemplateBox[{a, {z, _, 1}}, Gamma2]$ .

Details

Mathematical function, suitable for both symbolic and numerical manipulation.
The gamma function satisfies $TemplateBox[{z}, Gamma]=int_0^inftyt^(z-1)e^(-t)dt$ .
The incomplete gamma function satisfies $TemplateBox[{a, z}, Gamma2]=int_z^inftyt^(a-1)e^(-t)dt$ .
The generalized incomplete gamma function is given by the integral .
Note that the arguments in the incomplete form of Gamma are arranged differently from those in the incomplete form of Beta.
Gamma[z] has no branch cut discontinuities.
Gamma[a,z] has a branch cut discontinuity in the complex z plane running from to .
For certain special arguments, Gamma automatically evaluates to exact values.
Gamma can be evaluated to arbitrary numerical precision.
Gamma automatically threads over lists.
Gamma can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (7)

Integer values:

Wolfram Language code: Table[Gamma[n], {n, 10}]

Half-integer values:

Wolfram Language code: Table[Gamma[n + 1 / 2], {n, 5}]

Evaluate numerically for complex arguments:

Wolfram Language code: Gamma[2.3 + I]

Plot over a subset of the reals:

Wolfram Language code: Plot[Gamma[x], {x, -3, 3}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[Gamma[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[Gamma[x], {x, 0, 1}]

Series expansion at Infinity:

Wolfram Language code: Series[Gamma[ x], {x, ∞, 3}]//Normal//FullSimplify

Scope (51)

Numerical Evaluation (5)

Evaluate numerically:

Wolfram Language code: {Gamma[2.2], Gamma[1.5, 7.5], Gamma[1, 1.1, 2.2]}

Evaluate to high precision:

Wolfram Language code: N[Gamma[22 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: Gamma[2.20000000000000000000000000000000000000000]

Evaluate Gamma efficiently at high precision:

Wolfram Language code: Gamma[2.2`500]//Timing

Wolfram Language code: Gamma[2.2`5000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: Gamma[Interval[{1.4, 1.5}]]

Wolfram Language code: Gamma[CenteredInterval[3 / 4, 1 / 100]]

Wolfram Language code: Gamma[2 / 3, CenteredInterval[-3 + I, (1 + I) / 100]]

Compute average-case statistical intervals using Around:

Wolfram Language code: Gamma[1, 1, Around[1 / 2, 0.01]]

Compute the elementwise values of an array:

Wolfram Language code: Gamma[2, {{7 / 2, 0}, {0, 13 / 2}}]

Or compute the matrix Gamma function using MatrixFunction:

Wolfram Language code: MatrixFunction[Gamma[2, #]&, {{7 / 2, 0}, {0, 13 / 2}}]

Specific Values (5)

Singular points of Gamma:

Wolfram Language code: Assuming[{n∈Integers && n ≤ 0}, Refine[Gamma[n]]]

Values at infinity:

Wolfram Language code: Gamma[{-Infinity, Infinity, I Infinity, ComplexInfinity}]

Find a local minimum as a root of :

Wolfram Language code: xmin = N@Solve[D[Gamma[x], x] == 0 && 0 < x < 2, x, Reals][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[Gamma[x], {x, -1, 4}, Epilog -> Style[Point[{xmin, Gamma[xmin]}], PointSize[Large], Red]]

Evaluate the incomplete gamma function symbolically at integer and half‐integer orders:

Wolfram Language code: Gamma[2, z]//FunctionExpand

Wolfram Language code: Gamma[7 / 2, z]//FunctionExpand

Evaluate the generalized incomplete gamma function symbolically at half‐integer orders:

Wolfram Language code: Gamma[13 / 2, 7 / 2, 1 / 2]//FunctionExpand//Simplify

Visualization (3)

Plot the Euler gamma function:

Wolfram Language code: Plot[Gamma[x], {x, -4, 4}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[Gamma[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[Gamma[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 24]

Plot the incomplete gamma function for integer and half-integer orders:

Wolfram Language code: Plot[{Gamma[1 / 2, x], Gamma[1, x], Gamma[3 / 2, x], Gamma[2, x]}, {x, -4, 4}, IconizedObject[«PlotOptions»]]

Function Properties (10)

Real domain of the complete Euler gamma function:

Wolfram Language code: FunctionDomain[Gamma[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[Gamma[z], z, Complexes]

Domain of the incomplete gamma functions:

Wolfram Language code: FunctionDomain[Gamma[z, a], {z, a}]

Wolfram Language code: FunctionDomain[Gamma[z, a], {z, a}, Complexes]

Wolfram Language code: FunctionDomain[Gamma[z, a, b], {z, a, b}, Complexes]

The gamma function achieves all nonzero values on the reals:

Wolfram Language code: FunctionRange[Gamma[x], x, y]

The incomplete gamma function achieves all positive real values for real inputs:

Wolfram Language code: FunctionRange[Gamma[1, x], x, y]

On the complexes, however, it achieves all nonzero values:

Wolfram Language code: FunctionRange[Gamma[1, z], z, y, Complexes]

The incomplete gamma function has the restricted range :

Wolfram Language code: FunctionRange[Gamma[1 / 2, x], x, y]

The Euler gamma function has the mirror property :

Wolfram Language code: FullSimplify[Gamma[Conjugate[z]] == Conjugate[Gamma[z]]]

The complete gamma function is a meromorphic, nonanalytic function:

Wolfram Language code: FunctionMeromorphic[Gamma[x], x]

Wolfram Language code: FunctionAnalytic[Gamma[x], x]

is analytic in for positive integer :

Wolfram Language code: FunctionAnalytic[Gamma[a, x], x, Assumptions -> a > 0 && a∈ℤ]

But in general, it is neither an analytic nor a meromorphic function:

Wolfram Language code: FunctionAnalytic[Gamma[1 / 2, x], x]

Wolfram Language code: FunctionMeromorphic[Gamma[1 / 2, x], x]

has both singularities and discontinuities on the non-positive integers:

Wolfram Language code: FunctionSingularities[Gamma[x], x]

Wolfram Language code: FunctionDiscontinuities[Gamma[x], x]

is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[Gamma[x], x, PositiveReals]

is a non-increasing function of when is a positive, odd integer:

Wolfram Language code: FunctionMonotonicity[Gamma[2k + 1, x], x, Assumptions -> k∈ℤ && k > 0]

But in general, it is neither non-increasing nor non-decreasing:

Wolfram Language code: FunctionMonotonicity[Gamma[2, x], x]

is not injective:

Wolfram Language code: FunctionInjective[Gamma[1 / 2, x], x]

is an injective function of for noninteger :

Wolfram Language code: FunctionInjective[Gamma[a, x], x, Assumptions -> a > 0 && a∉ℤ]

Wolfram Language code: FunctionInjective[Gamma[a, x], x, Assumptions -> a < 0 && a∉ℤ]

For integer , it may or may not be injective in :

Wolfram Language code: FunctionInjective[Gamma[1, x], x]

Wolfram Language code: FunctionInjective[Gamma[2, x], x]

Wolfram Language code: Plot[{Gamma[1, x], Gamma[2, x], Gamma[x], .925}, {x, -1, 3}, PlotRange -> {0, 2}]

is not surjective:

Wolfram Language code: FunctionSurjective[Gamma[x], x]

is also not surjective:

Wolfram Language code: FunctionSurjective[Gamma[a, x], x, Assumptions -> a ≤ 0]

Wolfram Language code: FunctionSurjective[Gamma[a, x], x, Assumptions -> a > 0 && a∉ℤ]

Visualize for :

Wolfram Language code: Plot[{Gamma[1 / 2, x], -1}, {x, 0, 10}]

is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Gamma[x], x]

is non-negative for positive odd :

Wolfram Language code: FunctionSign[Gamma[2k + 1, x], x, Assumptions -> k∈ℤ && k > 0]

In general, it is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[Gamma[2, x], x]

is neither convex nor concave:

Wolfram Language code: FunctionConvexity[Gamma[x], x]

is convex on its real domain for :

Wolfram Language code: FunctionConvexity[{Gamma[a, x], x > 0}, x, Assumptions -> -1 ≤ a ≤ 1]

It is in general neither convex nor concave for other values of :

Wolfram Language code: FunctionConvexity[Gamma[2, x], x]

Differentiation (4)

First derivative of the Euler gamma function:

Wolfram Language code: D[Gamma[x], x]

First derivative of the incomplete gamma function:

Wolfram Language code: D[Gamma[a, x], x]

Higher derivatives of the Euler gamma function:

Wolfram Language code: Table[D[Gamma[x], {x, n}], {n, 1, 3}]

Wolfram Language code: Plot[Evaluate[%], {x, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Higher derivatives of the incomplete gamma function for an order :

Wolfram Language code: Table[D[Gamma[1 / 2, x], {x, n}], {n, 1, 3}]

Wolfram Language code: Plot[Evaluate[%], {x, 0, 4}]

Integration (3)

Indefinite integral of the incomplete gamma function:

Wolfram Language code: Integrate[Gamma[a, x], x]

Indefinite integrals of a product involving the incomplete gamma function:

Wolfram Language code: Integrate[Exp[x]Gamma[a, x], x]

Wolfram Language code: Integrate[x ^ b Gamma[a, x], x]

Numerical approximation of a definite integral $int_1^2TemplateBox[{x}, Gamma]dx$ :

Wolfram Language code: NIntegrate[Gamma[x], {x, 1, 2}]

Series Expansions (7)

Taylor expansion for the Euler gamma function around :

Wolfram Language code: Series[Gamma[x], {x, 1, 3}]

Plot the first three approximations for the Euler gamma function around :

Wolfram Language code:

terms = Normal@Table[Series[Gamma[x], {x, 1, m}], {m, 1, 3}];
Plot[{Gamma[x], terms}, {x, 0, 2}]

Series expansion at infinity for the Euler gamma function (Stirling approximation):

Wolfram Language code: Series[Gamma[z], {z, Infinity, 2}]//Normal

Give the result for an arbitrary symbolic direction:

Wolfram Language code: Series[Gamma[x], {x, DirectedInfinity[z], 2}]//Simplify//Normal

Series expansion for the incomplete gamma function at a generic point:

Wolfram Language code: Series[Gamma[a, z], {z, z0, 2}]

Wolfram Language code: Series[Gamma[a, z], {a, a0, 2}]

Series expansion for the incomplete gamma function at infinity:

Wolfram Language code: Series[Gamma[a, z], {z, Infinity, 3}]//Normal

Wolfram Language code: Series[Gamma[a, z], {a, Infinity, 2}]//Normal

Series expansion for the generalized incomplete gamma function at a generic point:

Wolfram Language code: Series[Gamma[a, z1, z2], {z2, z20, 2}]

Series expansion at a singular point:

Wolfram Language code: Series[Gamma[x], {x, -1, 1}]//Normal

Gamma can be applied to a power series:

Wolfram Language code: Gamma[1 + x + (x^2/2) + O[x]^3]

Integral Transforms (4)

Compute the Laplace transform of the incomplete gamma function using LaplaceTransform:

Wolfram Language code: LaplaceTransform[Gamma[a, t], t, s ]

InverseLaplaceTransform of the incomplete gamma function:

Wolfram Language code: InverseLaplaceTransform[Gamma[a, s], s, t ]

MellinTransform of the incomplete gamma function:

Wolfram Language code: MellinTransform[Gamma[a, x], x, s ]

InverseMellinTransform of the Euler gamma function:

Wolfram Language code: InverseMellinTransform[Gamma[s], s, x ]

Function Identities and Simplifications (5)

For positive integers :

Wolfram Language code: FunctionExpand[(n - 1)!, {Element[n, Integers] && n > 0}]

Use FullSimplify to simplify gamma functions:

Wolfram Language code: FullSimplify[Gamma[z]Gamma[1 - z]]

Wolfram Language code: FullSimplify[2^2z - 1Gamma[z]Gamma[z + 1 / 2]]

The Euler gamma function basic relation, :

Wolfram Language code: FullSimplify[Gamma[z + 1] == z Gamma[z]]

The Euler gamma function of a double argument, $TemplateBox[{{2, , x}}, Gamma]=(2^(2 x-1))/(sqrt(pi)) TemplateBox[{x}, Gamma] TemplateBox[{{x, +, {1, /, 2}}}, Gamma]$ :

Wolfram Language code: FullSimplify[Gamma[2x] == (2^2x - 1/Sqrt[π])Gamma[x]Gamma[x + 1 / 2]]

Relation to the incomplete gamma function:

Wolfram Language code: FullSimplify[Gamma[z, 0], Re@z > 0]

Function Representations (5)

Integral representation of the Euler gamma function:

Wolfram Language code: Integrate[t ^ (z - 1) Exp[-t], {t, 0, Infinity}, Assumptions -> Re[z] > 0]

Integral representation of the incomplete gamma function:

Wolfram Language code: Integrate[t ^ (a - 1) Exp[-t], {t, z, Infinity}, Assumptions -> Re[z] > 0]

The incomplete gamma function can be represented in terms of MeijerG:

Wolfram Language code: MeijerGReduce[Gamma[a, x], x]

Wolfram Language code: Activate[%]//FullSimplify

The incomplete gamma function can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[Gamma[a, x], x]

TraditionalForm formatting:

Wolfram Language code: Gamma[z]//TraditionalForm

Generalizations & Extensions (6)

Euler Gamma Function (3)

Gamma threads elementwise over lists:

Wolfram Language code: Gamma[{2, 3, 5, 7, 11}]

Series expansion at poles:

Wolfram Language code: Series[Gamma[z], {z, 0, 1}]

Expansion at symbolically specified negative integers:

Wolfram Language code: Series[Gamma[z], {z, -n, 1}, Assumptions -> n∈Integers∧n ≥ 0]

TraditionalForm formatting:

Wolfram Language code: Gamma[z]//TraditionalForm

Incomplete Gamma Function (1)

Evaluate symbolically at integer and half‐integer orders:

Wolfram Language code: Gamma[3, z]//FunctionExpand

Wolfram Language code: Gamma[7 / 2, z]//FunctionExpand

Generalized Incomplete Gamma Function (2)

Evaluate symbolically at integer and half‐integer orders:

Wolfram Language code: Gamma[13 / 2, 7 / 2, 1 / 2]//FunctionExpand//Simplify

Series expansion at a generic point:

Wolfram Language code: Series[Gamma[a, z1, z2], {z2, z20, 2}]

Applications (9)

Plot of the absolute value of Gamma in the complex plane:

Wolfram Language code: Plot3D[Abs[Gamma[x + I y]], {x, -5, 2}, {y, -1, 1}]

Find the asymptotic expansion of ratios of gamma functions:

Wolfram Language code: Series[(Gamma[n + α]/Gamma[n + β]), {n, ∞, 1}]

Volume of an ‐dimensional unit hypersphere:

Wolfram Language code: hypersphereVolume[n_] := (π^n / 2/Gamma[(n/2) + 1])

Low‐dimensional cases:

Wolfram Language code: Table[r ^ n hypersphereVolume[n], {n, 10}]

Plot the volume of the unit hypersphere as a function of dimension:

Wolfram Language code: DiscretePlot[hypersphereVolume[n], {n, 0, 25}]

Plot the real part of the incomplete gamma function over the parameter plane:

Wolfram Language code: Plot3D[Re[Gamma[a, x]], {a, -2, 2}, {x, -2, 2}]

CDF of the ‐distribution:

Wolfram Language code: CDF[ChiSquareDistribution[r]][x]

Calculate the PDF:

Wolfram Language code: {D[%, x], PDF[ChiSquareDistribution[r]][x]}

Plot the CDF for different numbers of degrees of freedom:

Wolfram Language code: Plot[Evaluate[Table[CDF[ChiSquareDistribution[r]][x], {r, 5}]], {x, 0, 10}]

Compute derivatives of the Gamma function with the BellY polynomial:

Wolfram Language code: Gamma[n]BellY[Table[{1, PolyGamma[k - 1, n]}, {k, 3}]]//Expand

Wolfram Language code: D[Gamma[n], {n, 3}]

Compute as a limit of Gamma functions at Infinity:

Wolfram Language code: Limit[(2 ^ (4 x - 1) Gamma[x + 1] ^ 4) / ((2x - 1) Gamma[2x + 1] ^ 2), x -> ∞]

Expectation value of the square root of a quadratic form over a normal distribution:

Wolfram Language code: MatrixForm[mat = HilbertMatrix[3]]

Wolfram Language code:

NExpectation[Sqrt[(1/2){u, v, w}.mat.{u, v, w}], {u, v, w}ProductDistribution[{NormalDistribution[], 3}], Method -> "MonteCarlo"]//Quiet

Compare with the closed-form result in terms of Gamma and CarlsonRG:

Wolfram Language code: N[(Gamma[(3 - 1/2)]/Gamma[(3/2)])(CarlsonRG@@Eigenvalues[mat]), 25]

Represent Zeta in terms of Integrate and the Gamma function:

Wolfram Language code: FullSimplify[Zeta[s] == (1/Gamma[s]) Subsuperscript[∫, 0, ∞](t^s - 1/E^t - 1)ⅆt, Re[s] > 1]

Properties & Relations (7)

Use FullSimplify to simplify gamma functions:

Wolfram Language code: FullSimplify[Gamma[z]Gamma[1 - z]]

Numerically find a root of a transcendental equation:

Wolfram Language code: FindRoot[Gamma[z] - 4 Gamma[z + 2] + z == 2, {z, 1}]

Sum expressions involving Gamma:

Wolfram Language code: Underoverscript[∑, k = 1, n]Gamma[k]

Wolfram Language code: FunctionExpand[%]

Generate from integrals, products, and limits:

Wolfram Language code: Integrate[t ^ (z - 1) Exp[-t], {t, 0, Infinity}, Assumptions -> Re[z] > 0]

Wolfram Language code: E^z EulerGamma Product[(1 + (z/k))E^-z / k, {k, 1, Infinity}]

Wolfram Language code: Product[((1 + (1/k))^z/1 + (z/k)), {k, 1, Infinity}]

Obtain Gamma as the solution of a differential equation:

Wolfram Language code: DSolve[z Derivative[2][w][z] + (1 - a + z) Derivative[1][w][z] == 0 , w, z]

Integrals:

Wolfram Language code: Integrate[z ^ b Gamma[a, z], z]

Gamma can be represented as a DifferenceRoot:

Wolfram Language code: DifferenceRootReduce[Gamma[k], k]

Possible Issues (2)

Large arguments can give results too large to be computed explicitly:

Wolfram Language code: Gamma[10 ^ 14.]

Machine‐number inputs can give high‐precision results:

Wolfram Language code: Gamma[10. ^ 3]

Wolfram Language code: MachineNumberQ[%]

Neat Examples (3)

Nest Gamma over the complex plane:

Wolfram Language code: DensityPlot[Arg[Nest[Gamma, x + I y, 3]], {x, -1.25, -0.6}, {y, -0.25, 0.25}]//Quiet

Fractal from iterating Gamma:

Wolfram Language code:

ArrayPlot[Table[c = N[cr + I ci];Length @NestWhileList[If[Abs[#] > 20., Indeterminate, Gamma[# / c]]&, c, (# =!= Indeterminate)&, 1, 20], {ci, -2.5, 2.5, 5 / 100}, {cr, -2, 2, 4 / 100}]]//Quiet

Plot the Riemann surface of :

Wolfram Language code:

With[{a = 1 / 3, ε = 1*^-12}, 
	ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[2 k π I a] Gamma[a, r Exp[I φ]] + (1 - Exp[2 k π I a]) Gamma[a]]}, {k, -2, 2}], {r, 0, 2}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotPoints -> 21, PlotRange -> All, PlotStyle -> Directive[Hue[0.09], Opacity[0.6]]]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

Gamma

Details

Examples

Basic Examples (7)

Scope (51)

Numerical Evaluation (5)

Specific Values (5)

Visualization (3)

Function Properties (10)

Differentiation (4)

Integration (3)

Series Expansions (7)

Integral Transforms (4)

Function Identities and Simplifications (5)

Function Representations (5)

Generalizations & Extensions (6)

Euler Gamma Function (3)

Incomplete Gamma Function (1)

Generalized Incomplete Gamma Function (2)

Applications (9)

Properties & Relations (7)

Possible Issues (2)

Neat Examples (3)

Text

CMS

APA

BibTeX

BibLaTeX

Gamma

Details

Examples

Basic Examples (7)

Scope (51)

Numerical Evaluation (5)

Specific Values (5)

Visualization (3)

Function Properties (10)

Differentiation (4)

Integration (3)

Series Expansions (7)

Integral Transforms (4)

Function Identities and Simplifications (5)

Function Representations (5)

Generalizations & Extensions (6)

Euler Gamma Function (3)

Incomplete Gamma Function (1)

Generalized Incomplete Gamma Function (2)

Applications (9)

Properties & Relations (7)

Possible Issues (2)

Neat Examples (3)

See Also

Tech Notes

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX